Zur Abwechslung mal was Nützliches …

Erst ab der Version 5 von QuarkXPress können die vier Werte für den Textabstand einzeln geändert werden.

Mit folgendem Script gelingt dies aber schon mit QuarkXPress 3.32 und 4.11:
---
tell document 1 of application "QuarkXPress 4.11"
  activate
  try
    set {y1, x1, y2, x2} to text inset of current box as list
  on error
    display dialog "Eine einzelne Textbox auswählen." buttons "OK" default button 1 with icon 0
    error number -128
  end try
  set oldInset to (y1 as point units as string) & ",  " & (x1 as point units as string) & ",  " & ¬
    (y2 as point units as string) & ",  " & (x2 as point units as string)
  set newInset to text returned of (display dialog "Textabstand
oben | links | unten | rechts" default answer oldInset)
  set newList to {}
  set AppleScript's text item delimiters to {",  "}
  repeat with i from 1 to 4
    set end of newList to text item i of newInset
  end repeat
  set AppleScript's text item delimiters to {""}
  tell current box
    set text inset to newList
  end tell
end tell
---
Zuerst wird versucht, die vier Textabstands-Werte in die Liste {y1, x1, y2, x2} zu setzen. Das Ergebnis ist eine Liste von vier Elementen, welche wie Textketten aussehen --> {"0 mm", "0 mm", "0 mm", "0 mm"}. Die Masseinheiten entsprechen jenen, welche in den Dokumentvorgaben eingestellt sind. Die Werte sehen wie Textketten aus, ihre 'class' ist aber 'vertical measurement' und 'horizontal measurement'. Einzeln können sie in einem Dialog angezeigt werden, aber sobald man einen zweiten Wert dazunimmt, kommt die Fehlermeldung, dass sie nicht in einen String verwandelt werden können.

Man muss also die Umwandlung einzeln vornehmen. Mit '(y1 as point units as string)' wird der Wert in Punkte umgerechnet, der Vorgabe-Masseinheit der Dialog-Textfeldes "Objekt/Modifizieren.../Text/Textabstand". Gleichzeitig geschieht die Umwandlung in eine Textkette.

Diese Liste mit den aktuellen Werten wird im Dialog gezeigt. Der Anwender kann die Werte einzeln ändern. Auf "OK" wird der Text, welcher im Resultat des Dialoges zurückkommt, in eine neue Liste geschrieben. Dazu müssen die 'text item delimiters' – die Text-Elemente-Trenner – auf ein Komma und nachfolgendem Zwischenraum geändert werden. Im Script benutze ich sogar zwei Zwischenräume = {",  "}. Damit ist die Zeile besser ausgeglichen, weil XPress zwischen der Zahl und der Masseinheit ein Halbgeviert setzt.

Die Variable 'newList' ist als leere Liste initialisiert worden, damit in der folgenden Repeat-Schleife die Textelemente einzeln daran angehängt werden können. Die 'text item delimiters' werden wieder auf einen leeren String zurückgesetzt {""} und der Textabstand der ausgewählten Box wird geändert.

Aufgepasst: es ist keine Kontrolle eingebaut, ob die eingegebenen Wert möglich sind. Wenn zum Beispiel durch einen Tippfehler der linke Abstand grösser ist, als die Boxenbreite, dann blinkt der Cursor ausserhalb der leeren Box. Wenn die Box Text enthält, dann verschwindet dieser und nur das Überflusszeichen ist sichtbar. Bei übertrieben grossen Werten kommt eine Fehlermeldung. Diese Probleme könnte man mit einem entsprechenden Test vermeiden, aber solch ein "error trapping" wird rasch ziemlich aufwendig.

Hans Haesler <hsa@ringier.ch>