[GastForen Programmierung/Entwicklung AppleScript Bilder sortieren lassen

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Bilder sortieren lassen

Pippalu
Beiträge gesamt: 279

19. Mär 2014, 14:41
Beitrag # 1 von 7
Bewertung:
(2855 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo, ich bin schon irgendwie lange auf der Suche, komme aber nicht zum Ergebnis.
Ich habe einen Ordner mit Bildern. Diese Bilder sollen geprüft werden, ob sie mindestens 1000 Pixel hoch oder Querformat haben. Wenn ja sollen diese Bilder in einen extra Ordner verschoben werden. Die Bilder die unter 100Pixel sind sollen dann einen separaten Ordner bekommen.
Ein weiterer Wunsch wäre dann noch prüfen zu lassen, gibt es von diesen Bildern die verschoben wurden Bilder mit Beschneidungspfad oder nicht. Wenn ja dann schiebe mir diese wiederum in einen anderen Ordner.

Gerne würde ich es über den Automator machen.
MacOS 10.8.5
Photoshop CS6
sind vorhanden.
X

Bilder sortieren lassen

Hans Haesler
  
Beiträge gesamt: 5797

19. Mär 2014, 15:16
Beitrag # 2 von 7
Beitrag ID: #525125
Bewertung:
(2842 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Pippalu,

das sollte machbar sein. Aber weshalb mit "Automator"? Ein Droplet oder ein Applet schaffen das doch spielend.

Wie sollen die verschiedenen Zielordner heissen? Wo sind sie in Bezug auf den Quellordner positioniert?

Zitat Die Bilder die unter 100Pixel sind ...

Sollte das nicht 1000 Pixel heissen?

Zitat Bilder mit Beschneidungspfad

Nur unter jenen, welche mindestens 1000 Pixel hoch sind oder Querformat haben?

Ich muss gleich weg, kann aber im Laufe des Abends versuchen, eine erste Version zu erstellen.

Gruss, Hans


als Antwort auf: [#525119]

Bilder sortieren lassen

Pippalu
Beiträge gesamt: 279

19. Mär 2014, 15:25
Beitrag # 3 von 7
Beitrag ID: #525127
Bewertung:
(2836 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo, dachte das der Automator damit was anfangen könnte :)
Womit dies passiert / gemacht werden kann ist mir recht egal.

Der Hauptordner soll "Bildempfang" heissen. Da soll alles reingelegt werden.
Dann soll es Ordner geben wie "min1000Pixel_Pfad", "min1000Pixel_oPfad", "unter1000Pixel".

Ja sollte heissen 1000 Pixel. Danke!

Richtig die Bilder die mind. 1000 Pixel H/Q haben sollen auch auf Pfad geprüft werden.

Das wäre ja echt Super, ich habe schon so viel Probiert.

Gruß
Daniel


als Antwort auf: [#525125]

Bilder sortieren lassen

Hans Haesler
  
Beiträge gesamt: 5797

19. Mär 2014, 16:58
Beitrag # 4 von 7
Beitrag ID: #525132
Bewertung:
(2793 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Daniel,

bin soeben zurückgekommen und habe noch ein paar Fragen:

Welche Endungen haben die Dateien? Sind das alles ".psd"? Oder kommen noch andere vor?
Die Aufgabe würde sehr viel leichter sein, wenn die Suffizes bekannt sind.

Ist es okay, wenn der Hauptordner neben dem Quellordner angelegt wird?

Wie schon gesagt, kann ich mich nicht sofort dahintersetzen, sondern erst in ein paar Stunden.

Gruss, Hans


als Antwort auf: [#525127]

Bilder sortieren lassen

Pippalu
Beiträge gesamt: 279

20. Mär 2014, 10:39
Beitrag # 5 von 7
Beitrag ID: #525148
Bewertung:
(2701 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo,

es sind alles .tif Dateien :)
Wie meinst du das Hauptordner neben dem Quellordner?

Gruß
Daniel


als Antwort auf: [#525132]

Bilder sortieren lassen

Hans Haesler
  
Beiträge gesamt: 5797

20. Mär 2014, 11:10
Beitrag # 6 von 7
Beitrag ID: #525149
Bewertung:
(2691 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Daniel,

gut, dann werde ich es so einrichten, dass nur Dateien mit der Endung ".tif" verschoben werden.

Nun, der Quellordner befindet sich ja in einem Ordner. Und es wäre am einfachsten, wenn der Hauptordner im gleichen Ordner angelegt wird. Okay?

Ich habe noch nichts gemacht. Aber heute werde ich mich dahintersetzen.

Gruss, Hans


als Antwort auf: [#525148]

Bilder sortieren lassen

Hans Haesler
  
Beiträge gesamt: 5797

20. Mär 2014, 15:27
Beitrag # 7 von 7
Beitrag ID: #525162
Bewertung:
(2639 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Daniel,

nachstehend eine erste Version des Droplets. Ich habe es Dir per PM zugestellt. Bitte mache einen ersten Versuch mit einem Quellordner, welcher nur drei Bilder enthält (von jeder Sorte eines).

Wer es interessehalber ausprobieren will, den folgenden Code auswählen, kopieren und in ein neues Fenster des AppleScript-Editors einsetzen.
Dann > Ablage > Sichern: Einen Namen tippen und als Dateiformat "Programm" wählen. Bei den Optionen keine der beiden Checkboxen aktivieren.

Zum Gebrauch: Den Quellordner, welcher alle ".tif"-Dateien enthält, auf das Icon des Droplets ziehen.
Das Script schickt die Dateien der Reihe nach zu einem Handler, in welchen Photoshop die Bilder öffnet und die Anzahl Pixel und Beschneidungspfade feststellt.
Je nach Ergebnis wird die aktuelle Datei in den entsprechenden Ordner verschoben.

Code
(*  
BilderSortieren_601d.app
Bild-Dateien in Zielordner verschieben, je nach Pixel-Anzahl und Beschneidungspfad
© 20.03.14 / Hans Haesler, Châtelard 52, CH-1018 Lausanne
*)

global subFolderOne
global subFolderTwo
global subFolderThr

-- einen Dialog zeigen, falls der Anwender einen Doppelklick auf das Droplet macht
on run
display dialog "Den Quellordner auf das Icon
dieses Droplets ziehen." buttons "OK" default button 1 with icon 0
end run

-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert
on open allObjects
-- das Trennzeichen zurücksetzen
set AppleScript's text item delimiters to {""}
-- der Pfad des gedroppten Ordners
set objPath to (item 1 of allObjects as Unicode text)
-- den Container-Ordner speichern
tell application "Finder"
set folderPath to (container of folder objPath) as string
end tell
-- der Hauptordner
set mainFolder to (folderPath & "Hauptordner") as string
-- testen, ob der Hauptordner vorhanden ist
tell application "Finder"
-- wenn nicht vorhanden, den Ordner erzeugen
if not (mainFolder exists) then
try
make new folder at folderPath with properties {name:"Hauptordner"}
end try
end if
end tell
-- die drei Unterordner
set subFolderOne to (mainFolder & ":min1000Pixel_Pfad")
set subFolderTwo to (mainFolder & ":min1000Pixel_oPfad")
set subFolderThr to (mainFolder & ":unter1000Pixel")
-- testen, ob die Unterordner vorhanden sind
tell application "Finder"
if not (subFolderOne exists) then
try
make new folder at mainFolder with properties {name:"min1000Pixel_Pfad"}
end try
end if
end tell
tell application "Finder"
if not (subFolderTwo exists) then
try
make new folder at mainFolder with properties {name:"min1000Pixel_oPfad"}
end try
end if
end tell
tell application "Finder"
if not (subFolderThr exists) then
try
make new folder at mainFolder with properties {name:"unter1000Pixel"}
end try
end if
end tell
-- den gedroppten Ordner zum Handler 'processFolder' schicken
processObject(objPath)
-- den Anwender über das Ergbenis der Aktion informieren
activate me
display dialog "Fertig." buttons "OK" default button 1 with icon 2 giving up after 1
end open

-- im folgenden Handler wird festgestellt, ob das Objekt ein Ordner oder eine Datei ist.
-- Bei Ordnern wird eine Liste des Inhalts erstellt und die Elemente rekursiv behandelt
-- (d.h. zum aktuellen Handler geschickt)
-- Dateien werden zum Handler 'processFile' gesandt
on processObject(aObject)
-- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner
if (aObject as string) ends with ":" then
-- die Liste des Inhalts wird erstellt (ohne unsichtbare Dateien)
set contentsList to list folder aObject without invisibles

-- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte zum Handler,
-- in welchem sie sich selbst befindet
repeat with anItem in contentsList
set objPath to ((aObject as Unicode text) & anItem)
processObject(objPath as alias)
end repeat

-- wenn das Objekt eine TIFF-Datei ist, dann wird der Pfad dem Handler 'processFile' übergeben
else if (aObject as string) ends with ".tif" then
processFile(aObject as Unicode text)
end if
end processObject

-- die Datei in den Zielordner kopieren
on processFile(aFile)
tell application "Adobe Photoshop CS6"
activate
try
open alias aFile
-- Pixel und Anzahl Beschneidungspfade speichern
tell current document
set docWidth to (width as pixels)
set docHeight to (height as pixels)
set nMasks to count (every path item whose kind is clipping)
end tell
close current document saving no
end try
end tell
-- Pixelwerte und Beschneidungspfad prüfen und die Datei entsprechend verschieben
if docWidth is greater than or equal to 1000 or docHeight is greater than or equal to 1000 then
if nMasks is greater than 0 then
try
tell application "Finder" to move aFile to subFolderOne with replacing
end try
else
try
tell application "Finder" to move aFile to subFolderTwo with replacing
end try
end if
else
try
tell application "Finder" to move aFile to subFolderThr with replacing
end try
end if
end processFile

Hier funktioniert es wie gewünscht. Mit Photoshop CS6 unter Mountain Lion.

Gruss, Hans


als Antwort auf: [#525149]
X

Aktuell

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
05.02.2021 - 05.11.2021

Digicomp Academy AG, Limmatstrasse 50, 8005 Zürich
Freitag, 05. Feb. 2021, 13.00 Uhr - Freitag, 05. Nov. 2021, 17.00 Uhr

Lehrgang

Bilden Sie sich zum zertifizierten Publishing-Multimedia-Profi aus. Neben Fotografie und Video befassen Sie sich mit der Medienproduktion, digitalen Publikationen und dem Webdesign für Desktop- und mobile Endgeräte.

Preis: CHF 10'500.-
Dauer: 30 Tage (ca. 210 Lektionen) – Unterricht findet jeweils am Freitag von 13 - 19 Uhr und Samstag von 09 - 17 Uhr statt

Ja

Organisator: Digicomp Academy AG

Kontaktinformation: Kundenberater-Team, E-Mailkundenberatung AT digicomp DOT ch

digicomp.ch/d/9PM

Veranstaltungen
01.03.2021 - 05.03.2021

Persönlichkeitsentwicklung

Online
Montag, 01. März 2021, 00.17 Uhr - Freitag, 05. März 2021, 00.18 Uhr

Webinar

Personal Power Coaching - Um was geht es? ​ Potenzialentfaltung: Potenzial entdecken und entfalten Talente entdecken: Deine Talente und Fähigkeiten erkennen und loslegen Gewohnheiten: schlechte Gewohnheiten durch Positive ersetzen Selbstbewusstsein stärken: Dein Bewusstsein stärken Eigendynamik entwickeln: Mehr Erfolg durch Eigenverantwortung & Disziplin Ängste kontrollieren: Ängste als Antrieb nutzen Entscheidungen treffen: Mit mehr Mut an die Sache ran! Lebensenergie steigern: Deine Lebensenergie steigern und aufrechterhalten Ziele erreichen: Ziele setzen und übertreffen! Motivationssteigerung: Mehr Erfolg durch Selbstmotivation Selbstvertrauen: Selbstvertrauen auf- und ausbauen

Details:
https://www.snfa.ch/swiss-personal-power-birolisik

Ja

Organisator: Birol Isik

Kontaktinformation: Birol Isik, E-Mailinfo AT snfa DOT ch

https://www.snfa.ch/swiss-personal-power-birolisik

Neuste Foreneinträge


Optionsfelder abhängig machen von Kontrollkästchen

InDesign CC21 sperrt Taskleiste und Programme

Bilder verschieben sich nach dem Speichern und Kopiern der Datei

Verknüpfung mit Format aufheben

Kursivierung geht bei é und É verloren

Abbildungen auf 100 % bringen

Scriptphänomen alle 16 Steps

Alternative Acrobat Pro

Affinity Designer

Objekte in Texten lassen sich nicht mehr mit Maus auswählen, nurnoch als Text mit Cursor
medienjobs