Hallo Forum,

kann man per OrdnerScript ankommenden Daten splitten:
wenn Dateien eintreffen, diese in "Eing_Dateien" moven
wenn Ordner eintreffen, alle in "Eing_Ordner" moven,

oder gibt es Probleme mit dem erkennen von EOF

Gruss willem

Hallo Willem,

ja, das kann man. Und nein, es gibt keine Probleme mit dem EOF (= end of file),
weil dieses nur beim Lesen des Inhalts von Dateien benutzt wird.

Im vorliegenden Fall genügt es, zu prüfen, ob die Property folder der Infos
des Objekts true oder false zurückgibt. Im ersten Fall ist es ein Ordner,
sonst eine Datei.

Ich überlasse es Dir die Pfade zu den beiden Zielordnern anzupassen.
---
property allFiles : "Tiger:Users:willem:Documents:Eing_Dateien:"
property allFolders : "Tiger:Users:willem:Documents:Eing_Ordner:"

on adding folder items to thisFolder after receiving objectList
   repeat with i from 1 to count of objectList
      set aObject to (item i of objectList) as Unicode text
      if folder of (info for file aObject) is true then
         try
            tell application "Finder" to move folder aObject to folder allFolders
         end try
      else
         try
            tell application "Finder" to move file aObject to folder allFiles
         end try
      end if
   end repeat
end adding folder items to
---
Gruss, Hans

Hallo Hans,

Danke für dieses Schmankerl,

Gruss willem

Hallo Hans,

wenn ich Ordner mit Inhalt von A nach "ONE HD:Ordnertest:Ordner" move
und möchte anschließend, wenn ein Ordner mit gleichem Namen aber Neuem Inhalt ankommt
den bestehenden Ordner überschreiben - aber eben nur, wenn dieser leer ist,
wie könnte das funktionieren?

habe Deinem Script ein "with replacing" angehängt,
da wird aber Überschrieben auch wenn noch Files im Ziel-Ordner liegen.

property allFiles : "ONE HD:Ordnertest:Datei:"
property allFolders : "ONE HD:Ordnertest:Ordner:"

on adding folder items to thisFolder after receiving objectList
repeat with i from 1 to count of objectList
set aObject to (item i of objectList) as Unicode text
if folder of (info for file aObject) is true then
try
tell application "Finder" to move folder aObject to folder allFolders with replacing
end try
else
try
tell application "Finder" to move file aObject to folder allFiles with replacing
end try
end if
end repeat
end adding folder items to

Gruss und Danke
willem

Hallo Willem,

mit dem Zusatz von with replacing wird genau das Gegenteil erreicht: Ein Ordner wird
ohne Warnmeldung ersetzt. Ob er nun leer ist oder nicht spielt keine Rolle.

Der im ersten Script vorhandene try-Wickel unterdrückt eine Warnmeldung, wenn ein Ordner
desselben Namens schon existiert. Zudem wird ein gleichnamiger Ordner nicht ersetzt.

Man müsste also ein on error einbauen, um bei einem "Fehler", d.h. wenn ein Ordner desselben
Namens vorhanden ist, entsprechende Aktionen auszulösen: Den Namen des zu bewegenden
Ordners speichern und dem Zielordnerpfad anhängen. Dann kann mit list folder der Inhalt
geprüft werden. Wichtig ist das without invisibles, damit eventuell vorhandene, unsichtbare
Dateien – wie "Icon" oder ".DS_Store" – nicht einen richtigen Inhalt vortäuschen.

Wenn die Liste fileList leer ist, kann der Ordner ersetzt werden.
---
try
   tell application "Finder" to move folder aObject to folder allFolders
on error
   tell application "Finder" to set folderName to name of folder aObject
   tell application "Finder" to set oldFolder to (folder folderName of folder allFolders) as Unicode text
   set fileList to list folder oldFolder without invisibles
   if fileList is {} then
      tell application "Finder" to move folder aObject to folder allFolders with replacing
   [color=#0000FF]end if
end try[/color]
---
Aber was sollte das Script tun, wenn ein gleichnamiger Ordner existiert und dieser Dateien
enthält? Mit der obigen Ergänzung geschieht nichts. Kein Ersetzen, aber auch keine Meldung
oder ein Eintrag in eine Logdatei.

Gruss, Hans