(*QuarkXPress 8.1.6 
Bilder deren Status auf modifiziert steht neu laden und Position und Skalierung so anpassen,  
dass der Bildausschnitt gleich bleibt. Setzt voraus, dass lediglich Größe (symmetrisch) und / oder Auflösung 
des Bildes verändert wurden (D.h. es wurde kein neuer Bildauschnitt im Bildbearbeitungsprogramm erstellt).  
Veränderte Symmetrien des modifizierten Bildes zum Originalbild werden nicht berücksichtigt ... könnte man hinzufügen ... 
 
*) 
 
 
global thePage 
global thePic 
global OrigPicHeight 
global OrigPicWidth 
global OrigCheck 
global OrigyScale 
global OrigxScale 
 
 
tell application "QuarkXPress" 
	set CurrentDoc to front document 
	tell CurrentDoc 
		repeat with thePage from 1 to count of pages 
			my checkPic(thePage) 
		end repeat 
	end tell 
end tell 
 
on checkPic(thePage) 
	tell application "QuarkXPress" 
		tell front document 
			 
			tell page thePage 
				repeat with thePic from 1 to count of every image 
					--select image thePic 
					tell image thePic 
						set ThePath to file path 
					end tell 
					 
					set PicStatusList to {themissing:missing of image thePic, themodified:modified of image thePic} 
					 
					if themissing of PicStatusList is false and themodified of PicStatusList is true then 
						set {OrigPicHeight, OrigPicWidth, OrigCheck, OrigyScale, OrigxScale} to my GetPicInfos(thePic, thePage) 
						my loadPic(thePic, thePage, ThePath) 
					end if 
					 
				end repeat 
			end tell 
		end tell 
	end tell 
end checkPic 
 
on loadPic(thePic, thePage, ThePath) 
	tell application "QuarkXPress" 
		tell front document 
			try 
				set image thePic of page thePage to ThePath 
				set {NewPicHeight, NewPicWidth, NewPicCheck} to my GetPicInfos(thePic, thePage) 
				 
				set newyScale to OrigPicHeight / NewPicHeight * (OrigyScale as real) 
				set newxScale to OrigPicWidth / NewPicWidth * (OrigxScale as real) 
				 
				tell image thePic of page thePage 
					set properties to {scale:{newyScale, newxScale}} 
				end tell 
				 
			end try 
		end tell 
	end tell 
end loadPic 
 
 
on GetPicInfos(thePic, thePage) 
	tell application "QuarkXPress" 
		tell front document 
			tell image thePic of page thePage 
				set {xbounds, ybounds, scaledHeight, scaledwidth} to actual bounds as list 
				set {yScale, xScale} to scale as list 
				set PicHeight to (scaledHeight as real) * 100 / (yScale as real) 
				set PicWidth to (scaledwidth as real) * 100 / (xScale as real) 
				set PicCheck to (PicHeight / PicWidth) 
			end tell 
		end tell 
	end tell 
	return {PicHeight, PicWidth, PicCheck, yScale, xScale} 
end GetPicInfos