[GastForen Programmierung/Entwicklung AppleScript löschen von Bilder mit TAG und anderem Dateiformat

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

löschen von Bilder mit TAG und anderem Dateiformat

sunseeker1982
Beiträge gesamt: 2

15. Jul 2019, 18:33
Beitrag # 1 von 4
Bewertung:
(5210 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo,

ich bin mir nicht sicher ob es überhaupt funktioniert. Folgendes "Problem":

Ich habe Bilder in JPG und RAW Dateiformat. Beide Dateien heißen bis auf die Endung (.JPG, .RAW) gleich. Ich habe die Bilder in einem Ordner mit jeweils zwei Unterordnern (einen für JPG, einen für RAW) gespeichert.
Nachdem ich die JPG Bilder gesichtet habe, bekommen die, die ich löschen möchte einen TAG von mir. Es ist in der Regel die rote Markierung.
Wenn ich dies markiert habe, hätte ich gerne ein Skript, dass die roten JPGs und die zugehörigen RAW Dateien löscht.
Ist so etwas möglich? Leider habe ich noch nicht viel Erfahrung mit AppleScript.

macOS ist Mojave in Version 10.14.5
X

löschen von Bilder mit TAG und anderem Dateiformat

Hans Haesler
  
Beiträge gesamt: 5826

15. Jul 2019, 22:07
Beitrag # 2 von 4
Beitrag ID: #571108
Bewertung:
(5193 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo sunseeker1982,

herzlich willkommen im AppleScript-Forum auf HilfDirSelbst! :-)

Zum Herausfinden, welcher Index eine eingefärbte Datei hat: Die Datei auswählen und dieses Hilfs-Script starten:

Code
tell application "Finder" 
set curFile to selection as Unicode text
set curLabel to label index of file curFile
end tell

Folgendes Script sollte funktionieren. Für "Rot" wird der Index 2 verwendet. In der Zeile 'if curLabel is 2 then'.
Der Anwender wird aufgefordert, nacheinander den JPG-Ordner und den RAW-Ordner zu wählen.

Code
# den JPG-Ordner wählen 
set jpgFolder to (choose folder with prompt "Den JPG-Ordner wählen") as Unicode text
# den RAW-Ordner wählen
set rawFolder to (choose folder with prompt "Den RAW-Ordner wählen") as Unicode text

# die Namen der Dateien auflisten ...
set jpgFiles to list folder jpgFolder without invisibles
# ... und zöhlen
set nFiles to count jpgFiles

# die RAW-Namensliste initialisieren
set delList to {}

# eine Schleife durch die Dateien
repeat with n from 1 to nFiles
tell application "Finder" to set curFile to file (item n of jpgFiles) of folder jpgFolder
tell application "Finder" to set curLabel to get label index of curFile
# wenn der Tag dem erwarteten entspricht ...
if curLabel is 2 then
# im aktuellen Namen "jpg" durch "raw" ersetzen und die Liste ergänzen
set end of delList to ((text 1 thru -4 of item n of jpgFiles) & "raw") as string
# die JPG-Datei entfernen
tell application "Finder" to delete curFile
end if
end repeat

# die Anzahl Namen speichern
set nDel to count delList

# eine Schleife durch die Namen
repeat with n from 1 to nDel
try
# die entsprechende RAW-Datei entfernen
tell application "Finder" to delete file (item n of delList) of folder rawFolder
end try
end repeat

# dem Anwender das Ende der Aktion verkünden
display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 2

Die Kommentare im Script erklären kurz, was gerade passiert. Hier klappt es wie erwartet mit "High Sierra".

Gruss, Hans


als Antwort auf: [#571107]

löschen von Bilder mit TAG und anderem Dateiformat

sunseeker1982
Beiträge gesamt: 2

17. Jul 2019, 12:11
Beitrag # 3 von 4
Beitrag ID: #571123
Bewertung:
(5120 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

erstmal vielen dank für deine Arbeit. Ich kam erst heute dazu das Skript zu testen. Und ich muss sagen es funktioniert einwandfrei. Ich musste nur eine Kleinigkeit ändern, das war aber mein Fehler da die RAW Dateien nicht RAW sonder AWR sind. Aber das habe ich hinbekommen und es funkitoniert.

1000 Dank für deine Hilfe, das nimmt mir viel Arbeit ab bei sortieren.


als Antwort auf: [#571108]

löschen von Bilder mit TAG und anderem Dateiformat

Hans Haesler
  
Beiträge gesamt: 5826

17. Jul 2019, 12:42
Beitrag # 4 von 4
Beitrag ID: #571124
Bewertung:
(5116 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo sunseeker1982,

bitte sehr. Ich bedanke mich für Deine Rückmeldung. Super, dass es (fast) auf Anhieb klappte.
Gut, dass Du die Anpassung hinbekommen hast.

Antwort auf: (...) das nimmt mir viel Arbeit ab bei sortieren.

Das wäre doch eine Spende ans Forum wert. :-)
https://www.hilfdirselbst.ch/...o=payment_donation;% ;-)

Nota bene: Davon bekomme ich keinen Cent. Im Gegenteil: Ich spende selber jedes Jahr CHF 100.–
Doch das ist es mir wert, allein schon, weil das Forum ein wertvolles "Nachschlagewerk" ist.

Gruss, Hans


als Antwort auf: [#571123]
X