Hallo Hans,

habe Dein Script so geändert, daß es bei Indd-Objekten funktioniert.

Es werden vom aktivierten Objekt 3 Duplikate erzeugt.
Das 1. erhält eine schwarze Kontur 4mm
Das 2. eine weisse Kontur 3.8 mm
Das 3. eine weisse Füllung
Das Original wird in den Vordergrund gestapelt

Es funktioniert, wenn 1 Objekt aktiviert ist, wenn mehrere Objekte aktiviert sind passiert nichts.
d.h. es werden nur Duplis erzeugt
____________
tell document 1 of application "Adobe InDesign CS2"
activate
set curSel to selection
set TestCopy to every item of selection

set TestCopy2 to duplicate TestCopy
repeat with i from 1 to count of curSel
try
set newFrame1 to TestCopy2
set newFrame2 to duplicate newFrame1
set newFrame3 to duplicate newFrame2
-- Schwarze Kontur zentrisch
set properties of newFrame1 to ¬
{stroke color:"Black", stroke weight:"4 mm", stroke alignment:center alignment ¬
, end cap:butt end cap, end join:miter end join}
-- Weisse Kontur zentrisch
set properties of newFrame2 to ¬
{stroke color:"Paper", stroke weight:"3.8 mm", stroke alignment:center alignment ¬
, end cap:butt end cap, end join:miter end join}

set properties of newFrame3 to ¬
{fill color:"Paper"}
end try
end repeat
-- Bild(er) in Vordergrund stapeln
bring to front TestCopy
end tell
------------------
ps
Scriptt vom 17. Feb. 2007
http://www.page-online.de/page/forum/viewthread/2982/

herzliche Grüße
willem

Hallo Willem,

vielen Dank für das Posten Deines Codes.

Unklar ist, ob Du damit zufrieden bist, oder ob Du möchtest, dass das
Script auch mehrere ausgewählte Objekte behandeln kann.

Gruss, Hans

Hallo Hans,

>> Unklar ist, ob Du damit zufrieden bist, oder ob Du möchtest, dass das
>> Script auch mehrere ausgewählte Objekte behandeln kann.

Wenn Du es so ändern könntest, daß man auch mehrere Objekte behandeln kann - das wäre super,
ich bekomme das nicht hin.

Gruesse willem

Hallo Willem,

die Wiederholschleife ist nicht notwendig, wenn nur ein Objekt
ausgewählt ist. Bei mehreren Rahmen, hingegen, braucht es diese
schon. Aber an anderer Stelle:
---
tell document 1 of application "Adobe InDesign CS2"
   activate
   try
      set TestCopy to every item of selection
      set newFrame1 to duplicate TestCopy
      set newFrame2 to duplicate newFrame1
      set newFrame3 to duplicate newFrame2
      repeat with i from 1 to count of TestCopy
         -- Schwarze Kontur zentrisch
         set properties of item i of newFrame1 to ¬
            {stroke color:"Black", stroke weight:"4 mm", stroke alignment:center alignment ¬
               , end cap:butt end cap, end join:miter end join}
         -- Weisse Kontur zentrisch
         set properties of item i of newFrame2 to ¬
            {stroke color:"Paper", stroke weight:"3.8 mm", stroke alignment:center alignment ¬
               , end cap:butt end cap, end join:miter end join}
         -- Hintergrundfarbe "Papier"
         set properties of item i of newFrame3 to ¬
            {fill color:"Paper"}
      end repeat
   end try
   -- Bild(er) in Vordergrund stapeln
   bring to front TestCopy
end tell
---
Zuerst wird alles mehrfach dupliziert. In der Wiederholschleife wird
dann jeweils das aktuelle Element der entsprechenden Sammlung
angesprochen.

Gruss, Hans

Hallo Hans,

habe es gleich ausprobiert -

Eins wäre da noch:
Wenn Bilder platziert sind sollten diese bei den Duplis newFrame1, newFrame2 und newFrame3 entfernt werden.

Habe versucht mit "delete graphic1 of newFrame" die Bilder zu löschen - es funktioniert aber nicht.

Danke!
Gruesse willem