(* 
DateienKopieren_02d.scpt 
*) 
 
-- die Textdatei wählen 
set txtFile to choose file with prompt "Die Textdatei wählen" 
 
-- den Quell- und den Zielordner wählen 
set sourceFolder to choose folder with prompt "Den Quellordner wählen" as Unicode text 
set targetFolder to choose folder with prompt "Den Zielordner wählen" as Unicode text 
 
-- die Textdatei einlesen und die Absätze einer Liste zuweisen  
set namesList to paragraphs of (read txtFile) 
set nNames to count of namesList 
 
-- eine Liste initialisieren 
set notFoundList to {} 
 
-- eine Schleife durch die Liste  
repeat with n from 1 to nNames 
  set curName to item n of my namesList 
  -- sich vergewissern, dass der Name nicht leer ist 
  if curName is not "" then 
    set curFile to (sourceFolder & curName) as text 
    tell application "Finder" 
      try 
        duplicate curFile to folder targetFolder with replacing 
      on error 
        -- wenn nicht gefunden, den Namen an die Liste hängen  
        set end of notFoundList to curName 
      end try 
    end tell 
  end if 
end repeat 
 
-- die Anwenderin informieren 
set nProb to count of notFoundList 
if nProb is 0 then 
  display dialog "Alle Dateien sind kopiert." buttons "OK" default button 1 with icon 1 
else 
  -- sonst die Logdatei definieren 
  set logPath to ((path to desktop as Unicode text) & "NotFound.txt") as string 
  set AppleScript's text item delimiters to return 
  set aString to every item of notFoundList as string 
  set AppleScript's text item delimiters to {""} 
  if nProb is 1 then 
    display dialog "Eine Datei nicht gefunden." buttons "OK" default button 1 with icon 2 
  else 
    display dialog "" & nProb & " Dateien nicht gefunden." buttons "OK" default button 1 with icon 2 
  end if 
  -- die Namen in die Logdatei schreiben 
  try 
    open for access file logPath with write permission 
    write aString to file logPath starting at 0 
    close access file logPath 
  on error 
    try 
      close access file logPath 
    end try 
  end try 
end if 

(*  
DateienVerschieben_03d.scpt  
*) 
 
-- die Textdatei wählen  
set txtFile to choose file with prompt "Die Textdatei wählen" 
 
-- den Quell- und den Zielordner wählen  
set sourceFolder to choose folder with prompt "Den Quellordner wählen" as Unicode text 
set targetFolder to choose folder with prompt "Den Zielordner wählen" as Unicode text 
 
-- die Textdatei einlesen und die Absätze einer Liste zuweisen   
set namesList to paragraphs of (read txtFile) 
set nNames to count of namesList 
 
-- zwei Listen initialisieren 
set defList to {} 
set notFoundList to {} 
 
-- eine Schleife durch die Liste  
repeat with n from 1 to nNames 
  set curName to item n of my namesList 
  -- sich vergewissern, dass der Name nicht leer ist 
  if curName is not "" then 
    set curFile to (sourceFolder & curName) as text 
    tell application "Finder" 
      if exists curFile then 
        -- wenn die Datei vorhanden ist, den Pfad an die definitive Liste hängen 
        set end of defList to curFile 
      else 
        -- wenn nicht gefunden, den Namen an die Nicht-gefunden-Liste hängen  
        set end of notFoundList to curName 
      end if 
    end tell 
  end if 
end repeat 
 
-- die Dateien verschieben 
if (count of defList) is not 0 then 
  try 
    tell application "Finder" to move defList to folder targetFolder with replacing 
  end try 
end if 
 
-- die Anwenderin informieren  
set nProb to count of notFoundList 
activate me 
if nProb is 0 then 
  display dialog "Alle Dateien sind verschoben." buttons "OK" default button 1 with icon 1 
else 
  -- sonst die Logdatei definieren  
  set logPath to ((path to desktop as Unicode text) & "NotFound.txt") as string 
  set AppleScript's text item delimiters to return 
  set aString to every item of notFoundList as string 
  set AppleScript's text item delimiters to {""} 
  if nProb is 1 then 
    display dialog "Eine Datei nicht gefunden." buttons "OK" default button 1 with icon 2 
  else 
    display dialog "" & nProb & " Dateien nicht gefunden." buttons "OK" default button 1 with icon 2 
  end if 
  -- die Namen in die Logdatei schreiben  
  try 
    open for access file logPath with write permission 
    write aString to file logPath starting at 0 
    close access file logPath 
  on error 
    try 
      close access file logPath 
    end try 
  end try 
end if