[GastForen Programme Print/Bildbearbeitung Adobe InDesign AppleScript: Eigenschaften von Absatzformaten ändern

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Print/Bildbearbeitung - Photos, Layout, Design
Themen
Beiträge
Moderatoren
Letzter Beitrag

AppleScript: Eigenschaften von Absatzformaten ändern

crashtron
Beiträge gesamt: 29

31. Okt 2006, 11:29
Beitrag # 1 von 6
Bewertung:
(2140 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo,

ich möchte gerne die Punktgröße von allen Absatzformaten auf einmal ändern. Das Script dafür habe ich schon geschrieben und es läuft auch ohne Fehler durch, doch Indesign ignoriert meine Änderungen einfach ;-) Vielleicht mag ja mal jemand überschauen und es ausprobieren.

Danke

Code
on setmydocument() 
try
tell application "Adobe InDesign CS2"
set myDocument to active document
end tell
on error
display dialog "Es ist kein Indesign Dokument geöffnet. Script wird beendet." buttons ("OK")
set myDocument to false
end try
return myDocument
end setmydocument

on switchUserInteractMode(myStatus)
tell application "Adobe InDesign CS2"
if myStatus is "never" then
-- Turn off user interaction to avoid dialogs
set user interaction level of script preferences to never interact
else if myStatus is "all" then
-- Revert user interaction
set user interaction level of script preferences to interact with all
end if
end tell
end switchUserInteractMode

on chooseName(myPrompttext, myAnswer)
-- Zeigt einen Texteingabedialog mit dem übergebenem Hinweistext (myPrompttext). Mit myAnswer kann man einen vorgegebenen Antworttext einstellen. Gibt den eingegebenen Text zurück.
set myName to text returned of (display dialog myPrompttext default answer myAnswer)
return myName
end chooseName

on changeFontsize(myDocument, myChangeValueFontSize)
tell application "Adobe InDesign CS2"
tell myDocument
repeat with myStyle in every paragraph style
tell properties of myStyle
set point size to point size + myChangeValueFontSize as real
end tell
end repeat
end tell
end tell
end changeFontsize

--Main
--Init-Process
switchUserInteractMode("never")

set myDocument to setmydocument()
set myChangeValueFontSize to chooseName("Bitte geben Sie einen Wert an um den die Schriftgröße geändert werden soll", "+1")
changeFontsize(myDocument, myChangeValueFontSize)

--Restore-Process
switchUserInteractMode("all")

X

AppleScript: Eigenschaften von Absatzformaten ändern

Martin Fischer
  
Beiträge gesamt: 12410

31. Okt 2006, 12:26
Beitrag # 2 von 6
Beitrag ID: #259469
Bewertung:
(2121 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Herr Crashtron,

versuchen Sie es mal mit folgendem Code:
Code
tell document 1 of application "Adobe InDesign CS2" 
set point size of paragraph styles whose name is not "[Kein Absatzformat]" to text returned of (display dialog "Schriftgröße: " default answer 10)

end tell


Viele Grüße
Martin




als Antwort auf: [#259458]

AppleScript: Eigenschaften von Absatzformaten ändern

crashtron
Beiträge gesamt: 29

31. Okt 2006, 13:00
Beitrag # 3 von 6
Beitrag ID: #259480
Bewertung:
(2115 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Danke das funktioniert schon mal, allerdings ist es nicht ganz was ich wollte. Ich will die Schriftgrößen nicht einfach alle auf das gleich setzen, sondern um einen bestimmten Wert vergrößer/verkleiner.


als Antwort auf: [#259469]

AppleScript: Eigenschaften von Absatzformaten ändern

Martin Fischer
  
Beiträge gesamt: 12410

31. Okt 2006, 13:18
Beitrag # 4 von 6
Beitrag ID: #259486
Bewertung:
(2106 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Im schlimmsten Fall müßten Sie dies über eine Schleife erledigen.

Gerald Singelmann oder Hans Haesler könnten sagen, ob es auch einfacher geht mit einem Konstrukt aus "point size of it" und mit passenden Klammern.

In JS ginge die Schleifenlösung etwa so:
Code
var myStep = prompt("Schriftgrad erhöhen um: ","0.5")*1; 
var myDoc = app.documents[0];
for (k = 1; k< myDoc.paragraphStyles.length; k++)
myDoc.paragraphStyles[k].pointSize += myStep;


Viele Grüße
Martin




als Antwort auf: [#259480]
(Dieser Beitrag wurde von Martin Fischer am 31. Okt 2006, 13:27 geändert)

AppleScript: Eigenschaften von Absatzformaten ändern

Hans Haesler
Beiträge gesamt: 5797

1. Nov 2006, 09:43
Beitrag # 5 von 6
Beitrag ID: #259604
Bewertung:
(2074 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo crashtron, hallo Martin,

der gute Gerald ist anscheinend anderweitig beschäftigt.

Zuerst zum ersten Handler. Falls kein Dokument geöffnet ist, wird dies
zwar vom Dialog gemeldet. Aber das Script fährt nach einem Klick auf
"OK" fröhlich weiter. Abhilfe: die Zeile 'error number -128' einfügen.

Code
on setmydocument() 
try
tell application "Adobe InDesign CS2"
set myDocument to active document
end tell
on error
display dialog "Es ist kein InDesign-Dokument geöffnet. Das Script wird beendet." buttons ¬
"OK" default button 1 with icon 2
error number -128
end try
return myDocument
end setmydocument

Zum eigentlichen Problem. Die Wiederholschleife sollte die Liste
der Absatzformate mit dem Zähler 'i' durchqueren und immer das
aktuelle Format adressieren (statt die Properties). Dann klappt es.
Wenn die Schleife bei '1' beginnt, muss zwingend ein 'try'-Wickel
eingefügt werden. Denn das erste Format ist "Kein Absatzformat",
welches nicht per Script verändert werden kann.

Nachstehend wird bei '3' begonnen (damit auch das Basisformat
"Einfacher Absatz" ausgeklammert wird) und der neue Wert wird
zuerst vorbereitet, bevor er zugewiesen wird:

Code
on changeFontsize(myDocument, myChangeValueFontSize) 
tell application "Adobe InDesign CS2"
tell myDocument
repeat with i from 3 to count of paragraph styles
try
tell paragraph style i
set newSize to point size + myChangeValueFontSize
set properties to {point size:newSize}
end tell
end try
end repeat
end tell
end tell
end changeFontsize

So funktioniert es hier.

Gruss, Hans


als Antwort auf: [#259486]

AppleScript: Eigenschaften von Absatzformaten ändern

Gerald Singelmann
  
Beiträge gesamt: 6247

5. Nov 2006, 13:24
Beitrag # 6 von 6
Beitrag ID: #260180
Bewertung:
(2028 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Zitat der gute Gerald ist anscheinend anderweitig beschäftigt.


Weintrinken in der Steiermark.
Ist eine hervorragende Ausrede.
Finde ich.
;)


als Antwort auf: [#259604]
X

Aktuell

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
05.02.2021 - 05.11.2021

Digicomp Academy AG, Limmatstrasse 50, 8005 Zürich
Freitag, 05. Feb. 2021, 13.00 Uhr - Freitag, 05. Nov. 2021, 17.00 Uhr

Lehrgang

Bilden Sie sich zum zertifizierten Publishing-Multimedia-Profi aus. Neben Fotografie und Video befassen Sie sich mit der Medienproduktion, digitalen Publikationen und dem Webdesign für Desktop- und mobile Endgeräte.

Preis: CHF 10'500.-
Dauer: 30 Tage (ca. 210 Lektionen) – Unterricht findet jeweils am Freitag von 13 - 19 Uhr und Samstag von 09 - 17 Uhr statt

Ja

Organisator: Digicomp Academy AG

Kontaktinformation: Kundenberater-Team, E-Mailkundenberatung AT digicomp DOT ch

digicomp.ch/d/9PM

Veranstaltungen
01.03.2021 - 05.03.2021

Persönlichkeitsentwicklung

Online
Montag, 01. März 2021, 00.17 Uhr - Freitag, 05. März 2021, 00.18 Uhr

Webinar

Personal Power Coaching - Um was geht es? ​ Potenzialentfaltung: Potenzial entdecken und entfalten Talente entdecken: Deine Talente und Fähigkeiten erkennen und loslegen Gewohnheiten: schlechte Gewohnheiten durch Positive ersetzen Selbstbewusstsein stärken: Dein Bewusstsein stärken Eigendynamik entwickeln: Mehr Erfolg durch Eigenverantwortung & Disziplin Ängste kontrollieren: Ängste als Antrieb nutzen Entscheidungen treffen: Mit mehr Mut an die Sache ran! Lebensenergie steigern: Deine Lebensenergie steigern und aufrechterhalten Ziele erreichen: Ziele setzen und übertreffen! Motivationssteigerung: Mehr Erfolg durch Selbstmotivation Selbstvertrauen: Selbstvertrauen auf- und ausbauen

Details:
https://www.snfa.ch/swiss-personal-power-birolisik

Ja

Organisator: Birol Isik

Kontaktinformation: Birol Isik, E-Mailinfo AT snfa DOT ch

https://www.snfa.ch/swiss-personal-power-birolisik

Neuste Foreneinträge


Affinity Designer

Optimierung doc2pdf-withPresets.jsx

Layout / Bildauflösung druckfertig anlegen

Affinity Publisher 1.9

Alternative Acrobat Pro

Affinity Photo

Open CL-Berschleunigung

Studiovorgaben (Workspace) beim Programmstart vorgeben?

Illustrator AI in Designer öffnen

Verknüpfung mit Format aufheben
medienjobs