[GastForen Programmierung/Entwicklung AppleScript Ein Skript für Illustrator zum Abspeichern auf eine alte Version gesucht

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Ein Skript für Illustrator zum Abspeichern auf eine alte Version gesucht

suppel
Beiträge gesamt: 203

26. Feb 2012, 22:41
Beitrag # 1 von 3
Bewertung:
(1445 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Forum,
ich habe Illustrator CS3 Mac (Intel) auf OS 10.5 zur Verfügung.
Um Schrift- und Grafikdaten zu plotten, müssen die Daten in Illu Version 8 abgespeichert werden, weil die Schneidsoftware sehr alt ist und nur Illustratordaten 8 importieren kann. Das manuelle Runterspeichern ist ansicht kein Problem, aber es gibt Leute, die das nicht kapieren (wollen) und ich nicht jedesmal meine Arbeit unterbrechen muss. Droplet, wo der User nur die Datei auf das Icon ziehen muss, und eine Illustratordatei 8 wird automatisch erzeugt, wäre wunderbar. Weitere Speicheroptionen wie Schrifteinbettung, sollten nicht aktiv sein. Wäre schön, wenn mir jemand helfen könnte.

gruß suppel

(Dieser Beitrag wurde von suppel am 26. Feb 2012, 22:44 geändert)
X

Ein Skript für Illustrator zum Abspeichern auf eine alte Version gesucht

TMA
Beiträge gesamt: 372

27. Feb 2012, 06:58
Beitrag # 2 von 3
Beitrag ID: #490781
Bewertung:
(1424 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo suppel,
ich habe zwar kein Illustrator CS3 mehr aber probier dieses Droplet mal aus:

Code
global tmpDesktopPath 
-------------------------------------------------------------------------------------------------------------------------------------
on Initialize()
set my text item delimiters to ""
set tmpDesktopPath to (path to desktop) as string
end Initialize

on Finalize()
with timeout of 14400 seconds -- 4 Stunden
activate
display alert "Fertig" message "Objekt(e) wurde(n) verarbeitet."
end timeout
end Finalize

on ProcessAFileOrFolder(theFile)
if (theFile as string) ends with ":" then
ScanAFolder(theFile)
else
ProcessAFile(theFile)
end if
end ProcessAFileOrFolder

on ScanAFolder(theFolder)
set fileNames to list folder theFolder without invisibles
repeat with aFile in fileNames
set theFile to (theFolder as string) & contents of aFile
ProcessAFileOrFolder(alias theFile)
end repeat
end ScanAFolder

on open of filesList
my Initialize()
repeat with aFile in filesList
ProcessAFileOrFolder(contents of aFile)
end repeat
my Finalize()
end open

on run
activate
display alert "ACHTUNG!" message "Läuft nur als Droplet. Bitte Objekt(e) auf das Script ziehen." as warning
end run
-------------------------------------------------------------------------------------------------------------------------------------
on ProcessAFile(aFile)
tell application "Finder" to set tmpName to name of aFile as string
set saveFile to my tmpDesktopPath & tmpName
set aLogo to aFile as string
tell application "Adobe Illustrator"
close every document saving no
open file aLogo without dialogs
tell front document
save in saveFile as eps with options {compatibility:Illustrator 8, compatible gradient printing:true, PostScript:level 3, preview:color Macintosh}
close saving no
end tell
end tell
end ProcessAFile
-------------------------------------------------------------------------------------------------------------------------------------


Das Droplet speichert die neue Datei auf dem Desktop ab.

Gruß
TMA


als Antwort auf: [#490777]

Ein Skript für Illustrator zum Abspeichern auf eine alte Version gesucht

suppel
Beiträge gesamt: 203

1. Mär 2012, 21:44
Beitrag # 3 von 3
Beitrag ID: #491079
Bewertung:
(1361 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Vielen Dank für das Skript. Ich kam erst heute dazu, es zu testen und es läuft einwandfrei. Illustratordateien, als eps-Datei, werden umgewandelt, jedoch das Icon von CS3 bleibt erhalten. Bei Umwandlung einer ai-Datei wird auch das Icon der Version gewechselt.

gruss suppel


als Antwort auf: [#490781]

Aktuell

PDF / Print
PDF-XCange_300

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
26.10.2021

Online
Dienstag, 26. Okt. 2021, 10.00 - 10.30 Uhr

Webinar

In unserem ca. 30-minütigen kostenlosen Webinar zeigt Ihnen unser Produktmanager Karsten Schwarze, wie Sie mit ColorLogic ColorAnt, CoPrA und ZePrA einen konsistenten Farbmanagement Workflow aufbauen und die Druckqualität sichern.

Ja

Organisator: Impressed GmbH

Kontaktinformation: Silvia Noack, E-Mailsnoack AT impressed DOT de

https://www.impressed.de/schulung.php?c=sDetail&sid=305

Mit ColorLogic ColorAnt & CoPrA & ZePrA zum perfekten Druckergebnis
Veranstaltungen
29.10.2021 - 08.07.2022

Digicomp Academy, Zürich
Freitag, 29. Okt. 2021, 13.00 Uhr - Freitag, 08. Juli 2022, 19.00 Uhr

Lehrgang

Bilden Sie sich zum zertifizierten Publishing-Multimedia-Profi aus. Neben Fotografie und Video befassen Sie sich mit der Medienproduktion, digitalen Publikationen und dem Webdesign für Desktop- und mobile Endgeräte.

Preis: 10'500.– zzgl. 7.7% MWST
Dauer: 30 Tage(ca. 210 Lektionen) – Unterricht findet jeweils am Freitag von 13 - 19 Uhr und Samstag von 09 - 17 Uhr statt

Ja

Organisator: Digicomp Academy AG

Kontaktinformation: Kundenberater-Team, E-Mailkundenberater AT digicomp DOT ch