Connect failed: Connection timed out

[GastForen Programmierung/Entwicklung AppleScript Photoshop Pfade Kopieren

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Photoshop Pfade Kopieren

HFPatzi
Beiträge gesamt: 37

24. Feb 2012, 08:51
Beitrag # 31 von 44
Beitrag ID: #490681
Bewertung:
(7379 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
ja, da ist wohl etwas die euphorie mit mir durchgegangen ;-)


als Antwort auf: [#490679]
X

Photoshop Pfade Kopieren

dobi-lee
Beiträge gesamt: 9

10. Dez 2013, 12:54
Beitrag # 32 von 44
Beitrag ID: #520787
Bewertung:
(7049 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Patzi, das ist genau das, was ich jetzt suche. Leider weiß ich nicht, was ich wo ändern muss im Script, um das bei mir zum Laufen zu bekommen.

PhotoShop CS6, Intel iMac
RGB JPGs im Original mit den Pfaden, HighRes-TIFs, wo die Pfade reinsollen.

Kannst du mir helfen?
Gruß

Dobi-Lee


als Antwort auf: [#490577]

Photoshop Pfade Kopieren

Hans Haesler
  
Beiträge gesamt: 5826

10. Dez 2013, 15:51
Beitrag # 33 von 44
Beitrag ID: #520802
Bewertung:
(7000 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Dobi-Lee,

ich weiss nicht, ob Patzi und Hans-Gerd hier mitlesen. Deshalb meine Fragen:

Wie hast Du versucht, das Script zu benutzen?
Lauten die Endungen auch ".jgp" und ".tif"?
Liegen die Dateien im selben Ordner?

Würdest Du mir bitte zwei kleine Musterdateien zustellen?

Gruss, Hans


als Antwort auf: [#520787]

Photoshop Pfade Kopieren

dobi-lee
Beiträge gesamt: 9

10. Dez 2013, 16:28
Beitrag # 34 von 44
Beitrag ID: #520810
Bewertung:
(6989 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,
ich habe bei CS6 über Datei-Skripten-durchsuchen die .jsx ausgewählt.
Die .jpg enthalten die benötigten Pfade,
die .tif sollen sie bekommen (also: ja, das Suffix ist korrekt).
Im selben Ordner hatte ich noch nichts liegen, da ich gar nicht weiß, wo und wie ich einen Ordner angeben kann :-(
Ich bin Skript-technisch ein Unwissender ;-)

anbei 2 Dateien zum Check. (das .tif musste ich auch als .jpg abspeichern und von CMYK in RGB wandeln, da ich es sonst nicht hochladen kann ... Das ist die Datei, die die Pfade bekommen soll.)

Danke schon mal ...Gruß
Dobi-Lee


als Antwort auf: [#520802]
Anhang:
J1371_J1161_J1394_1.jpg (113 KB)   J1371_J1161_J1394_1_tif.jpg (23.8 KB)

Photoshop Pfade Kopieren

Hans Haesler
  
Beiträge gesamt: 5826

10. Dez 2013, 17:16
Beitrag # 35 von 44
Beitrag ID: #520818
Bewertung:
(6964 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Dobi-Lee,

danke für die Dateien. Ich werde im Laufe des Abends versuchen, das Script zum Laufen zu bringen.

Zunächst ein paar Erklärungen: ".jsx" ist die Endung eines JavaScripts, welches sowohl unter Windows als auch unter Macintosh gestartet werden kann.

Das Script in der Diskussion dieses Themas hier, ist ein AppleScript. Und weil es mit on open listOfFolders einen speziellen "Handler" enthält, ist es auch ein spezielles AppleScript, nämlich ein Droplet.

Dieses muss aber im Dateiformat "Programm" gespeichert werden und bekommt dabei die Endung ".app". Im Gegensatz zu einem "gewöhnlichen" AppleScript, dessen Endung ".scpt" ist.

Mit einem Droplet muss man den Ordner, welcher die Dateien enthält, nicht "angeben", sondern auf das Icon des Scripts fallen (= to drop) lassen (= to let).

Soviel für den Moment.

Gruss, Hans


als Antwort auf: [#520810]

Photoshop Pfade Kopieren

dobi-lee
Beiträge gesamt: 9

10. Dez 2013, 17:22
Beitrag # 36 von 44
Beitrag ID: #520819
Bewertung:
(6957 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Ok, lieben Dank erst mal :-)
Gruß
DL


als Antwort auf: [#520818]

Photoshop Pfade Kopieren

Hans Haesler
  
Beiträge gesamt: 5826

10. Dez 2013, 20:30
Beitrag # 37 von 44
Beitrag ID: #520830
Bewertung:
(6917 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Dobi-Lee,

angehängt an diesen Beitrag ist das Droplet PS_PFade_kopieren.app.

Den Code habe ich aus dem Beitrag #29 übernommen, mit Kommentaren ergänzt, ein paar Variablen-Namen geändert und kleinere Verbesserungen angebracht. Unter anderem die doppelte "tell application Photoshop"-Anrede rausgenommen.

Nachstehend der gesamte Code. Wie schon gesagt, im Dateiformat "Programm" zu speichern (falls nicht die angehängte ".zip"-Datei benutzt wird).

Code
(* 
PS_PFade_kopieren.app
Dieses Droplet kopiert die Pfade einer jpg-Datei in dei entsprechende tif-Datei
*)

-- hier wird die Error.txt-Datei geschrieben
property logPath : POSIX path of (path to desktop as Unicode text)

-- der 'open'-Handler
on open listOfFolders
-- das aktuelle Trennzeichen speichern
set TID to AppleScript's text item delimiters
-- der Pfad zum aktuellen Ordner
set curFolder to (item 1 of listOfFolders) as Unicode text
-- die Namen der Dateien auflisten
set fileNameList to list folder curFolder without invisibles
-- den aktuellen Ordner und die Liste der Namen zum Handler 'processList()' schicken
processList(curFolder, fileNameList)
-- das Trennzeichen auf das gespeicherte zurücksetzen
set AppleScript's text item delimiters to TID
-- das Ende der Aktion verkünden
activate me
display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end open

-- dieser Handler arbeitet die Liste ab
on processList(curFolder, fileNameList)
set AppleScript's text item delimiters to {"."}
-- eine Schleife durch die Liste der Namen
repeat with n from 1 to count of fileNameList
-- der aktuelle Dateiname
set curPic to item n of fileNameList
-- wenn das Suffix ".jpg" ist ...
if text item -1 of curPic is "jpg" then
try
-- ... den Pfad zur Zieldatei zusammensetzen
set tifPath to ((curFolder & (text 1 thru -5 of curPic) & ".tif") as string)
-- prüfen, ob die Datei existiert
alias tifPath
-- der Pfad der Quelldatei
set jpgPath to (curFolder & curPic) as string
-- beide zum Handler 'sendToPhotoshop()' schicken
sendToPhotoshop(jpgPath, tifPath)
on error e
-- bei einem Fehler eine Meldung zeigen ...
display alert e giving up after 2
-- das Problem in die Log-Datei schreiben
do shell script "echo " & quoted form of (e) & " >> " & quoted form of (logPath & "Error.txt")
end try
end if
end repeat
end processList

-- dieser Handler behandelt die Dateien
on sendToPhotoshop(jpgPath, tifPath)
tell application "Adobe Photoshop CS6"
activate
-- die beiden Dateien öffnen
open file tifPath
open file jpgPath
-- den Variablen die beiden Dokumentnamen zuweisen
set docName1 to name of document 1
set docName2 to name of document 2
-- Name prüfen und übers Kreuz zuweisen, falls notwendig
if docName1 ends with ".jpg" then
set sourceDoc to docName1
set targetDoc to docName2
else
set sourceDoc to docName2
set targetDoc to docName1
end if
-- eine Schleife durch die Pfade des Quelldokuments
repeat with p from 1 to count of path items of document sourceDoc
-- das Quelldokument in den Vordergrund rücken
set current document to document sourceDoc
-- den aktuellen Pfad auswählen
select path item p of document sourceDoc
-- kopieren
copy
-- das Zieldokument in den Vordergrund rücken
set current document to document targetDoc
-- den Handler aufrufen, welcher den Pfad einsetzt
my pastePath()
-- die Auswahl im Zieldokument aufheben
try
deselect every path item of document targetDoc
end try
end repeat
-- das Zieldokument speichern und schliessen
close document targetDoc saving yes
-- das Quelldokument nur schliessen
close document sourceDoc saving no
end tell
end sendToPhotoshop

-- dieser Handler setzt die Pfade ein
on pastePath()
tell application "System Events"
keystroke "v" using {command down}
end tell
end pastePath

Vorbereitung: Das Droplet in einem Ordner unterbringen und von dort in Dock ziehen. Die gleichnamigen ".jpg"- und ".tif"-Dateien im denselben Ordner unterbringen. Diesen Ordner auf das Icon des Droplets ziehen.

Mit den beiden gelieferten Bilddateien funktioniert es wie erwartet.

Gruss, Hans


als Antwort auf: [#520819]
Anhang:
PS_Pfade_kopieren.zip (34.2 KB)

Photoshop Pfade Kopieren

dobi-lee
Beiträge gesamt: 9

11. Dez 2013, 08:03
Beitrag # 38 von 44
Beitrag ID: #520835
Bewertung:
(6873 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo und guten Morgen Hans :-)
Liiiiiiieben herzlichen Dank! Funktioniert einwandfrei.
Einfach herrlich, was alles möglich ist. Ich danke dir und diesem Forum für die tolle Hilfe!

Das erspart viel Zeit, Flüchtigkeits-Fehler und dadurch natürlich Kosten.
Also nochmal: vielen Dank und eine schöne Weihnachtszeit, wünscht
Dobi-Lee


als Antwort auf: [#520830]

Photoshop Pfade Kopieren

tony_danza
Beiträge gesamt: 29

26. Jul 2017, 20:46
Beitrag # 39 von 44
Beitrag ID: #558764
Bewertung:
(4328 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

lange ist es her, aber da du damals helfen konntest, hoffe ich, dass du nun auch mir helfen kannst.

Ich benötige genau dieses Script, denn bei über 1000 Bildern kann ich das einfach nicht händisch machen.

Leider funktioniert das Droplet bei mir nicht. Eine Error.txt wird nicht geschrieben aber Photoshop öffnet sich, sonst passiert nichts.

Nun verstehe ich leider nicht viel von AppleScript. Seit 2 Tagen versuche ich mit Hilfe von Lektüre den Code nachzuvollziehen und den Fehler zu finden, aber ohne Erfolg.

Der Code ist mittlerweile auch 4 Jahre alt, vielleicht hat sich mit der Zeit etwas geändert?
Wäre toll wenn du helfen kannst.

Meine Workstation:
iMac 5K Retina 27", aktuelles Betriebssystem, Photoshop CC2017

Gruss, tony


als Antwort auf: [#520830]

Photoshop Pfade Kopieren

Hans Haesler
  
Beiträge gesamt: 5826

26. Jul 2017, 22:11
Beitrag # 40 von 44
Beitrag ID: #558769
Bewertung:
(4316 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

welcome back! :-)

"aktuelles Betriebssystem" ... ist das "Sierra"? Habe ich nur auf einem Laptop zur Verfügung.

Aber Photoshop CC2017 habe ich nicht installiert. Weil ich Photoshop nur selten benutze, genügt mir CS6.

Fazit: Ich befürchte, dass ich Dir nicht helfen kann. Doch hoffentlich meldet sich ein versierter Mitleser.

Gruss, Hans


als Antwort auf: [#558764]

Photoshop Pfade Kopieren

TMA
Beiträge gesamt: 399

27. Jul 2017, 08:12
Beitrag # 41 von 44
Beitrag ID: #558774
Bewertung:
(4287 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,
ich habe das Script bei mir mal laufen lassen. Funktioniert ohne Probleme.

macOS 10.12.6, Photoshop CC 2017.1.1

Allerdings geht das nur mit einem TIF und einem JPG, wie oben beschrieben. Mit 2 JPG's geht das nicht.

Gruß, TMA


als Antwort auf: [#558769]

Photoshop Pfade Kopieren

tony_danza
Beiträge gesamt: 29

27. Jul 2017, 10:28
Beitrag # 42 von 44
Beitrag ID: #558782
Bewertung:
(4267 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,
hallo TMA,

vielen Dank für eure Antworten.

Und bei dir funktioniert das @TMA?

Versteh ich nicht, ich habe die gleiche OS Version und die gleiche PS Version.

Muss ich denn in dem Script noch irgendwas abändern bzw. definieren?
Bspw. einen Pfad zu meinem Schreibtisch definieren?
Oder ist das schon definiert in dieser Zeile:
property logPath : POSIX path of (path to desktop as Unicode text)

Denn wenn ich den Code kopiere, als Programm speicher und dann einen Ordner mit 1 x .jpg und 1 x .tif mit identischen Namen auf das Droplet ziehe, dann passiert egtl. nichts, außer dass Photoshop sich öffnet.

Dasselbe passiert auch, wenn ich die ZIP von Hans verwende.

Wäre toll wenn du mir helfen kannst @TMA.

Gruß, tony


als Antwort auf: [#558774]

Photoshop Pfade Kopieren

TMA
Beiträge gesamt: 399

27. Jul 2017, 10:45
Beitrag # 43 von 44
Beitrag ID: #558786
Bewertung:
(4254 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,
wenn ich das richtig gelesen habe, muss das Script sich auch in dem Ordner befinden.
Aber wie gesagt bei mir läuft das Script.

Diese property:
Code
property logPath : POSIX path of (path to desktop as Unicode text) 

ist nur für den Speicherort der Logdatei zuständig. Also auf dem Schreibtisch (path to desktop).

Gruß
TMA


als Antwort auf: [#558782]
(Dieser Beitrag wurde von TMA am 27. Jul 2017, 10:46 geändert)

Photoshop Pfade Kopieren

tony_danza
Beiträge gesamt: 29

27. Jul 2017, 11:13
Beitrag # 44 von 44
Beitrag ID: #558790
Bewertung:
(4243 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo TMA,

danke für deinen Beitrag, hilft mir leider nicht wirklich weiter.

Ich beschreibe mal was ich mache:

• Automator öffnen
• neues Programm
• Aktion (AppleScript ausführen) in das Feld bewegen, um einen Arbeitsablauf zu erstellen
• ich entferne den voreingestellten Code
Code
on run {input, parameters} 

(* Your script goes here *)

return input
end run

• füge den Code von Hans ein
• speicher das Droplet in einem Ordner auf dem Schreibtisch
• ziehe von diesem Ordner aus das Droplet in mein Dock
• platziere das gleichnamige JPG und TIF (test.jpg und test.tif) in diesem Ordner
• Ziehe den Ordner auf das Droplet
• Photoshop öffnet sich, sonst passiert nichts.

Erkennt hier jemand den Fehler?

Danke und Gruß
tony


als Antwort auf: [#558786]
X