Hallo

Ich habe angefangen mir ein Script zu basteln das mir Quark dokumente in InDesign öffnet und dann neu Abspeichern soll. Nur habe ich mit dem Abspeichern noch probleme.
Ich verwende 10.4 und Indesign cs.

Die Lösung liegt warscheinlich schon jedem auf der Zunge nur mir nicht :-(


Hier ist mein Script

[code:1]property quellpfad : "Applications:QXD_to_Indd:Eingang"
---------------------------------------------------------------------------------------------------------------------

on idle
 set watchlist to (list folder quellpfad)
 try
  repeat with x in watchlist
   set watchfile to quellpfad & ":" & x
   if x does not start with "." then
    checkFileSize(watchfile)
   end if
  end repeat
 end try
 return 90
end idle




on checkFileSize(x)
 set myStartsize to size of (info for file (x as string))
 delay 5
 set myEndsize to size of (info for file (x as string))
 if myStartsize is myEndsize then
  tell application "InDesign CS"
   open file (x as string)
   save document 1
   
  end tell
  try
   do shell script "rm " & the POSIX path of x as string
  end try
 else
  checkFileSize(x)
 end if
end checkFileSize
[/code:1]

Hi,
versuchs mal mit:

[code:1]
save document 1 to file... (ablageort+filename)
close document 1
[/code:1]

gruß
TMA

Hallo TMA

nein Leider funktioniert das nicht.



Gruß Jörg

komisch, bei mir klappts. hab ein xpress4 dokument benutzt, das kann man ja so öffnen in IDcs. xpress6 dokumente kann ich leider nicht öffnen da ich das plug-in nicht installiert habe.

vielleicht hat ja jemand noch ne lösung.

gruß
TMA

Hallo Jörg,

der Rat von TMA ist richtig. Aber damit es klappt, musst Du auch einen Zielort für die konvertierten Dateien
angeben. Und einen Namen für das Dokument. Und wenn der Quellpfad nur mit "Applications" beginnt, wird dieser
Ordner nicht gefunden. Das öffnen in InDesign sollte in einen 'try'-Wickel gepackt werden. Und zuvor sollte auch
der Dateityp getestet werden. Kann natürlich entfallen, wenn nur XPress-Dateien in den Hotfolder gelegt werden.
---
property quellpfad : (path to applications folder as Unicode text) & "QXD_to_Indd:Eingang:"
property zielpfad : (path to applications folder as Unicode text) & "QXD_to_Indd:Ausgang:"
---------------------------------------------------------------------------------------------------------------------

on idle
   set watchlist to (list folder quellpfad)
   try
      repeat with x in watchlist
         set watchfile to quellpfad & x
         if x does not start with "." then
            checkFileSize(watchfile)
         end if
      end repeat
   end try
   return 90
end idle

on checkFileSize(x)
   set myStartsize to size of (info for file x)
   delay 5
   set myEndsize to size of (info for file x)
   if myStartsize is myEndsize then
      set docName to name of (info for file x)
      if docName ends with ".qxd" then
         set docName to text 1 thru -5 of docName
      end if
      tell application "InDesign CS"
         activate
         open (x as alias)
         save document 1 to file (zielpfad & docName & ".indd")
         close document 1 saving no
      end tell
      try
         do shell script "rm " & POSIX path of x
      end try
   else
      checkFileSize(x)
   end if
end checkFileSize
---
Hier funktioniert es. Habe es allerdings nur mit einer sehr einfachen Datei getestet.

Gruss, Hans

Vielen dank für eure Hilfe.

Es klappt.


thx
Jörg