(* 
DateienMarkieren_01d.app 
Dieses Script markiert Dateien, deren Name bestimmte Zeichen enthalten 
© 26.08.14 / Hans Haesler, Châtelard 52, CH-1018 Lausanne 
*) 
 
-- den Hauptordner wählen 
set sourceFolder to (choose folder) as Unicode text 
 
-- den Anwender auffordern, die Zeichenfolge einzugeben 
set dialogResult to display dialog "Zeichenfolge eingeben" default answer "" buttons ¬ 
  {"Abbrechen", "OK", "+Unterordner"} default button 2 
 
-- die Eingabe prüfen 
set curString to text returned of dialogResult 
if (count of curString) is 0 then 
  display dialog "Die Eingabe ist leer. Bitte nochmals." buttons "OK" default button 1 with icon 0 
  error number -128 
end if 
 
-- wenn "OK", dann die Dateien im Hauptordner 
if button returned of dialogResult is "OK" then 
  tell application "Finder" to set selFiles to ¬ 
    (every file whose name contains curString) of folder sourceFolder 
  -- sonst auch die Dateien in den Unterordnern 
else if button returned of dialogResult is "+Unterordner" then 
  -- die Namen der Unterordner auflisten 
  tell application "Finder" to set subFolders to name of every folder of folder sourceFolder 
  -- eine Liste initialisieren 
  set selFiles to {} 
  -- schon mal die Dateien des Hauptordners an die Liste hängen 
  tell application "Finder" to set end of selFiles to ¬ 
    (every file whose name contains curString) of folder sourceFolder 
  -- eine Schleife durch die Unterordner 
  repeat with n from 1 to count of subFolders 
    set curFolder to (item n of subFolders) 
    tell application "Finder" to set end of selFiles to ¬ 
      (every file whose name contains curString) of folder curFolder of folder sourceFolder 
  end repeat 
end if 
 
-- die Dateien auswählen 
tell application "Finder" to select selFiles 

tell application "Finder" to set label index of selFiles to 2 

(* 
DateienMarkieren_02d.app 
Dieses Script markiert Dateien, deren Name bestimmte Zeichen enthalten 
© 26.08.14 / Hans Haesler, Châtelard 52, CH-1018 Lausanne 
*) 
 
-- den Hauptordner wählen 
set sourceFolder to (choose folder) as Unicode text 
 
-- den Anwender auffordern, die Zeichenfolge einzugeben 
set dialogResult to display dialog "Zeichenfolge eingeben" default answer "" buttons ¬ 
  {"Abbrechen", "OK", "+Unterordner"} default button 2 
 
-- die Eingabe prüfen 
set curString to text returned of dialogResult 
if (count of curString) is 0 then 
  display dialog "Die Eingabe ist leer. Bitte nochmals." buttons "OK" default button 1 with icon 0 
  error number -128 
end if 
 
-- wenn "OK", dann die Dateien im Hauptordner 
if button returned of dialogResult is "OK" then 
  tell application "Finder" to set selFiles to ¬ 
    (every file whose name contains curString) of folder sourceFolder 
  -- sonst auch die Dateien in den Unterordnern 
else if button returned of dialogResult is "+Unterordner" then 
  tell application "Finder" to set selFiles to ¬ 
    (every file whose name contains curString) of entire contents of folder sourceFolder 
end if 
 
-- die Dateien auswählen 
tell application "Finder" to select selFiles 

-- ... oder etikettieren 
repeat with m from 1 to count of selFiles 
  tell application "Finder" to set label index of item m of selFiles to 2 
end repeat 

repeat with m from 1 to count of selFiles 
  tell application "Finder" to set label index of item m of my selFiles to 2 
end repeat