Hallo,
Ich habe eine Vorlage mit Vorgegebenen Bildrahmen in die ich grafiken einfüge. Das Platzieren bezieht sich immer auf die obere linke Ecke oder es kann zentriert eingefügt werden. Kann ich auch den Befehl geben, dass es sich IMMER AUTOMATISCH an der rechten unteren ecke orientiert? Ich möchte verhindern jedes Bild extra mit dem Auswahlwerkzeug zubewegen.

könnt Ihr mirhelfen?
Die Judith

Hallo Judith
soweit ich sehe, ist das auch in cs nicht vorgesehen. Cool wäre es, wenn in Zukunft mittels Tastenkürzel die aktive Ecke/Position des Rahmens in der Transformationspalette berücksichtigt würde. Hoffen wir auf CS2!
Vielleicht hat ja noch wer eine Skriptidee?!
Gruss und Dank
Urs
------------------------------------------------------
Member und Premiummember sichern HilfDirSelbst.ch die Zukunft:
http://www.hilfdirselbst.ch/info/

Es hat mir keine Ruhe gelassen...

Hier ein AppleScript, das die gewünschte Transformation mit Bezug auf die Ecke unten rechts vornimmt. Es sind zwar ein paar Prüfroutinen enthalten, das Script sollte aber nur auf eine Auswahl von Bildrahmen mit Bildinhalt oder auf die Direktauswahl eines Bildes angewandt werden.

-- Trafo.as
--
tell application "InDesign CS"
set myDoc to active document
set mySelection to selection
-- Prüfung, ob etwas ausgewählt ist.
if (count of mySelection) > 0 then
set myClass to class of item 1 of selection
-- Prüfung, ob Rahmen oder Bild ausgewählt
if myClass is rectangle then
set myObject to selection
else if myClass is image then
set myObject to parent of selection
end if
try
-- Iteration durch alle Objekte der Auswahl
repeat with myObjectNum from 1 to count of myObject
tell item myObjectNum of myObject
-- Koordinaten des Rahmens
set myFrameBounds to geometric bounds
-- Koordinaten des Rahmeninhalts
set myImageBounds to geometric bounds of item 1 of all graphics
-- Differenz der rechten unteren Ecken
set myXDiff to ((item 4 of myFrameBounds) - (item 4 of myImageBounds))
set myYDiff to ((item 3 of myFrameBounds) - (item 3 of myImageBounds))
-- Verschiebung
move item 1 of all graphics to {(item 2 of myImageBounds) + myXDiff, (item 1 of myImageBounds) + myYDiff}
end tell
end repeat
on error
display dialog "Something has gone wrong ..."
end try
else
display dialog ("Bitte etwas auswählen!")
end if
end tell
-- Ende Trafo.as

Das Skript kann auf einen oder mehrere Bildrahmen oder auf ein direkt ausgewähltes Bild angewendet werden (auf eine weitere Unterscheidung, ob es sich beim ausgewählten Objekt um etwas anderes, wie z.B. einen Textrahmen, handelt, habe ich verzichtet.

@ Urs: Meines Wissens ist es nicht möglich per Script auf die Elemente des UserInterfaces, so auch auf die Transformationspalette, zuzugreifen. Ich kann also die gewünschte Bezugsecke nicht aus der Transformationspalette auslesen, sondern müßte die 8 Bezugspunkte in einem Dialog zur Auswahl bieten. Dies würde aber im Moment mein Zeitkontingent sprengen.

@ Judith: Ich hoffe, Du kannst mit dem AppleScript etwas anfangen. Ansonsten könnte ich Dir eventuell heute Abend das gleiche nochmal in JavaScript stricken.

Grüßle
Martin

Hallo Martin!
Dankeschön für das Skript. AppleScript ist perfect.

Nur... ich habe nicht erwähnt, dass ich mit indesign 2.0.1 arbeite.
WAS MÜSSTE ICH WO AM SKRIPT ÄNDERN?

wenn ich gleich am Anfang anstatt "indesign cs" "idndesign 2.0.1" eingebe, hängt er sich unten irgendwo auf. Geht es vielleicht garnicht?
Als möglichkeit besteht auch noch, dass ich appleskript nicht ordentlich benütze.

SCHÖNEN GRUSS,
judith

Das Objektmodell von ID2 und IDCS unterscheiden sich.
Da ich erst seit CS intensiver mit Indesign arbeite und erst seit CS Scripts schreibe, habe ich mich um die Unterschiede nie gekümmert. Ich könnte heute Abend versuchen, eine vereinfachte (!) Version für ID2 zu rekonstruieren.

Schade, daß Du erst jetzt die Version erwähnst.
Wenn heute jemand von InDesign redet, dann setze ich stillschweigend die Version CS voraus, wenn ich nichts anderes höre.

Grüßle
Martin

Hallo Martin
super! Danke für das Script! Ich dachte bei meinem Vorschlag der Importoptionen eher an Adobe: das diese Möglichkeit in Zukunft integriert würde.
Gruss und Dank
Urs
------------------------------------------------------
Member und Premiummember sichern HilfDirSelbst.ch die Zukunft:
http://www.hilfdirselbst.ch/info/

@ Urs: schön, daß wenigstens einer 'was damit anfangen kann. ;-)
Vielleicht sind's morgen schon zwei ...

@ Judith: Hier das AppleScript für InDesign 2.0.2 (das ist m.W. die letzte ID2-Version). Es war nur ein Ausdruck auszutauschen: "all graphics" gegen "all page items":

-- Trafo2.as
--
tell application "InDesign 2.0.2"
set myDoc to active document
set mySelection to selection
-- Prüfung, ob etwas ausgewählt ist.
if (count of mySelection) > 0 then
set myClass to class of item 1 of selection
-- Prüfung, ob Rahmen oder Bild ausgewählt
if myClass is rectangle then
set myObject to selection
else if myClass is image then
set myObject to parent of selection
else
set myObject to selection
end if
-- Iteration durch alle Objekte der Auswahl
repeat with myObjectNum from 1 to count of myObject
try
tell item myObjectNum of myObject
-- Koordinaten des Rahmens
set myFrameBounds to geometric bounds
-- Koordinaten des Rahmeninhalts
set myImageBounds to geometric bounds of item 1 of all page items
-- Differenz der rechten unteren Ecken
set myXDiff to ((item 4 of myFrameBounds) - (item 4 of myImageBounds))
set myYDiff to ((item 3 of myFrameBounds) - (item 3 of myImageBounds))
-- Verschiebung
move item 1 of all page items to {(item 2 of myImageBounds) + myXDiff, (item 1 of myImageBounds) + myYDiff}
end tell
on error
display dialog "Something went wrong ..." & return & "Maybe there's a textframe in the selection."
end try
end repeat
else
display dialog ("Bitte etwas auswählen!")
end if
end tell
-- Ende Trafo2.as


Und hier nochmal das leicht veränderte Skript für InDesign CS (besserer Fehlerabfang):

-- TrafoCS.as
--
tell application "InDesign CS"
set myDoc to active document
set mySelection to selection
-- Prüfung, ob etwas ausgewählt ist.
if (count of mySelection) > 0 then
set myClass to class of item 1 of selection
-- Prüfung, ob Rahmen oder Bild ausgewählt
if myClass is rectangle then
set myObject to selection
else if myClass is image then
set myObject to parent of selection
else
set myObject to selection
end if
-- Iteration durch alle Objekte der Auswahl
repeat with myObjectNum from 1 to count of myObject
try
tell item myObjectNum of myObject
-- Koordinaten des Rahmens
set myFrameBounds to geometric bounds
-- Koordinaten des Rahmeninhalts
set myImageBounds to geometric bounds of item 1 of all graphics
-- Differenz der rechten unteren Ecken
set myXDiff to ((item 4 of myFrameBounds) - (item 4 of myImageBounds))
set myYDiff to ((item 3 of myFrameBounds) - (item 3 of myImageBounds))
-- Verschiebung
move item 1 of all graphics to {(item 2 of myImageBounds) + myXDiff, (item 1 of myImageBounds) + myYDiff}
end tell
on error
display dialog "Something went wrong ..." & return & "Maybe there's a textframe in the selection."
end try
end repeat
else
display dialog ("Bitte etwas auswählen!")
end if
end tell
-- Ende TrafoCS.as

Grüßle
Martin

Oh! Es funktioniert. Was Dich nicht wundert, oder?
Mich schon, weil kappiert habe ich es noch nicht. Ma viene.
Danke schön,
Judith

> Oh! Es funktioniert. Was Dich nicht wundert, oder?
Sagen wir's so: es trifft mich nicht ganz unvorbereitet.

> Mich schon, weil kappiert habe ich es noch nicht.
Der Kern ist relativ einfach:
Ausgangspunkt: ein Rahmen mit vier Eckpunkten und ein Rahmeninhalt (Bild) mit vier Eckpunkten.
Ziel: Der Eckpunkt des Rahmeninhalts rechts unten soll in Übereinstimmung gebracht werden mit dem Eckpunkt des Rahmens rechts unten.
Weg: Berechnung der Distanz der x- und y-Koordinaten zwischen den beiden Eckpunkten und Verschieben aller vier Eckpunkte des Rahmeninhalts um diese Distanz.

Der Rest ist ein bißchen Fehlerabfangen:
- was passiert, wenn nix ausgewählt ist?
- was passiert, wenn nicht der Bildrahmen, sondern das Bild selber (direkt-)ausgewählt ist?
- was passiert, wenn der ausgewählte Rahmen gar kein Bild enthält?
- was passiert, wenn der ausgewählte Rahmen gar kein Bildrahmen, sondern ein Textrahmen ist?
(die Liste ist damit noch nicht erschöpft, aber ich habe mir z.B. die Möglichkeit, daß gar kein Dokument geöffnet sein könnte, ausgespart ...)

Schön, daß Du was damit anfangen kannst.

Grüßle
Martin