tell document 1 of application "QuarkXPress 7.5" 
 activate 
  
 -- Masseinheiten und Objektkoordinaten speichern und prüfen 
 -- wenn nicht "Millimeter" und "Montagefläche", dann ändern 
 set isc to 0 
 set mes to 0 
 set {vMes, hMes} to {vertical measure, horizontal measure} 
 if vMes is not millimeters or hMes is not millimeters then 
  set mes to 1 
 end if 
 if item spread coords is false then set isc to 1 
 if isc is 1 and mes is 1 then 
  set properties to ¬ 
   {vertical measure:millimeters, horizontal measure:millimeters ¬ 
    , item spread coords:true} 
 else if isc is 0 and mes is 1 then 
  set properties to {vertical measure:millimeters, horizontal measure:millimeters} 
 else if isc is 1 and mes is 0 then 
  set item spread coords to true 
 end if 
  
 -- eine Schleife durch die Montageflächen 
 repeat with s from 1 to count of spreads 
  set posList to {} 
  tell spread s 
   -- die Koordinaten der Bildboxen auflisten 
   repeat with p from 1 to count of picture boxes 
    tell picture box p 
     set {y1, x1, y2, x2} to bounds as list 
     set end of posList to x1 as real 
     set end of posList to y2 as real 
    end tell 
   end repeat 
   -- eine Schleife durch die Textboxen 
   repeat with t from (count of text boxes) to 1 by -1 
    tell text box t 
     -- die Positionen der Ränder 
     set {y1, x1, y2, x2} to bounds as list 
     set y1 to y1 as real 
     set x1 to x1 as real 
     -- eine Schleife durch die Liste der Bildboxen-Koordinaten 
     repeat with i from 1 to count of posList by 2 
      -- das aktuelle Element der Liste 
      set curItem1 to item i of my posList 
      -- die Werte vergleichen 
      -- wenn X und Y passen, den Bildpfad holen und einsetzen 
      if curItem1 is greater than (x1 - 1) and curItem1 is less than (x1 + 1) then 
       set curItem2 to item (i + 1) of my posList 
       if curItem2 is greater than (y1 - 3) and curItem2 is less than (y1 - 1) then 
        set filePath to my getFilePath(s, (i + 1) / 2) 
        tell paragraph 1 
         set contents to filePath 
        end tell 
        exit repeat 
       end if 
      end if 
     end repeat 
    end tell 
   end repeat 
  end tell 
 end repeat 
  
 -- Masseinheiten und Objektkoordinaten:  
 -- Die ursprüngliche Einstellung wiederherstellen 
 if mes = 1 then 
  if isc = 0 then 
   set properties to {vertical measure:vMes, horizontal measure:hMes} 
  else if isc = 1 then 
   set properties to ¬ 
    {vertical measure:vMes, horizontal measure:hMes, item spread coords:false} 
  end if 
 else if mes = 0 then 
  if isc = 1 then 
   set item spread coords to false 
  end if 
 end if 
  
 display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
  
end tell 
 
-- der Handler, welcher den aktuellen Bildpfad auszieht und zurückschickt 
on getFilePath(s, ctr) 
 set filePath to "" 
 tell document 1 of application "QuarkXPress 7.5" 
  tell spread s 
   try 
    set filePath to (file path of image 1 of picture box ctr) as Unicode text 
   end try 
  end tell 
 end tell 
 return filePath 
end getFilePath