Ich muß über einen 200seitigen Katalog die Textrahmenoption "Erste Grundlinie" auf "Grossbuchstabenhöhe" ändern.
Gibt es hiefür eine automatische Funktion bzw. ist dies
über AppleScript möglich (oder besitzt jemand ein funktionierendes Script, das dies ermöglicht)?

Vielen Dank im voraus für eventuelle Hilfe.

Hans

das ist sicherlich über ein skript möglich, aber vorher die frage: sind die textrahmen auf der musterseite vorbereitet? in dem fall würde man die änderung einfach einmal auf der musterseite machen.

ansonsten:


tell application "InDesign 2.0.2"


set aDoc to active document
set nSpreads to count spreads in active document
set allSpreads to spreads in aDoc
activate

repeat with aSpread in allSpreads
set active spread of active window to aSpread
zoom active window given fit spread

set allItems to page items of aSpread
tell me to checkItems(allItems)
end repeat
end tell


on checkItems(theseItems)
repeat with anItem in theseItems
tell application "InDesign 2.0.2"
if visible of item layer of anItem then
if page items of anItem is not {} then
tell me to checkItems(page items of anItem)
else if class of anItem is text frame then
set first baseline offset of text frame preferences of anItem to cap height -- ascent offset, leading offset, embox height, x height, fixed height
set minimum first baseline offset of text frame preferences of anItem to 0
end if
end if
end tell
end repeat
end checkItems



das skript ändert JEDEN textrahmen der datei.

Vielen, vielen Dank für die rasche und
vor allem effiziente Hilfe,
es ist genau die Lösung meines Problems.

Hans