Hallo Hans,

ist es per Skript möglich in QX4 alle Bildskalierungen welche unter 70% und über 130% liegen auf 100%zu setzen?
Hintergrund ist:
Alles <70% und >130% wird in Photoshop neu berechnet und in Quark auf 100% gestellt.

Gruss willem

Hallo Willem,

Ich hab grade mal ein Script gebastelt, welches deine Anforderungen erfüllen sollte. Getestet ist es unter XPress 4 und 5.

Es arbeitet sämtliche Bildrahmen ab und setzt die zu kleinen oder zu großen Bilder auf 100 %. Gleichzeitig wird der X- und Y-Wert des Bildes auf 0 gesetzt.


tell application "Passport 4.04"
 tell document 1
  repeat with x from 1 to count of picture box
   tell picture box x
    try
     set Groesse to get scale of image 1 as list
     set GroesseY to item 1 of Groesse as real
     set GroesseX to item 2 of Groesse as real
     if GroesseX < 70 then
      if GroesseY < 70 then
       set scale of image 1 to {100, 100} -- Bildgroesse wird auf 100 % gestellt
       set offset of image 1 to {0, 0}
      end if
     end if
     if GroesseX > 130 then
      if GroesseY > 130 then
       set scale of image 1 to {100, 100} -- Bildgroesse wird auf 100 % gestellt
       set offset of image 1 to {0, 0}
      end if
     end if
    end try
   end tell
  end repeat
 end tell
end tell



Ich hoffe es hilft dir weiter.

Rainer

hallo Rainer,

das Script funktioniert einwandfrei, es werden alle entsprechende Bilder auf 100% gesetzt.

Gruss und Danke
willem

Hallo Rainer, hallo Willem,

ja das Script funktioniert &#133; aber nur mit "normalen" Skalierungswerten.

Wenn sie aus dem Rahmen fallen (z.B. x = 68, y = 70 oder x = 131, y = 128), dann erfolgt keine Reaktion. Der Fehler liegt in den beiden Zeilen &#133;
---
if GroesseX < 70 then
  if GroesseY < 70 then
---
Die erste Zeile fängt den zu kleinen x-Wert von 68 ab, aber weil der y-Wert in Ordnung ist, wird nicht eingeschritten. Das Script "glaubt", dass die Werte okay sind.

Man sollte deshalb die vier Vergleiche in eine einzige Befehlszeile packen. Immer mit dem Operatoren 'or' (= oder) dazwischen. Wenn nur ein Vergleich zutrifft wird die folgende Aktion ausgelöst.

Das eventuell notwendige Ändern der Bildgrösse und des Versatzes kann ebenfalls mit einem Einzeiler vorgenommen werden.
---
tell document 1 of application "QuarkXPress 4.11"
  repeat with i from 1 to count of picture boxes
    tell picture box i
      tell image 1
        set {y, x} to scale as list
        set y to y as real
        set x to x as real
        if y < 70 or y > 130 or x < 70 or x > 130 then
          set properties to {scale:{100, 100}, offset:{0, 0}}
        end if
      end tell
    end tell
  end repeat
end tell
---
Hans Haesler <hsa@ringier.ch>