tell application "Adobe InDesign CS2" 
	activate 
	-- Initialisierung 
	set foundThese to "" 
	set allColors to every swatch of active document 
	set myDialog to make dialog with properties {name:"Welche Farbe"} 
	tell myDialog 
		make dialog column 
		tell the result 
			set whichButtons to make radiobutton group 
			tell whichButtons 
				repeat with aColor in allColors 
					make radiobutton control with properties {static label:name of aColor} 
				end repeat 
			end tell 
		end tell 
	end tell 
	set nu to show myDialog 
	if nu is true then 
		set thisColor to item ((selected button of whichButtons) + 1) of allColors 
	else 
		destroy myDialog 
	end if 
	set nameOfThisColor to name of thisColor 
	 
	set find preferences to nothing 
	set fill color of find preferences to thisColor 
	tell active document to set foundText to search 
	set find preferences to nothing 
	set stroke color of find preferences to thisColor 
	tell active document to set foundText to (foundText & (search)) 
	 
	tell active document 
		set nPages to number of pages 
		repeat with n from 1 to nPages 
			set allThings to every page item of page n 
			repeat with someThing in allThings 
				if (fill color of someThing) = thisColor or (stroke color of someThing) = thisColor or (gap color of someThing) = thisColor then 
					set foundThese to foundThese & "Seite " & n & " @ " & item 2 of visible bounds of someThing & ", " & item 1 of visible bounds of someThing & " 
" 
				end if 
			end repeat 
		end repeat 
		 
		set myFoundText to "" 
		if (count foundText) > 0 then 
			repeat with n from 1 to count foundText 
				set hae to item n of foundText 
				set myFoundText to myFoundText & (index of first character of hae) & return 
			end repeat 
		end if 
		 
		set thisFrame to make text frame 
		set geometric bounds of thisFrame to {0, 150, 150, 0} 
		set contents of thisFrame to "Gefundene Objekte" & return & (foundThese as string) & return & "Gefundene Texte:" & return & myFoundText & return 
		 
	end tell 
end tell