set lZiffern to {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9"} 
set sInternSeparator to "." 
set sLastSeparator to "	" 
 
tell application "Adobe InDesign CS2" 
	set aSel to selection 
	set aDoc to active document 
	if aSel = {} then return 
	set thisStory to item 1 of aSel 
	if class of thisStory is text frame then 
		set thisStory to parent story of thisStory 
	else 
		repeat until (class of thisStory is story) 
			set thisStory to parent of thisStory 
		end repeat 
	end if 
	set allStyles to every paragraph style of aDoc 
	set nStyles to count allStyles 
	 
	activate 
	 
	set myDialog to make dialog with properties {name:"Hierarchie bestimmen"} 
	tell myDialog 
		tell (make dialog column) 
			tell (make dialog row) 
				make static text with properties {static label:"Anfangen bei:"} 
				set startValueField to make integer editbox with properties {edit value:1} 
			end tell 
			make static text with properties {static label:"Oberste Ebene = 1; zweite = 2; etc. ;"} 
			make static text with properties {static label:"Absätze ohne Nr = 0  /  -1 für Neustart 1. Level"} 
			set lHFields to {} 
			if nStyles > 10 then 
				set nHalfOfIt to nStyles div 2 + 2 
			else 
				set nHalfOfIt to nStyles 
			end if 
			tell (make dialog row) 
				tell (make dialog column) 
					repeat with n from 3 to nHalfOfIt 
						tell (make dialog row) 
							set aSTmp to (name of (item n of allStyles)) 
							set lHFields to lHFields & (make integer editbox ¬ 
								with properties ¬ 
								{edit value:0, small nudge:1, minimum value:(-1 * nStyles), maximum value:(nStyles - 2)}) 
							make static text with properties {static label:aSTmp} 
						end tell 
					end repeat 
				end tell 
				if nStyles > 10 then 
					tell (make dialog column) 
						repeat with n from (nHalfOfIt + 1) to nStyles 
							tell (make dialog row) 
								set aSTmp to (name of (item n of allStyles)) 
								set lHFields to lHFields & (make integer editbox ¬ 
									with properties ¬ 
									{edit value:0, small nudge:1, minimum value:(-1 * nStyles), maximum value:(nStyles - 2)}) 
								make static text with properties {static label:aSTmp} 
							end tell 
						end repeat 
					end tell 
				end if 
				 
			end tell 
		end tell 
	end tell 
	 
	set nu to show myDialog 
	 
	if nu is true then 
		set startValue to edit value of startValueField as integer 
		set lStyleHierarchy to {} 
		set lBreakStyles to {} 
		set lBreakLevel to {} 
		repeat with m from 1 to (nStyles - 2) -- minus 2, weil wir [keins] und [basis] nicht berücksichtigen 
			repeat with n from 3 to nStyles 
				set aux to edit value of (item (n - 2) of lHFields) 
				if aux = (-1 * m) then 
					copy (item n of allStyles) to end of lBreakStyles 
					copy m to end of lBreakLevel 
				else if aux = m then 
					copy (item n of allStyles) to end of lStyleHierarchy 
					--					set lStyleHierarchy to lStyleHierarchy & (item n of allStyles) 
				end if 
			end repeat 
		end repeat 
		set nHeadStyles to count lStyleHierarchy 
		set nBreakStyles to count lBreakStyles 
		set lCounters to {(startValue - 1)} 
		repeat with n from 2 to nHeadStyles 
			set lCounters to lCounters & 0 
		end repeat 
		 
		repeat with nPara from 1 to (count paragraphs in thisStory) 
			set aPara to (a reference to (paragraph nPara in thisStory)) 
			set aStyle to applied paragraph style of aPara 
			try 
				set c1 to first character in aPara 
				set weiter to true 
			on error 
				set weiter to false 
			end try 
			 
			if weiter then -- leere Absätze werden ignoriert 
				if aStyle is in lStyleHierarchy then -- Anfangsziffern löschen, wenn Format in Liste 
					if c1 is in lZiffern then 
						set c2 to second character in aPara 
						set c3 to third character in aPara -- Wir können nicht weiter als bis 99 zählen 
						if (c2 is sInternSeparator) or (c3 is sInternSeparator) or (c2 is sLastSeparator) or (c3 is sLastSeparator) then 
							repeat until first character of aPara is sLastSeparator 
								set contents of first character of aPara to "" 
							end repeat 
							set contents of first character of aPara to "" -- der last separator ist noch da 
						end if 
					end if 
				end if 
				 
				if aStyle is in lStyleHierarchy then -- kleinere Level auf 0 setzen 
					repeat with i from 1 to nHeadStyles 
						if item i of lStyleHierarchy = aStyle then set thisIndex to i 
					end repeat 
					set aufNull to true 
				else if aStyle is in lBreakStyles then 
					repeat with i from 1 to nBreakStyles 
						if item i of lBreakStyles = aStyle then set thisIndex to (item i of lBreakLevel) - 1 
					end repeat 
					set aufNull to true 
				else 
					set aufNull to false 
				end if 
				if aufNull then 
					repeat with i from (thisIndex + 1) to nHeadStyles 
						set item i of lCounters to 0 
					end repeat 
				end if 
				 
				if aStyle is in lStyleHierarchy then 
					set tempCounter to (item thisIndex of lCounters) + 1 
					set item thisIndex of lCounters to tempCounter 
					set tempIndex to index of first character of aPara 
					set hey to first character in aPara 
					repeat with n from thisIndex to 1 by -1 
						if n = thisIndex then 
							set contents of insertion point tempIndex of thisStory to (((item n of lCounters) as string) & sLastSeparator) 
						else 
							set contents of insertion point tempIndex of thisStory to (((item n of lCounters) as string) & sInternSeparator) 
						end if 
					end repeat 
				end if 
			end if 
		end repeat 
		 
	else 
		--destroy dialog 
		return 
	end if 
end tell