[GastForen Programmierung/Entwicklung AppleScript AS in Verbindung von XPress 4.11 und Photoshop CS

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

6. Okt 2004, 13:43
Beitrag # 1 von 15
Bewertung:
(2746 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo,
folgende Aufgabenstellung:
- XPress Dok. öffnen
- alle Bilder mit der Endung"_XY05" in Photoshop CS öffnen
- Photoshop Aktionen ausführen
- Bilder sichern in Ordner "xyz"
- Bilder schließen
- Xpress Dok. schließen

Alles sollte per AppleScript angestoßen werden. Entweder per Hotfolder oder per Doppelklick.

XPress 4.11 läuft im Classic Modus, Photoshop CS auf X.

Hat schon einmal jemand so etwas "gebaut", oder hat eine Idee?

Gruß
Uwe
X

AS in Verbindung von XPress 4.11 und Photoshop CS

Hans Haesler
  
Beiträge gesamt: 5816

6. Okt 2004, 14:47
Beitrag # 2 von 15
Beitrag ID: #419087
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

happig, Deine Aufgabenstellung... Aus Erfahrung weiss ich, dass das Anstossen von Aktionen
aus einem AppleScript heraus problematisch sein kann. Aber das war mit Photoshop 6.

Ich warte immer noch auf mein CS-Upgrade. Doch werde ich morgen mit Photoshop 7
versuchen, etwas zu entwickeln.

Morgen, weil ich die beiden Ferientage einziehe, welche ich für den AppleScript-Kurs
reserviert hatte. Dieser fällt aber aus, weil nicht genügend Anmeldungen eingegangen sind …

Hans Haesler <[email protected]>


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

6. Okt 2004, 17:49
Beitrag # 3 von 15
Beitrag ID: #419088
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

diese Aufgabenstellung hat nicht zufällig was mit den Beschneidungspfaden zu tun, oder?

Ansonsten wäre das ärgerlich ...

Karsten


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

6. Okt 2004, 19:12
Beitrag # 4 von 15
Beitrag ID: #419089
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Karsten,
nein keineswegs. Hier handelt es sich um eine andere Baustelle. Aber da ich meinem Kollegen jetzt mit deiner Hilfe diesen tollen Workflow gebastelt habe, kommt nun ein anderer mit ähnlichen Gedankengängen, in dem aber die Sache mit den Beschneidungspfaden nicht zu tragen kommt.

Aber vielen Dank nochmal für deine perfekte Anleitung

Uwe


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

6. Okt 2004, 20:13
Beitrag # 5 von 15
Beitrag ID: #419090
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

aber es kommt erneut ein Kollege "mit Gedankengängen" &#133;

Im Gegensatz zu der ClipppingPath-Frage beginnt das Prozedere ja nicht im Dateisystem, sondern in QXP.

Folglich könnte - ja was eigentlich - &#133;?
Tut es sehr weh, die Anforderungen GENAU zu definieren?

Karsten


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

6. Okt 2004, 20:34
Beitrag # 6 von 15
Beitrag ID: #419091
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi Karsten,
folgende Anforderungen:
Aus einem aktuellen Katalog sollen alle Bilder mit der Kennung FS05 (Frühjahr-Sommer05) ausgelesen werden. Diese Bilder müßen einem Dienstleister zur Erstellung von Internetseiten zur Verfügung gestellt werden. Die Bilder werden ganz einfach rechteckig begrenzt ohne Freisteller und sonstigen Firlefanz abgegeben (in drei Größen). Da natürlich sehr viele Bilder mit der Kennung FS05 existieren, ist der Weg über das entgültige XPress der Eleganteste; meiner Meinung nach.
Ich kann natürlich auch alle Bilder mit Flightcheck sammeln lassen und alle die kein FS05 enthalten löschen. Aber da ist mir immer noch zu viel manueller Eingriff von Nöten.
Wenn noch mehr Info benötigt wird, kannst Du dich gerne bei mir melden.
Gruß und einen schönen Abend wünscht Dir
Uwe


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

6. Okt 2004, 20:58
Beitrag # 7 von 15
Beitrag ID: #419092
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

aus XY wurde kurzerhand FS und die Tatsache, dass 3 Größen benötigt werden hat ja auch was &#133;

Zitat Die Bilder werden ganz einfach rechteckig begrenzt ohne Freisteller und sonstigen Firlefanz abgegeben

Der sichtbare Ausschnitt im QXP-Layout ist folglich irrelevant &#133;

Hans macht das schon ;-)


Karsten


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Hans Haesler
  
Beiträge gesamt: 5816

7. Okt 2004, 12:22
Beitrag # 8 von 15
Beitrag ID: #419093
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
@ Karsten: Danke für die Vorarbeit! ;-)


Hallo Uwe,

nun, fürs erste komme ich mit einer Lösung, welche nur halbautomatisch ist. Der Vorteil
ist aber, dass die Aktionen geradlinig, ohne konfliktbeladene Überschneidungen ablaufen.

Mein Vorschlag: ein Droplet, auf welches die XPress-Dokumente gezogen werden. Das Script
fordert auf, einen Zielordner zu bestimmen. Dann öffnet es ein Dokument nach dem andern,
erstellt eine Liste der "FS05"-Bilder und kopiert sie in den gewählten Ziel-Ordner.

Danach kann man aus Photoshop die Aktion starten.

Den folgenden Code als Applikation sichern:
---
property targetFolder : ""
global filePath

script copyImages
  global imageList
  set imageList to {}
  tell application "QuarkXPress 4.11"
    activate
    open alias filePath use doc prefs yes remap fonts no do auto picture import no
    tell document 1
      repeat with i from 1 to count of picture boxes
        set curPath to (file path of image i) as string
        if curPath ends with "FS05" then
          set end of imageList to curPath
        end if
      end repeat
    end tell
  end tell
  if imageList is not {} then
    tell application "Finder" to activate
    repeat with i from 1 to count of imageList
      try
        tell application "Finder" to duplicate file (item i of my imageList) to &not;
          folder targetFolder with replacing
      end try
    end repeat
  end if
  tell application "QuarkXPress 4.11"
    close document 1 saving no
  end tell
end script

on open droppedObjects
  if targetFolder = "" then
    set dR to (display dialog "Der Ziel-Ordner für die &raquo;FS05&laquo;-Bilder
ist nicht bekannt." buttons {"Abbruch", "Zuweisen"} default button 2 with icon 2)
    if button returned of dR = "Zuweisen" then
      set targetFolder to (choose folder with prompt &not;
        "Den Ziel-Ordner für die &raquo;FS05&laquo;-Bilder bestimmen.") as string
    else
      error number -128
    end if
  end if
  repeat with anObject in droppedObjects
    if (anObject as string) ends with ":" then
      set fileList to list folder anObject without invisibles
      repeat with aFile in fileList
        set filePath to (anObject & aFile) as string
        set fileType to file type of (info for file filePath)
        if fileType = "XDOC" then
          tell application "QuarkXPress 4.11"
            do script {copyImages}
          end tell
        end if
      end repeat
    else
      set filePath to anObject as string
      set fileType to file type of (info for file filePath)
      if fileType = "XDOC" then
        tell application "QuarkXPress 4.11"
          do script {copyImages}
        end tell
      end if
    end if
  end repeat
  activate
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end open
---
Übrigens: Wenn ich "Classic Modus" höre, dann sträuben sich bei mir die Nackenhaare &#133;
Deshalb habe ich das Script zuerst unter Mac OS 9 entwickelt. Aber dann habe ich mich
überwunden und das Script auch unter Mac OS X getestet: Es funktioniert hervorragend!

Hans Haesler <[email protected]>


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

11. Okt 2004, 09:11
Beitrag # 9 von 15
Beitrag ID: #419094
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Guten Morgen Hans,
ich habe das Script gerade ausprobiert. Es läuft super. Natürlich habe ich in meiner Beschreibubg für Karsten etwas wichtiges vergessen: :oops:
In dem XPress Dokument sind natürlich "Lay"-Bilder geladen. Die dazugehörigen Feinbilder liegen ein Verzeichniss höher. Kann man den Schritt auch noch einbauen, das die Fein- und nicht die Grobdaten kopiert werden?
Gruß und Danke
Uwe


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Hans Haesler
  
Beiträge gesamt: 5816

11. Okt 2004, 09:40
Beitrag # 10 von 15
Beitrag ID: #419095
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

ja, den Schritt kann man einbauen. Aus Deiner Schilderung lese ich heraus, dass die Grobbilder in einem Ordner
namens "layouts" liegen. Aus Erfahrung weiss ich, dass bei bestimmten Dateitypen dabei das Suffix geändert
wird. Aber weil die Bilddateien, welche uns interessieren, mit "FS05" enden, haben sie folglich kein Suffix. Uff!!!

Bitte bestätige meine Annahme, dass der Ordner "layouts" heisst.

Hans Haesler <[email protected]>


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

11. Okt 2004, 09:45
Beitrag # 11 von 15
Beitrag ID: #419096
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,
das ist richtig. Die Grobdaten liegen in einenm Ordner Namens "lauouts".
In diesem Fall enthalten die Bilddaten aber kein Suffix. Die Bilder heißen einfach z.B. "022547 41_FS05".

Gruß
Uwe


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Hans Haesler
  
Beiträge gesamt: 5816

11. Okt 2004, 10:35
Beitrag # 12 von 15
Beitrag ID: #419097
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

gut. In diesem Fall ist die Änderung recht einfach. Die einzelnen Elemente des Pfades sind mit Doppelpunkten
abgegrenzt. Deshalb werden die 'text item delimiters' von AppleScript zuerst auf {":"} gesetzt. Zum Entfernen
des "layouts"-Ordners setzt man den Pfad neu zusammen. Man nimmt dazu die Elemente 1 bis -3 (also vom
ersten bis zum drittletzten) und das Element -1 (der Bildname):
Code
set finePath to ((text items 1 thru -3 of curPath) & (text item -1 of curPath)) as string 

Nach dem Ende der Repeat-Schleife werden die 'text item delimiters' wieder auf {""} zurückgesetzt. Die Änderung
betrifft nur das Script-Objekt "copyImages". Bitte ersetze dieses im Script durch den folgenden Code:
---
script copyImages
  global imageList
  set imageList to {}
  tell application "QuarkXPress 6.1"
    activate
    open alias filePath use doc prefs yes remap fonts no do auto picture import no
    set AppleScript's text item delimiters to {":"}
    tell document 1
      repeat with i from 1 to count of picture boxes
        set curPath to (file path of image i) as string
        if curPath ends with "FS05" then
          set finePath to &not;
            ((text items 1 thru -3 of curPath) & (text item -1 of curPath)) as string
          set end of imageList to finePath
        end if
      end repeat
    end tell
    set AppleScript's text item delimiters to {""}
  end tell
  if imageList is not {} then
    tell application "Finder" to activate
    repeat with i from 1 to count of imageList
      try
        tell application "Finder" to duplicate file (item i of my imageList) to &not;
          folder targetFolder with replacing
      end try
    end repeat
  end if
  tell application "QuarkXPress 6.1"
    close document 1 saving no
  end tell
end script
---

Hans Haesler <[email protected]>


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

11. Okt 2004, 13:33
Beitrag # 13 von 15
Beitrag ID: #419098
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,
es funktioniert mal wieder tadellos. Nun werde ich mal versuchen den zugewiesenen "FS05"-Ordner mit einer Ordneraktion zu belegen. Vielleicht klappt das ja.

Vielen Dank
Uwe


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Hans Haesler
  
Beiträge gesamt: 5816

11. Okt 2004, 14:21
Beitrag # 14 von 15
Beitrag ID: #419099
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Uwe,

an Deiner Stelle würde ich ganz einfach die Aktion aus Photoshop heraus starten.
Denn wenn dies von einer Ordneraktion aus gemacht wird, dann gibt es garantiert
Probleme beim Sichern.

Eine Variante: Die Photoshop-Aktion in ein Droplet verwandeln und den "FS05"-
Ordner darauf ziehen.

Hans Haesler <[email protected]>


als Antwort auf: [#419086]

AS in Verbindung von XPress 4.11 und Photoshop CS

Anonym
Beiträge gesamt: 22827

11. Okt 2004, 15:22
Beitrag # 15 von 15
Beitrag ID: #419100
Bewertung:
(2745 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi Hans,
ja ich habe gemerkt, das das mit dem überwachten Ordner nicht so ganz einfach ist.
Die Sache per Droplet zu lösen ist sicherlich eleganter und sicherer.


Uwe


als Antwort auf: [#419086]
X

Aktuell

PDF / Print
Wolken_300

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
08.11.2022

Frankfurt, Fraport Conference Center
Dienstag, 08. Nov. 2022, 13.30 - 18.00 Uhr

Seminar

Auf der Enfocus World Tour stellen wir Ihnen gemeinsam mit Enfocus die aktuellen Highlights von Enfocus Switch und dem Impressed Workflow Server (IWS) vor. Wir präsentieren Ihnen anhand typischer Aufgabenstellungen in einem modernen Produktionsbetrieb die Möglichkeiten, die Enfocus Switch für die Automatisierung und Standardisierung von Abläufen bietet. Wir haben sowohl für Produktionsverantwortliche als auch technisch Interessierte ein spannendes Programm vorbereitet, bei dem Sie sicherlich viel Neues erfahren werden, welches Sie in Ihrem eigenen Betrieb umsetzen können. Die Veranstaltung bietet darüber hinaus eine hervorragende Möglichkeit, sich mit anderen Anwendern und Workflow-Spezialisten auszutauschen und Antworten auf konkrete Aufgabenstellungen zu erhalten, welche Sie mit Hilfe von Enfocus Switch/IWS umsetzen möchten.

Wir sind jeweils an 2 Tagen in Frankfurt, Hamburg und München vor Ort. Der erste (halbe) Tag richtet sich in erster Linie an Betriebsleiter und Produktionsverantwortliche in Druckereien - ist also weniger technisch orientiert - sondern gibt einen Überblick zu den heutigen Möglichkeiten einer automatisierten Produktion.

Der zweite Tag (Switch Anwender-Treffen) richtet sich an bestehende Switch-Anwender und Administratoren.

Anmeldung und weitere Infos: https://www.impressed.de/schulung.php?c=sDetail&sid=310

Ja

Organisator: Enfocus/Impressed

Kontaktinformation: Silvia Noack, E-Mailsnoack AT impressed DOT de

https://www.impressed.de/schulung.php?c=sDetail&sid=310

Enfocus World Tour 2022
Veranstaltungen
08.11.2022

Frankfurt, Fraport Conference Center
Dienstag, 08. Nov. 2022, 13.30 - 18.00 Uhr

Seminar

Auf der Enfocus World Tour stellen wir Ihnen gemeinsam mit Enfocus die aktuellen Highlights von Enfocus Switch und dem Impressed Workflow Server (IWS) vor. Wir präsentieren Ihnen anhand typischer Aufgabenstellungen in einem modernen Produktionsbetrieb die Möglichkeiten, die Enfocus Switch für die Automatisierung und Standardisierung von Abläufen bietet. Wir haben sowohl für Produktionsverantwortliche als auch technisch Interessierte ein spannendes Programm vorbereitet, bei dem Sie sicherlich viel Neues erfahren werden, welches Sie in Ihrem eigenen Betrieb umsetzen können. Die Veranstaltung bietet darüber hinaus eine hervorragende Möglichkeit, sich mit anderen Anwendern und Workflow-Spezialisten auszutauschen und Antworten auf konkrete Aufgabenstellungen zu erhalten, welche Sie mit Hilfe von Enfocus Switch/IWS umsetzen möchten.

Wir sind jeweils an 2 Tagen in Frankfurt, Hamburg und München vor Ort. Der erste (halbe) Tag richtet sich in erster Linie an Betriebsleiter und Produktionsverantwortliche in Druckereien - ist also weniger technisch orientiert - sondern gibt einen Überblick zu den heutigen Möglichkeiten einer automatisierten Produktion.

Der zweite Tag (Switch Anwender-Treffen) richtet sich an bestehende Switch-Anwender und Administratoren.

Anmeldung und weitere Infos: https://www.impressed.de/schulung.php?c=sDetail&sid=310

Ja

Organisator: Enfocus/Impressed

Kontaktinformation: Silvia Noack, E-Mailsnoack AT impressed DOT de

https://www.impressed.de/schulung.php?c=sDetail&sid=310

Enfocus World Tour 2022