------------------------------------------------------------------------------------------------------------------------------------- 
on Initialize() 
	set my text item delimiters to "" 
end Initialize 
 
on Finalize() 
	with timeout of 14400 seconds -- 4 Stunden 
		activate 
		display alert "Fertig" message "Objekt(e) wurde(n) verarbeitet." 
	end timeout 
end Finalize 
 
on ProcessAFileOrFolder(theFile) 
	if (theFile as string) ends with ":" then 
		ScanAFolder(theFile) 
	else 
		ProcessAFile(theFile) 
	end if 
end ProcessAFileOrFolder 
 
on ScanAFolder(theFolder) 
	set fileNames to list folder theFolder without invisibles 
	repeat with aFile in fileNames 
		set theFile to (theFolder as string) & contents of aFile 
		ProcessAFileOrFolder(alias theFile) 
	end repeat 
end ScanAFolder 
 
on open of filesList 
	my Initialize() 
	repeat with aFile in filesList 
		ProcessAFileOrFolder(contents of aFile) 
	end repeat 
	my Finalize() 
end open 
 
on run 
	activate 
	display alert "ACHTUNG!" message "Läuft nur als Droplet. Bitte Objekt(e) auf das Script ziehen." as warning 
end run 
------------------------------------------------------------------------------------------------------------------------------------- 
on ProcessAFile(csvDatei) 
	if (csvDatei as string) does not end with ".csv" then 
		activate 
		display alert "ACHTUNG!" message "Keine CSV-Datei. Bitte eine CSV-Datei auf das Script ziehen." as warning 
		error number -128 
	end if 
	set SourceFolder to choose folder with prompt "Bitte den zu bearbeitenden Oberordner wählen:" without invisibles 
	set csvList to {} 
	set csvList to my readLogFile(csvDatei as string) 
	repeat with tmpCsvLine in csvList 
		set my text item delimiters to ";" 
		set tmpOldFileName to text item 1 of tmpCsvLine as string 
		set tmpNewFileName to text item 2 of tmpCsvLine as string 
		set my text item delimiters to "" 
		if tmpOldFileName ≠ "" and tmpNewFileName ≠ "" then 
			set tmpAllFiles to {} 
			set tmpFileList to {} 
			-- letzter doppelpunkt vom pfad entfernen 
			set startPath to (characters 1 thru -2 of (SourceFolder as string)) as string 
			-- alle bilder aus dem oberordner holen die mit dem namen anfangen 
			set tmpAllFiles to do shell script ("find " & quoted form of (POSIX path of startPath) & " -type f -name " & quoted form of (tmpOldFileName) & " -not -path '*layouts*' " as string) 
			log tmpAllFiles 
			 
			if tmpAllFiles ≠ "" then 
				set my text item delimiters to return 
				set tmpAllFiles to every text item of tmpAllFiles 
				set my text item delimiters to "" 
				repeat with tmpFoundFile in tmpAllFiles 
					set tmpHSFpath to POSIX file (tmpFoundFile as string) as string 
					set end of tmpFileList to tmpHSFpath 
				end repeat 
			end if 
			 
			log tmpFileList 
			repeat with tmpFile in tmpFileList 
				try 
					tell application "Finder" to set name of file tmpFile to tmpNewFileName 
				on error 
					activate 
					display dialog "Die Datei" & return & tmpFile & return & "konnte nicht umbenannt werden" giving up after 30 
				end try 
			end repeat 
		end if 
	end repeat 
end ProcessAFile 
------------------------------------------------------------------------------------------------------------------------------------- 
on readLogFile(theFile) 
	try 
		set tmpList to paragraphs of (do shell script "tr '\\r' '\\n' < " & quoted form of (POSIX path of (theFile as string))) 
		if tmpList &#8800; {} then return tmpList 
		return false 
	on error 
		return false 
	end try 
end readLogFile 
-------------------------------------------------------------------------------------------------------------------------------------