[GastForen Programme Print/Bildbearbeitung QuarkXPress Anzahl der satzzeichen in einem Textdokument

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Print/Bildbearbeitung - Photos, Layout, Design
Themen
Beiträge
Moderatoren
Letzter Beitrag

Anzahl der satzzeichen in einem Textdokument

Apfelmann
Beiträge gesamt: 36

15. Nov 2007, 18:29
Beitrag # 1 von 6
Bewertung:
(2058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo, gibt es eine Möglichkeit, in Quark 7 die Anzahl der Satzzeichen eines Textes zu erfahren?

Gruß, Apfelmann
X

Anzahl der satzzeichen in einem Textdokument

Hans Haesler
Beiträge gesamt: 5826

16. Nov 2007, 16:39
Beitrag # 2 von 6
Beitrag ID: #322768
Bewertung:
(2010 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Apfelmann,

das sollte möglich sein. Mit einem AppleScript.

Wäre der zu behandelnde Text ausgewählt? Oder die Box, welche den Text enthält? Oder sind mehrere Boxen zu berücksichtigen?

Gruss, Hans


als Antwort auf: [#322655]

Anzahl der satzzeichen in einem Textdokument

Apfelmann
Beiträge gesamt: 36

17. Nov 2007, 12:54
Beitrag # 3 von 6
Beitrag ID: #322836
Bewertung:
(1982 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo,

es handelt sich in der Regel um redaktionelle Musterseiten mit einem oder mehreren verketteten Textrahmen.

Gruß, Apfelmann


als Antwort auf: [#322768]

Anzahl der satzzeichen in einem Textdokument

Hans Haesler
Beiträge gesamt: 5826

17. Nov 2007, 15:54
Beitrag # 4 von 6
Beitrag ID: #322849
Bewertung:
(1960 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Apfelmann,

okay. Aber soll das Script den gesamten Text der aktiven Seite untersuchen? Oder wäre eine der verketteten Boxen ausgewählt und dann würde die ganze Textkette behandelt?

Welche Satzzeichen sollen berücksichtigt werden? Sicher schon mal , . ; : ! ? Aber auch Apostrophe, Bruchstriche, Klammern, Anführungszeichen, Ellipsen?

Gruss, Hans


als Antwort auf: [#322836]

Anzahl der satzzeichen in einem Textdokument

Apfelmann
Beiträge gesamt: 36

18. Nov 2007, 20:03
Beitrag # 5 von 6
Beitrag ID: #322949
Bewertung:
(1932 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

ja, das komplette Dokument inklusive alle Satzzeichen...

Gruß, Apfelmann


als Antwort auf: [#322849]

Anzahl der satzzeichen in einem Textdokument

Hans Haesler
Beiträge gesamt: 5826

18. Nov 2007, 21:34
Beitrag # 6 von 6
Beitrag ID: #322967
Bewertung:
(1923 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Apfelmann,

"alle Satzzeichen" ist mir zu nebulös... Deshalb überlasse ich es Dir, die Aufzählung in der ersten Zeile des folgenden Scripts zu ergänzen. Dann das Script speichern und in den Ordner "Scripts" des QuarkXPress-Programmordners legen, damit es als Menüartikel zur Verfügung steht.

Für den ersten Text bitte nur ein Dokument mit einer Seite benutzen. Wenn mehrere Seiten vorhanden sind, kann die Untersuchung doch ziemlich dauern.

Es ist auch möglich, etwas Text auszuwählen, oder eine Textbox. Dann werden nur die Satzzeichen der Auswahl gezählt.

Gruss, Hans

Code
set punctString to ".,:;!?-" 

tell application "QuarkXPress Passport"
activate
try
set initVar to do script {initialChecks}
if (count of initVar) = 2 then
error (item 1 of initVar) number (item 2 of initVar)
end if
set {docRef, selType} to initVar
if selType is 0 then
set nPunct to 0
tell docRef
repeat with i from 1 to count of stories
tell story i
set curCount to count (every character where it is in punctString)
end tell
set nPunct to nPunct + curCount
end repeat
end tell
else if selType is 1 then
tell current box
tell story 1
set nPunct to count (every character where it is in punctString)
end tell
end tell
else if selType is 2 then
tell selection
set nPunct to count (every character where it is in punctString)
end tell
end if

if selType is 0 then
display dialog "Das Dokument enthält
" & nPunct & " Satzzeichen." buttons "OK" default button 1 with icon 1
else
display dialog "Die Auswahl enthält
" & nPunct & " Satzzeichen." buttons "OK" default button 1 with icon 1
end if

on error errMsg number errNum
if errNum is not -128 then
display dialog errMsg buttons "OK" default button 1 with icon 0
end if
return
end try
end tell

script initialChecks
tell application "QuarkXPress Passport"
try
if not (exists document 1) then error "Bitte ein Projekt öffnen."

tell document 1
if tool mode is not contents mode then set tool mode to contents mode
set docRef to object reference
if masterdoc is true then set docRef to object reference of ¬
master document 1 of application "QuarkXPress Passport"
end tell

tell docRef
if not (exists current box) then
set selType to 0
else
tell current box
if box type is not text box type then ¬
error "Bitte eine einzelne Textbox auswählen."
end tell
try
set selText to contents of selection as text
if selText is "" then
set selType to 1
else
set selType to 2
end if
on error
set selType to 1
end try
end if
end tell
return {docRef, selType, 1}
on error errMsg number errNum
return {errMsg, errNum}
end try
end tell
end script



als Antwort auf: [#322949]
X

Aktuell

Web / SEO / Blockchain / Betriebssystem
300

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
17.04.2024

Online
Mittwoch, 17. Apr. 2024, 10.00 - 10.30 Uhr

Webinar

Komplizierte, kleinteilige Aufträge; alles sehr speziell; seit Jahren bewährte Prozesse – da können wir nichts standardisieren und automatisieren! Das sagen viele Großformatdrucker – aber stimmt das wirklich, ist dem tatsächlich so? Günther Business Solutions und Impressed treten in einem Webinar den Gegenbeweis an. Experten beider Unternehmen zeigen, wie Großformatdrucker vom Einsatz zweier bewährter Lösungen profitieren können: • von advanter print+sign von Günther Business Solutions, dem ERP-System für den Großformatdruck, dass alle Phasen der Wertschöpfung im Large Format Printing abdeckt • von Impressed Workflow Server, der smarten PDF-Workflow-Lösung für Druckereien, die Datenmanagement, Preflight und Produktionssteuerung übernimmt Über die Kombination beider Lösungen können Großformatdrucker ihre Prozesse mit modernen Workflows Schritt für Schritt automatisieren – und so zügig deutliche Zeit- und Kosteneinsparungen realisieren. Das Webinar sollten Sie sich nicht entgehen lassen – damit Sie keine Effizienzpotenziale mehr liegen lassen. Melden Sie sich am besten gleich an, wir freuen uns auf Sie! PS: Melden Sie sich in jedem Fall an – sollten Sie zum Termin verhindert sein, erhalten Sie die Aufzeichnung.

kostenlos

Ja

Organisator: Impressed / Günther Business Solutions

https://www.impressed.de/schulung.php?c=sDetail&sid=326

Und es geht doch: Automatisierung im Großformatdruck!