Hallo Jörg,

hier schon mal die Lösung, wie sich die Dialoge wegen fehlender Schriften oder Bilder unterdrücken
lassen. Zunächst versuchte ich es mit
set user interaction level to never interact

Funktioniert mit InDesign CS vorzüglich, aber hilft mit Illustrator CS nicht.

Doch nicht verzagen: Im Verzeichnis wird für den Open-Befehl die Option [dialogs boolean] angeboten.

Im Script also zum Handler on collectFiles(filePath, folName) scrollen
und den öffnen-Befehl so ergänzen:

Code

open filePath [b]as alias [b]without dialogs 

Gruss, Hans

Hallo Hans

Ja also das mit dem "without dialogs" funktioniert natürlich.


Ist es nun möglich alle drei Scripte zu einem zu vereinen? Also das das Script mit Quark InDesign und Illustrator umgehen kann?


Gruß Jörg
Und Vielen dank für deine schnellen Lösungen.

Hallo Jörg,

ja, ich glaube, dass es möglich ist, Dateien von alle drei Programmen mit ein und demselben
Script zu behandeln.

Aber ich muss noch andere Projekte vorantreiben und die Prioritäten nach der Dringlichkeit
setzen. Deshalb musst Du Dich noch etwas gedulden. Vor allem weil die beiden bisherigen
Lösungen ja schon recht gut funktionieren.

Gruss, Hans

Hallo Jörg,

die grobe Fassung des Scripts steht. Mit Abfrage nach dem Zielordner, in welchem automatisch
ein Ordner mit dem Namen der aktuellen Datei angelegt wird und darin die Unterordner "Bilddaten",
"Composing" und "Schriften".

Ein Fortschrittsbalken mit Statusanzeige zeigt das Kopieren der Bilddateien an. Am Schluss wird
eine Rapportdatei erstellt. Soeben mit einem QuarkXPress-Projekt getestet.

Die Handler, welche sich um die InDesign- und Illustrator-Dateien kümmern sind eingebaut, müssen
aber noch getestet werden.

Es kann noch eine Weile dauern, bis die erste Version versandbereit sein wird, denn die Testerei
ist aufwendig. Zumal ich ein paar InDesign- und Illustrator-Dokumente erst herstellen muss.

Gruss, Hans

Vielen Dank nochmals

Ja ist kein Problem wenn das ganze noch ein wenig dauert.

Du kannst mir das Script auch zuschicken das ich es Teste, wenn das dir ein wenig Arbeit abnimmt.



Gruß Jörg

Hallo Jörg,

ja, ich werde Dir das Script auf jeden Fall zuschicken, weil es voraussichtlich zu umfangreich
sein wird, um es hier zu posten. Doch die ersten Tests muss ich schon selbst durchführen, damit
ich prüfen kann, ob meine Ideen auch funktionieren.

Aber weil ich nun mal keine Illustrator-Layouts mit plazierten EPS-Files habe, muss ich welche
zuerst basteln ...

Aktueller Stand: QuarkXPress und Illustrator werden schon wie gewünscht unterstützt. Heute Abend
werde ich noch das Verhalten mit InDesign testen.

Frage: Gibt es unter den QuarkXPress-Projekten auch welche mit mehr als einem Layout? Ich werde
den Code noch so ergänzen, dass in diesem Fall die Bilder aller Layouts gesammelt werden.
In denselben Bilddaten-Ordner? Oder noch Unterordner erstellen?

Gruss, Hans

Hallo Hans,
also wenns soweit ist hätte ich auch Interesse an deinem Script.

Gruß
TMA

Hallo TMA,

ja, kein Problem. Ich weiss aber noch nicht, ob die erste Version heute Abend fertig werden wird
(tagsüber habe ich keine Zeit dafür: ein paar sehr dringende Arbeiten zu erledigen).

Ich werde das Script auf der Website http://www.fachhefte.ch der Allgemeinheit zur Verfügung stellen.
Aber erst, wenn es der Jörg ausgiebig getestet hat. Wenn Du gerne eine Vorabversion hättest, dann
musst Du mir Deine E-Mail-Adresse zumailen.

Gruss, Hans

Hi Hans,
ist nicht eilig bei mir. Für unsere Zwecke hier haben wir schon angepasste Scripte. Wollt nur so mal reinschauen ob man noch was lernen kann.

Danke und Gruß
TMA

Hallo Jörg,

die erste Version des Droplets ist unterwegs zu Dir. Jetzt läuft es so, wie ich mir es vorgestellt habe.
Jedenfalls mit meinen einfachen Testdokumenten. Mit "richtigen" sind überraschungen nicht ausgeschlossen.

Beim ersten Ausführen muss der Haupt-Archiv-Ordner ausgewählt werden. Das kann auch im voraus, durch
Doppelklick auf das Icon des Droplets ausgelöst werden.

Die zu archivierenden Dokumente können lose gedroppt werden. Oder in einem Ordner (auch mit Unterordnern)
enthalten sein. Dateien, welche nicht QuarkXPress-Projekte (oder -Dokumente), InDesign- oder Illustrator-
Dokumente sind, sollten den Ablauf nicht stören, werden aber im Rapport vermerkt.

Auch die Namen der Bilder, welche nicht gefunden werden, sind im Rapport aufgelistet.

Das Script geht davon aus, dass die LowRes- und die HiRes-Dateien ein identisches Suffix aufweisen.
Falls es Ausnahmen gibt, sollte ich die Liste haben, damit ich das Script ergänzen kann.

Was noch fehlt: Das Behandeln mehrerer Layouts von QuarkXPress-Projekten. Ist für die Version 02 vorgesehen.

Gruss, Hans

Hallo Jörg,

die Version 02 des Scripts ist unterwegs zu Dir.

Neu sind die Tests, welche bei jeder Datei prüfen, ob das entsprechende
Programm läuft. Offensichtlich gibt es Probleme, wenn z.B. InDesign erst
durch einen 'tell application InDesign CS'-Befehl gestartet wird. Weil die
Umgebung noch nicht hochgefahren ist, wenn der nächste Befehl ausgeführt
wird, sind die Ausdrücke 'user interaction level' noch nicht bekannt und
das Resultat ist eine Fehlermeldung.

Falls notwendig, kommt dann auch ein Dialog, welcher aber den Anwender
bittet, das entsprechende Programm zu starten. Auf "OK" wird die Ausführung
des Scripts abgebrochen.

Eine weitere Neuerung, wie angekündigt: Wenn ein XPress-Projekt mehrere
Layouts aufweist, werden nun alle Bilder gesammelt.

Gruss, Hans

Hallo Hans

Endlich habe ich es mal geschaft dein Script zu Testen.

Aber leider macht die Zeile "set user interaction level to never interact" von InDesign immer noch probleme.

Außerdem finde ich es nicht unbedingt von Vorteil das die Programme schon alle offen sein müssen. Besser wäre wen nur das Programm geöffnet wird das auch tatsächlich für das dokument benötigt wird.

Bei der Auswahl wo hin die Datein gesammelt werden sollen wäre mir auch lieber jedes mal erneut den Ort zu wählen als einmal Ausgewählt (z.b. Desktop) und dann wird immer auf den Desktop gesammelt.

Gut finde ich die Status Anzeige und das der Ordner der Erstellt wird den Name des Dokuments hat was bei uns nämlich der Job Name ist.


Ich weiß nur nicht warum diese eine Zeile so Probleme macht. Vieleicht ist es doch besser wenn man versucht meine zwei bisherigen Scripts in eins zu quetschen. Denn die laufen ja.



Hier nochmal meine zwei bisherigen Scripts.


Script 1
[code:1]
property targetFolder : ""

global ctr
global docCtr
global docList
global docName
global missList
global timeStamp1
global timeStamp2

on run
 showConfig()
end run

on showConfig()
 try
  targetFolder as alias
  set dR to button returned of (display dialog "Der Pfad des Zielordners:
" & targetFolder buttons ¬
   {" Abbruch ", "Anderen bestimmen", "OK"} default button 3 with icon 1)
  if dR = "Anderen bestimmen" then
   with timeout of 300 seconds
    set targetFolder to (choose folder with prompt "Einen neuen Zielordner für die Bild-Dateien wählen.") as Unicode text
   end timeout
  else
   error number -128
  end if
 on error errMsg number errNum
  if errNum is not -128 then
   set dR to button returned of (display dialog "Der Zielordner ist nicht bestimmt." buttons ¬
    {" Abbruch ", "Bestimmen"} default button 2 with icon 2)
   if dR = "Bestimmen" then
    with timeout of 300 seconds
     set targetFolder to (choose folder with prompt "Einen Zielordner für die Bild-Dateien wählen.") as Unicode text
    end timeout
   else
    error number -128
   end if
  end if
 end try
 return targetFolder
end showConfig

on open fileList
 if targetFolder is not "" then
  try
   targetFolder as alias
  on error
   showConfig()
  end try
 else
  showConfig()
 end if
 set ctr to 0
 set docCtr to 0
 set docList to {}
 set missList to {}
 set filePath to (item 1 of fileList) as string
 -- den Handler zum Prüfen des Creators aufrufen
 set okay to checkFile(filePath)
 if okay then
  set docCtr to 1
  -- die Zeit des Beginns speichern
  set timeStamp1 to current date
  set AppleScript's text item delimiters to {":"}
  -- den Ordnernamen vorbereiten
  set folName to text item -1 of filePath
  set AppleScript's text item delimiters to {""}
  -- ein eventuelles Suffix abschneiden und den Ordnernamen mit "_f" ergänzen
  if folName ends with ".eps" then
   set folName to (text 1 thru -5) of folName & "_f"
  else if folName ends with ".ai" then
   set folName to (text 1 thru -4) of folName & "_f"
  else
   set folName to folName & "_f"
  end if
  -- Aufruf der Subroutine zum Erzeugen des Hauptordners
  makeFolder(folName)
  -- die Subroutine aufrufen, welche die Bilddateien sammelt
  collectFiles(filePath, folName)
  -- die Zeit stoppen
  set timeStamp2 to current date
  -- den Rapport schreiben
  makeReport(folName)
 end if
 -- den Anwender benachrichtigen
 displayDialog()
end open

on checkFile(filePath)
 try
  set fileCreator to file creator of (info for file filePath)
  if fileCreator = "ART5" then
   return true
  else
   return false
  end if
 on error
  return false
 end try
end checkFile

on makeFolder(folName)
 try
  alias (targetFolder & folName)
 on error
  tell application "Finder" to make new folder at folder targetFolder with properties {name:folName}
 end try
end makeFolder

on collectFiles(filePath, folName)
 global imgList
 global imgRef
 set destFolder to (targetFolder & folName)
 tell application "Illustrator CS"
  try
   open filePath as alias without dialogs
   tell document 1
    set docName to name
    set imgList to {}
    set imgRef to (file path of every placed item)
    if class of imgRef is not list then set imgRef to {imgRef}
    repeat with k from 1 to count imgRef
     set imgPath to (item k of my imgRef)
     if imgPath is not null then
      set imgPath to imgPath as Unicode text
      if imgPath is not in imgList then
       set end of imgList to imgPath
      end if
     end if
    end repeat
    if imgList is not {} then
     set imgCount to count of imgList
     set AppleScript's text item delimiters to {":"}
     repeat with i from 1 to imgCount
      set imgPath to item i of my imgList
      set imgName to last text item of imgPath
      if imgPath contains ":layouts:" then
       set finePath to ((text items 1 thru -3 of imgPath) & imgName) as string
      else
       set finePath to imgPath
      end if
      my dupFile(finePath, destFolder, imgName)
     end repeat
     set AppleScript's text item delimiters to {""}
    end if
   end tell
   set docCtr to 1
   close document 1 without saving
  on error
   try
    close document 1 without saving
   end try
  end try
 end tell
 try
  tell application "Finder" to duplicate file filePath to folder destFolder with replacing
 end try
end collectFiles

on dupFile(finePath, destFolder, imgName)
 try
  tell application "Finder" to duplicate file finePath to folder destFolder with replacing
 on error
  set end of missList to imgName
  set ctr to ctr + 1
 end try
end dupFile

on makeReport(folName)
 set rPath to targetFolder & "Rapport.txt"
 set rf to "Start • " & timeStamp1 & return
 if docCtr is greater than 0 then
  set rf to rf & "Die Bild-Dateien des Illustrator-Dokuments \"" & folName & "\" sammeln" & return
  if ctr is greater than 0 then
   set rf to rf & "Unauffindbare Bild-Dateien: " & ctr & return & return
   try
    repeat with i from 1 to count of missList
     set rf to rf & item i of missList & return
    end repeat
    set rf to rf & return & "Ende • " & timeStamp2 & return
    set rf to rf & "---------------------------------------------------" & return & return
   end try
  else
   set rf to rf & "Alles okay." & return
   set rf to rf & "Ende • " & timeStamp2 & return
   set rf to rf & "---------------------------------------------------" & return & return
  end if
 else
  set rf to rf & "Kein gültiges Illustrator-Dokument." & return
  set rf to rf & "Ende • " & timeStamp2 & return
  set rf to rf & "---------------------------------------------------" & return & return
 end if
 try
  open for access file rPath with write permission
  write rf to file rPath starting at eof
  close access file rPath
 on error
  try
   close access file rPath
  end try
 end try
end makeReport

on displayDialog()
 activate
 if ctr = 0 then
  if docCtr is greater than 0 then
   display dialog "Fertig.

Alles okay." buttons "OK" default button 1 with icon 1 giving up after 5
  else
   display dialog "Fertig.

Kein gültiges Illustrator-Dokument." buttons "OK" default button 1 with icon 2 giving up after 2
  end if
 else if ctr is 1 then
  display dialog "Fertig.

Unauffindbare Bilddatei: " & ctr buttons "OK" default button 1 with icon 2 giving up after 50
 else
  display dialog "Fertig.

Unauffindbare Bilddateien " & ctr buttons "OK" default button 1 with icon 2 giving up after 50
 end if
end displayDialog[/code:1]


Script 2
[code:1]global destinationFolder

on Initialize()
 set my text item delimiters to ""
 set destinationFolder to choose folder with prompt "Bitte Zielordner wählen"
 set imageFolder to destinationFolder & "Bilddaten"
 set composingFolder to destinationFolder & "Composing" as string
 set fontFolder to destinationFolder & "Schriften" as string
 tell application "Finder"
  try
   make new folder at destinationFolder with properties {name:"Bilddaten"}
   make new folder at destinationFolder with properties {name:"Composing"}
   ---make new folder at destinationFolder with properties {name:"Schriften"}
  end try
 end tell
end Initialize


on Finalize()
 tell application "Finder"
  activate
  display dialog "Für Ausgabe Sammeln wurde erfolgreich beendet"
 end tell
end Finalize


on ProcessAFileOrFolder(theFile)
 set theFileInfo to info for theFile
 if folder of theFileInfo then
  ScanAFolder(theFile)
 else
  ProcessAFile(theFile)
 end if
end ProcessAFileOrFolder


on ScanAFolder(theFolder)
 set fileNames to list folder theFolder
 repeat with aFile in fileNames
  set theFile to (theFolder as string) & contents of aFile
  ProcessAFileOrFolder(alias theFile)
 end repeat
end ScanAFolder


on open of filesList
 Initialize()
 repeat with aFile in filesList
  ProcessAFileOrFolder(contents of aFile)
 end repeat
 Finalize()
end open


on run
 set theFolder to choose folder with prompt "Bitte Zielordner für die zu Zusammenstellung der Daten wählen:"
 Initialize()
 ScanAFolder(theFolder)
 Finalize()
end run


on ProcessAFile(theFile)
 tell application "Finder"
  set theCreator to the creator type of theFile
  duplicate file (theFile as string) to folder (destinationFolder & "Composing" as string)
 end tell
 if theCreator is "InDn" then
  --if (theFile as string) ends with ".indd" then
  -------------------------------------------------------------------------------------------Indesign-------------------------------------------------------------------------------------------------
  set theFile to theFile as string
  tell application "InDesign CS"
   set «class UIAc» to «constant elnteNvr»
   try
    «event CoReclos» every document
   end try
   try
    open file theFile
   on error
    tell application "Finder"
     display dialog ("Die Datei " & name of alias theFile as string) & " konnte nicht geöffnet werden"
     return
    end tell
   end try
   tell document 1
    if not («event CoRedoex») then
     display dialog ("Kein Dokument geöffnet")
     return false
    end if
    set tmpList to {}
    set tmpList to every «class clnk»
    repeat with theMissingLink in tmpList
     set theFileToWork to «class path» of theMissingLink as string
     tell application "Finder"
      if exists file theFileToWork then
       set filename to name of file theFileToWork
       if name of parent of file theFileToWork = "layouts" then
        set tmpFoldert to parent of parent of file theFileToWork as string
        if exists file (tmpFoldert & filename as string) then
         set the highFile to (tmpFoldert & filename as string)
        else
         set tmpList to (every file of folder tmpFoldert whose name starts with (my suffixDel(filename as string) as string))
         if tmpList ≠ {} then
          set the highFile to item 1 of tmpList as string
         else
          set highFile to false
         end if
        end if
       else
        set the highFile to theFileToWork
       end if
       if highFile ≠ false then
        duplicate file (highFile as string) to folder (my destinationFolder & "Bilddaten" as string) with replacing
       end if
      end if
     end tell
    end repeat
    «event CoResave»
    «event CoReclos»
   
   end tell
  set «class UIAc» to «constant elnteInA»
  end tell
 end if
 -------------------------------------------------------------------------------------------QuarkXPress Passport----------------------------------------------------------------------------
 if theCreator is "XPR3" then
  --if (theFile as string) ends with ".qxd" then
  tell application "QuarkXPress Passport"
   try
    close every document
   end try
   try
    open theFile remap fonts no use doc prefs yes
   on error
    tell application "Finder"
     display dialog ("Die Datei " & name of theFile as string) & " konnte nicht geöffnet werden"
     return
    end tell
   end try
   tell front document
    set picBoxcount to count every picture box
    repeat with i from 1 to picBoxcount
     tell image 1 of picture box i
      if not missing then
       try
        if (file path as string) ≠ "null" then
         set theFileToWork to (file path as string)
         tell application "Finder"
          if exists file theFileToWork then
           set filename to name of file theFileToWork
           if name of parent of file theFileToWork = "layouts" then
            set tmpFoldert to parent of parent of file theFileToWork as string
            if exists file (tmpFoldert & filename as string) then
             set the highFile to (tmpFoldert & filename as string)
            else
             set tmpList to (every file of folder tmpFoldert whose name starts with (my suffixDel(filename as string) as string))
             if tmpList ≠ {} then
              set the highFile to item 1 of tmpList as string
             else
              set highFile to false
             end if
            end if
           else
            set the highFile to theFileToWork
           end if
           if highFile ≠ false then
            duplicate file (highFile as string) to folder (my destinationFolder & "Bilddaten" as string) without replacing
           end if
          end if
         end tell
        end if
       end try
      end if
     end tell
    end repeat
    try
     close without saving
    end try
   end tell
  end tell
 end if
 
 
end ProcessAFile


on suffixDel(i)
 set text item delimiters of me to ""
 set i to i as string
 if i contains "." then
  set my text item delimiters to "."
  set i to every text item of i
  if (count of every character of (last item of i as string)) ≠ 4 then
   set i to (items 1 thru -2 of i) as string
   set my text item delimiters to ""
   return i
  else
   set i to i as string
   set text item delimiters of me to ""
   return i
  end if
 else
  return i
 end if
end suffixDel[/code:1]

Hallo Jörg,

Dein InDesign hat ein ziemliches Problem. Der Beweis: In Deinem Code sind jede Menge Rawcodes,
(z.B. 'set «class UIAc» to «constant elnteNvr»'). Das ist ein Hinweis darauf, dass etwas ganz
und gar nicht stimmt. Abhilfe? Eventuell die Präferenzen löschen.

Beim Gebrauch des Droplets müssen nicht alle drei Programme offen sein. Nur beim allerersten
öffnen des Scripts und beim folgenden Speichern als kompiliertes Script. Danach kann man die
nichtbenötigten Programme wieder beenden.

Aber wenn Du zum Beispiel Bild-Dateien aus Illustrator-Dateien sammeln willst, dann ist es
von Vorteil, den Illustrator vorher zu starten. Und nicht erst durch den Aufruf im Script.
Dasselbe gilt auch für die anderen beiden Programme.

Okay, wenn Du bei jedem Ausführen einen Dialog sehen möchtest, um den Hauptordner auszuwählen,
dann werde ich das Script entsprechend ändern und es Dir zustellen.

Gruss, Hans

Vielen Dank  für eure Hilfe

Jetzt funktioniert alles bestens.

Und es lag natürlich an meinem InDesign :-) Fehler ist behoben.


Grüsse Jörg

Hallo Jörg,

bitteschön! Ich bin froh, dass es nun klappt.

Gruss, Hans