Sub Druckbarkeit_einerEbeneumstellen() 
  Dim doc As Document 
  Dim Mldg, Titel, Voreinstellung, Eingabe 
  Dim Druckbar As Boolean 
   
  Mldg = "Soll eine Ebene auf druckbar (JA) oder nicht_druckbar (NEIN) gestellt werden?" 
  Titel = "Druckbar oder nicht druckbar?" 
  Eingabe = MsgBox(Mldg, vbYesNoCancel, Titel) 
  If Eingabe = vbYes Then 
    Druckbar = True 
    Titel = "Welche Ebene soll druckbar gestellt werden?" 
  ElseIf Eingabe = vbNo Then 
    Druckbar = False 
    Titel = "Welche Ebene soll NICHT_druckbar gestellt werden?" 
  Else 
    Exit Sub 
  End If 
  Mldg = "Bitte Ebenenname eingeben" 
  Voreinstellung = "Ebene 1" 
  Eingabe = InputBox(Mldg, Titel, Voreinstellung) 
  If Len(Eingabe) > 0 Then 
    Set doc = ActiveDocument 
    For i = 1 To doc.Pages.Count 
      doc.Pages(i).Layers(Eingabe).Printable = Druckbar 
    Next i 
  End If 
End Sub 

Sub Druckbarkeit_vonEbenenumstellen() 
  Dim doc As Document 
  Dim p As Page 
  Dim lay As Layer 
  Dim Mldg, Titel, Voreinstellung, Eingabe 
  Dim Druckbar, layName As Boolean 
  Dim sz As Integer    'Seitenzähler 
   
  Voreinstellung = "Ebene 1" 
  Do 
    Mldg = "Soll eine Ebene auf druckbar [JA] oder nicht_druckbar [NEIN] gestellt werden?" _ 
      & Chr(13) & Chr(13) & "[Abbrechen] beendet das Makro." 
    Titel = "Makro Druckbarkeit von Ebenen umstellen" 
    Eingabe = MsgBox(Mldg, vbYesNoCancel, Titel) 
    If Eingabe = vbYes Then 
      Druckbar = True 
      Titel = "Welche Ebene soll druckbar gestellt werden?" 
    ElseIf Eingabe = vbNo Then 
      Druckbar = False 
      Titel = "Welche Ebene soll NICHT_druckbar gestellt werden?" 
    Else 
      Exit Sub 
    End If 
    Mldg = "Ebenenname eingeben" 
    Eingabe = InputBox(Mldg, Titel, Voreinstellung) 
    If Len(Eingabe) > 0 Then 
      Voreinstellung = Eingabe 
      Set doc = ActiveDocument 
      sz = 0 
      For i = 1 To doc.Pages.Count    'alle Seiten durchlaufen 
        Set p = doc.Pages(i) 
        layName = False               'prüfen ob Ebenenname auf Seite vorhanden 
        For Each lay In p.Layers 
          If lay.Name = Eingabe Then layName = True 
        Next lay 
        If layName = True Then 
          p.Layers(Eingabe).Printable = Druckbar 
          'p.Layers(Eingabe).Visible = Druckbar  'zugleich sichtbar machen? 
      Else 
          sz = sz + 1 
        End If 
      Next i 
      If sz = doc.Pages.Count Then 
        Eingabe = MsgBox("Ebene >" & Eingabe & "< ist im Dokument nicht vorhanden!", , "Achtung") 
      ElseIf sz > 0 Then 
        Eingabe = MsgBox("Ebene >" & Eingabe & "< ist auf " & sz & " Seite(n) nicht vorhanden!", , "Warnung") 
      End If 
    Else 
      Eingabe = MsgBox("Keinen Ebenennamen eingegeben oder [Abbrechen] gewählt!" _ 
        & Chr(13) & Chr(13) & "(Makro kann erst im nächsten Dialog beendet werden.)") 
    End If 
  Loop 
End Sub