Hallo,
ich probiere gerade ein Script zu schreiben, welches mir ein bei Script-aufruf ein Bild in einen aktivierten Bildrahmen in Xpress platziert.
Bisher habe ich mir mit diesem Script beholfen:
(allerdings erzeuge ich hiermit einen neuen Rahmen in dem das Bild platziert wird)
----
tell application "QuarkXPress Passport™ 4.11"
 activate
 if not (exists document 1) then
  beep
  display dialog "Kein Xpress Dokument geöffnet." buttons {"Ooooh!"} default button 1
  return
 end if
 tell document 1
  if item spread coords is true then
   set thisPageOrSpread to index of current spread
   set pageOrSpreadIndexList to index of every spread
   set theDialogItem to "spread"
  else
   set thisPageOrSpread to index of current page
   set pageOrSpreadIndexList to index of every page
  end if
  try
   set chosenPageOrSpread to thisPageOrSpread
  end try
  try
   set thePicture to "system:bilder:test.eps"
   set theImage to thePicture as alias
  end try
  try
   tell page thisPageOrSpread
    set theBox to make new picture box at beginning with properties {bounds:{"-1 cm", "-1 cm", "10 cm", "13 cm"}, color:"none"}
   end tell
   try
    set image 1 of theBox to theImage
   end try
   try
    set bounds of image 1 to proportional fit
   end try
  end try
 end tell
end tell

-----

Wie aber krieg ich es hin das das Bild in einem aktiven Xpress-Rahmen geladen wird? Das Script sollte unter OSX 10.2.8. sowie unter 0S9.2.2 laufen.

Danke für alle Antworten.


Seb

Hallo Seb,

weil das Bild in die aktive Box geladen werden soll, braucht sich das Script nicht um die Seite oder die
Arbeitsfläche zu kümmern. Aber es muss testen, ob eine Box ausgewählt ist, nur eine Box und zwar eine Bildbox.

Wenn alles okay ist, dann kann mit einem Dialog der Anwender aufgefordert werden, eine Bilddatei auszuwählen.

Die ausgewählte Box wird mit 'current box' bezeichnet:
---
tell application "QuarkXPress 4.11"
  activate
  if not (exists document 1) then
    display dialog "Kein XPress Dokument geöffnet." buttons {"Ooooh!"} default button 1 with icon 0
    error number -128
  end if
  try
    set boxType to box type of current box
  on error
    display dialog "Es ist keine Box ausgewählt." buttons "OK" default button 1 with icon 2
    error number -128
  end try
  if boxType = group box type then
    display dialog ¬
      "Bitte nur eine Box aufs Mal." buttons "OK" default button 1 with icon 2
    error number -128
  else if boxType is not picture box type then
    display dialog "Bitte eine  B I L D - Box auswählen." buttons "OK" default button 1 with icon 0
    error number -128
  end if
 
  set aPicture to (choose file with prompt "Ein Bild wählen" of type {"TIFF", "EPSF", "JPEG"}) as string
 
  tell current box
    set image 1 to aPicture as alias
  end tell
end tell
---
Der Zusatz 'of type {"TIFF", "EPSF", "JPEG"}' schränkt die Auswahl der gezeigten Dateien auf die genannten Typen
ein. Ohne diese Präzisierung würden auch Textdateien, XPress-Dokumente, unsichtbare Dateien usw. erscheinen.

Ich habe dieses Script nur unter Mac OS 9.2.2 ausprobiert.

Hans Haesler <hsa@ringier.ch>

Du musst ein Applescript Gott sein - Danke.

Es läuft auch unter 10.2.8. in der Classic-Umgebung.

Danke noch mal.

Schönes Wochende.

Eine Frage Frage noch:

Es soll immer eine Bildunterschrift an das Bild angefügt werden, zB ein Copyright-Vermerk.
Dann müsste ich doch die aktuellen koordinaten der box auslesen und dann einen textrahmen unterhalb der box erzeugen ?? wie kann ich diese koordinaten der aktiven box auslesen und dort dann einen textrahmen mit inhalt erzeugen ??

Danke für alle Antworten.....

Hallo Seb,

nun mal sachte! "AppleScript-Guru" reicht mir allemal &#133; ;-)

Zu Deiner "Frage noch" habe ich ein neues Thema eröffnet.

Hans Haesler <hsa@ringier.ch>