Hallo alle, hallo lieber Hans,

ich würde gerne über Applescript die Checkbox "Black" in der Ausgabevorschau (unter "Erweitert" -> "Druckproduktion" deaktivieren.

Ich vermute mal, dass ich dies unter Zuhilfenahme von Systemevents machen muss... Aber da hört mein Know How einfach auf. Hat jemand eine Idee, wie ich das machen muss? Vielen Dank für Eure Hilfe

Gruß, Edgar

Hallo lieber Edgar,

welche Version von Acrobat? Unter welcher Version des Betriebssystems?

Gruss, Hans

Hallo Hans,
Acrobat 8.1.2, OSX 10.4.11

Hallo Edgar,

da kann ich erst im Laufe des Abends versuchen, eine Lösung zu finden. Ich hoffe deshalb, dass mir ein versierter Mitleser zuvorkommen wird.

Gruss, Hans

Super, vielen Dank. Kannst Du mir nur schnell sagen, ob die Ansprache der Menüs über die deutsche Bezeichnung der Menüs funktioniert oder über die englische?

Und was verbirgt sich hinter der Meldung
„System Events“ hat einen Fehler erhalten: NSReceiverEvaluationScriptError: 4

Hallo Edgar,

es sollte mit den deutschen Namen klappen.

Leider funktioniert die Suche im Forum immer noch nicht. Sonst könntest Du gezielt nach "UI-Scripting" suchen.

Als Ersatz hier ein Link, in welchem diese Methode diskutiert wird:
http://www.page-online.de/forum/viewthread/3355/

Gruss, Hans

Soweit bin ich schonmal...

tell application "Adobe Acrobat Professional"
    activate
end tell
tell application "System Events"
    if UI elements enabled then
        tell process "Acrobat"
            try
                get every checkbox of window "Ausgabevorschau"
            on error
                click menu item "Ausgabevorschau..." of menu 1 of menu item "Druckproduktion" of menu 1 of menu bar item "Erweitert" of menu bar 1
            end try
-- die nächste Zeile funktiert nicht. Ich habe auch schon versucht, die Koordinaten dieser Box zu ermitteln und dann mit click at zu arbeiten... Geht auch nicht.
          click UI element 1 of row 1 of table 1 of scroll area 1 of group 1 of window "Ausgabevorschau"
        end tell
       
       
    else
        tell application "System Preferences"
            activate
            set current pane to pane "com.apple.preference.universalaccess"
            display dialog "UI element scripting is not enabled. Check \"Enable access for assistive devices\""
        end tell
    end if
end tell

Ich komme einfach nicht an diese komischen Checkboxen vor den Farben... Mir ist nicht klar, was Adobe da gemacht hat, denn normale Checkboxen sind das nicht...

Hallo Edgar,

zuerst ein Hinweis an alle, welche im oben angegebenen Thread auf H =:o) L G Is Link angeguckt geklickt haben und anstelle der Site die Meldung "Die Struktur von page-online.de hat sich geändert." gefunden haben.

Es genügt, im Link ...
---
http://www.page-online.de/page/forum/viewthread/3278/P15/
---
... die Zeichenfolge page/ zu entfernen ...
---
http://www.page-online.de/forum/viewthread/3278/P15/
---
... und schon ist man am Ziel.

Zu Deinem Problem. Ich nehme an, dass Du die Checkbox "Schwarze Druckfarbe simulieren" deaktivieren möchtest. Aufbauend auf Deinem geposteten Code gelingt es mir wie folgt:
---
tell application "Adobe Acrobat Professional"
   activate
end tell
tell application "System Events"
   tell process "Acrobat"
      try
         click menu item "Ausgabevorschau..." of menu 1 of menu item ¬
            "Druckproduktion" of menu 1 of menu bar item "Erweitert" of menu bar 1
      end try
      try
         if value of checkbox 1 of window 1 is 1 then
            click checkbox 1 of window 1
         end if
      end try
   end tell
end tell
---
Der Test ...
---
if value of checkbox 1 of window 1 is 1
---
... dient dazu, zu vermeiden, dass die Checkbox aktiviert wird, wenn sie nicht angekreuzt (= value 0) ist.

Gruss, Hans

Hallo Hans,

nee nee, ich will den Farbauszug für Black (Schwarz) ausblenden
Findet sich in dem Fenster wo auch Cyan, Yellow, etc. stehen...
Da siehst Du doch die etwas anders aussehenden Checkboxen, oder? Die vor Schwarz will ich ansprechen...

Hallo Edgar,

ach sooo ...

Und so hat es hier geklappt:
1. Mit dem "UI Element Inspector" die Position der Checkbox ausgelesen und zu den X- und Y-Werten ein paar Pixel dazugegeben.
2. "cliclick" auf den Schreibtisch kopiert.
3. Das Script entsprechend umgeschrieben:
---
property cliclickPath : POSIX path of file ((path to "desk" as text) & "cliclick")

tell application "Adobe Acrobat Professional"
   activate
end tell
tell application "System Events"
   tell process "Acrobat"
      try
         click menu item "Ausgabevorschau..." of ¬
            menu 1 of menu item "Druckproduktion" of ¬
            menu 1 of menu bar item "Erweitert" of menu bar 1
      end try
   end tell
   delay 1
   set clickCommand to (cliclickPath & " " & 660 & " " & 747)
   try
      do shell script clickCommand
   end try
end tell
---
Die Pause mit 'delay 1' ist wichtig. Sonst funktioniert es bestimmt nicht.

Der UI Element Inspector kann hier heruntergeladen werden: http://www.apple.com/applescript/uiscripting/02.html

cliclick findest Du hier: http://www.bluem.net/downloads/cliclick/ (bitte vergiss nicht dem Carsten eine Spende zukommen zu lassen).

Gruss, Hans

GEILOMAT!!!!

Vielen Dank, lieber Hans. Funktioniert!. Ich habe die Position jedoch nicht fest verdratet sondern ermittel die Position der Checkbox über System Events:

set theAria to position of UI element 1 of row 6 of table 1 of scroll area 1 of group 1 of window "Ausgabevorschau"
            delay 1
            set clickCommand to (cliclickPath & " " & item 1 of theAria & " " & item 2 of theAria)

Hallo Edgar,

bitteschön. Gut, dass es klappt.

Und ja, es ist natürlich besser, wenn die Position "on the fly" ermittelt wird. Denn das Fester wird nicht immer an derselben Position bleiben und dann würde der Klick ins Leere erfolgen.

Gruss, Hans