[GastForen Programmierung/Entwicklung AppleScript Indesign_Textpassage in neuen Textrahmen

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

5. Okt 2006, 10:59
Beitrag # 1 von 17
Bewertung:
(3059 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Scripters, hallo Hans,

habe mir ein Script gestrickt, es extrahiert aus dem Haupttextstrom Legendentext und fügt diesen auf neuer Seite in neuen Rahmen. Das Dumme ist nur, dass sämtliche Formatierungen flöten gehen, lässt sich der cut-befehl mit einer entsprechenden Option erweitern oder was geht?

tell application "Adobe InDesign CS2"
tell front document
set thisStory to index of every story whose name of applied paragraph style of paragraph 1 is "BTitel"
tell story thisStory
tell (every paragraph whose name of applied paragraph style is "Petit")
set CountLegends to count of (every paragraph whose word 1 is "Figure")
end tell
end tell
end tell
end tell

on CutLegend(thisStory)
tell application "Adobe InDesign CS2"
tell front document
tell story thisStory
tell (every paragraph whose name of applied paragraph style is "Petit")
select (paragraph 1 whose word 1 is "Figure")
end tell
end tell
end tell
cut
end tell
end CutLegend

on CreateFrames(CountLegends, thisStory)
set LegNum to 1
repeat CountLegends times
CutLegend(thisStory)
tell application "Adobe InDesign CS2"
tell front document
activate
make page
set Seitenzahl to name of last page
if Seitenzahl mod 2 is 0 then
set theBounds to {"29 mm", "28.5 mm", "59 mm", "193.5 mm"}
else
set theBounds to {"29 mm", "227 mm", "59 mm", "391.5 mm"}
end if
tell page Seitenzahl
set Bildlegende to make text frame
tell Bildlegende
set the geometric bounds to theBounds
--set fill color to "Blau"
set the label to "Bildlegende_" & LegNum
set contents to the clipboard
set LegNum to LegNum + 1
end tell
end tell
end tell
end tell
end repeat
end CreateFrames

CreateFrames(CountLegends, thisStory)

bin dankbar für jede Info!

Gruß
Jürgen
X

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

5. Okt 2006, 11:31
Beitrag # 2 von 17
Beitrag ID: #421205
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

ich muss gleich weg. Die Sitzung wird bis 15 Uhr dauern.
Anschliessend werde ich mir Dein Problem vornehmen.

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

5. Okt 2006, 12:32
Beitrag # 3 von 17
Beitrag ID: #421206
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hans,

net hudle, das rennt uns nicht davon, ich kann warten.
Bis denn

Jürgen


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

5. Okt 2006, 14:54
Beitrag # 4 von 17
Beitrag ID: #421207
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

mit paste würden die Textattribute des entfernten Textes übernommen.
Besser ist aber, den Text mit move zu verschieben.

Ich habe die Reihenfolge der Handler umgekehrt, damit die Aktion von
oben nach unten gelesen werden kann.

Verschiedene kleine Änderungen habe ich angebracht. Aber auch diese:
Das Ersetzen der mod-2-Methode (zum Bestimmen, ob die neue Seite
links oder rechts steht) durch das CS2-Attribut side, welches die Werte
left hand, right hand oder single sided zurückgibt.
Code
tell document 1 of application "Adobe InDesign CS2" 
  activate
  set thisStory to index of every story whose name of applied paragraph style of paragraph 1 is "BTitel"
  tell story thisStory
    tell (every paragraph whose name of applied paragraph style is "Petit")
      set CountLegends to count of (every paragraph whose word 1 is "Figure")
    end tell
  end tell
end tell

CreateFrames(CountLegends, thisStory)

on CreateFrames(CountLegends, thisStory)
  set LegNum to 1
  repeat CountLegends times
    tell document 1 of application "Adobe InDesign CS2"
      activate
      make page
      set Seitenzahl to name of last page
      if side of page Seitenzahl is left hand then
        set theBounds to {"29 mm", "28.5 mm", "59 mm", "193.5 mm"}
      else
        set theBounds to {"29 mm", "227 mm", "59 mm", "391.5 mm"}
      end if
      tell page Seitenzahl
        set Bildlegende to make text frame
        tell Bildlegende
          set geometric bounds to theBounds
          set label to "Bildlegende_" & LegNum
          my MoveLegend(thisStory, Bildlegende)
          set LegNum to LegNum + 1
        end tell
      end tell
    end tell
  end repeat
end CreateFrames

on MoveLegend(thisStory, Bildlegende)
  tell document 1 of application "Adobe InDesign CS2"
    tell story thisStory
      tell (every paragraph whose name of applied paragraph style is "Petit")
        move (paragraph 1 whose word 1 is "Figure") to after insertion point 1 of Bildlegende
      end tell
    end tell
  end tell
end MoveLegend

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

5. Okt 2006, 16:28
Beitrag # 5 von 17
Beitrag ID: #421208
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hans, du bist der König aller Scripter,

konnte mich die ganze Zeit nicht um das Problem kümmern da ich meinem alten Quecksilber-Mac heute mittag zuerst 'nen DVD-Laufwerk und dann den Tiger spendiert hab'.

Bin dann ein wenig irregelaufen, denn auch das hat nichts bezweckt:

tell clipboard preferences -- properties
set properties to {prefer styled text when pasting:true}
end tell

Eben noch versuchte ich mit diffusen insertion points und paste rumzuexperimentieren und hab gar nicht gemerkt dass du die Sache schon so souverän in den Griff bekommen hast. Ich hätte für sowas wahrscheinlich noch eine halbe Ewigkeit gebraucht.

Ich bin total begeistert!
Danke Hans!


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

5. Okt 2006, 19:10
Beitrag # 6 von 17
Beitrag ID: #421209
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

Bitteschön! Und danke für die Blumen! :-) Aber es ist sicher alles halb so wild ...

Für den Fall, dass Du mal doch ein cut und paste einsetzen möchtest:
---
         end tell -- document
         set selection to insertion point 1 of Bildlegende
         paste
      end tell -- application
   end repeat
end CreateFrames
---
Wobei das paste innerhalb der tell application-Schleife plaziert werden muss (wie hier
mit den beiden Comments angedeutet).

Noch zwei Hinweise zum obenstehenden Script:

1) Statt den Namen der letzten Seite zu verlangen, um die Seitennummer zu erhalten,
lieber die absolute Position der Seite im Dokument feststellen:
---
set Seitenzahl to document offset of last page
---
Warum? Wenn mal bei einem Dokument ein Abschnittsbeginn definiert ist und ein Präfix,
dann gibt es mit name of last page eine Fehlermeldung.
Je nachdem, wie man den Abschnittsbeginn herstellt, fügt InDesign automatisch das
Präfix "Abs1:" ein. Und dann kann man die Seiten nur noch mit absoluten Werten
ansprechen (auch wenn die Checkbox "Bei Seitennummerierung Präfix verwenden"
nicht aktiviert ist).

2) Die x-Werte für den Rahmen auf ungeraden Seiten lassen darauf schliessen, dass
der Ursprung der Linealeinheiten auf "Druckbogen" steht (Voreinstellungen/Einheiten &
Einteilungen). Wenn dort mal "Seite" ausgewählt ist, wird der Rahmen um eine
Seitenbreite zu weit nach rechts erzeugt.

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

7. Okt 2006, 06:08
Beitrag # 7 von 17
Beitrag ID: #421210
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

kann erst jetzt antworten, weil das DSL seitens des Providers nicht funktionierte.
Tja, nochmal Danke für die vielen Tips. Erstaunlich ist für mich, dass außerhalb des document tell-blocks die selection definiert wird.

end tell -- document
        set selection to insertion point 1 of Bildlegende


Ich werde gelegentlich versuchen noch eins drauf zu setzen und das Ganze mit dem Bildeinbau kombinieren, für diejenigen Fälle in denen keine a, b, c usw. Abbildungen existieren.
Der übernächste Schritt wäre dann die Plazierung in der Nähe der Bildreferenz im Text, so à la automatisches Umbruchsystem, ich denke das muss nicht Phantasie bleiben sondern ließe sich mit Indesign umsetzen.

Bis denn
Jürgen


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

7. Okt 2006, 07:58
Beitrag # 8 von 17
Beitrag ID: #421211
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

bitteschön.

Es ist nicht erstaunlich, wenn man bedenkt, was die Variable Bildlegende enthält:
---
tell document 1 of application "Adobe InDesign CS2"
   tell page -1
      set Bildlegende to make text frame
   end tell
end tell
-->text frame id 191 of page id 159 of spread id 154 of document "test_01.indd" of application "Adobe InDesign CS2"

Übrigens: Ganz schön ambitiös, Dein Projekt. Viel Spass!

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

7. Okt 2006, 08:20
Beitrag # 9 von 17
Beitrag ID: #421212
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi,

Ist doch gut wenn noch ein kleiner Rest an Wünschen für eine bessere Zukunft übrigbleibt.

Ähmm, habe grad' was zusammengepfriemelt ist aber nicht vom Elegantesten wie ich das Return behandle, sag mir bitte mal die ästhetischere Variante.

tell document 1 of application "Adobe InDesign CS2"
activate
tell text frame "Bildlegende_5"
set LastChar to last character
if LastChar is return then
tell last character
delete
end tell
end if
fit given frame to content
end tell
end tell

Gruß Jürgen

P.S.:

ich machs jetzt einfach so wieso die Umstände...

tell document 1 of application "Adobe InDesign CS2"
activate
tell text frame "Bildlegende_5"
search for return replacing with ""
(*
set LastChar to last character
if last character is return then
tell LastChar
delete
end tell
end if
*)
fit given frame to content
end tell
end tell


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

7. Okt 2006, 12:48
Beitrag # 10 von 17
Beitrag ID: #421213
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

ist es möglich unterschiedliche Objekte z.B. text frame und page item (rectangle) direkt über horizontal alignment zueinander auszurichten, oder muss man die jeweiligen bounds berechnen  lassen.

P.S.: Bei mir tauchen bei list folder versteckte Dateien auf, hat das mit dem Update auf Tiger zu tun, oder war das schon immer so. Gottseidank habe ich anderweitig in einem deiner Scripts die option without invisibles aufgetrieben... echt cool auch dein Trick mit Farbe "[Keine]" über ...set noneID to (id of every swatch whose name is "none")
set noColor to swatch id noneID... sowas kann man echt gut gebrauchen.

Gruß
Jürgen


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Anonym
Beiträge gesamt: 22827

8. Okt 2006, 11:35
Beitrag # 11 von 17
Beitrag ID: #421214
Bewertung:
(3059 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

habe jetzt noch den Bildimport dazugenommen, es muss halt noch etwas verfeinert werden ist aber auch so schon ganz brauchbar. Habe bei der Gelegenheit mal, Fischer sei dank, den von Ihm stammenden CodeFormatter angeschmissen.

tell document 1 of application "Adobe InDesign CS2"
   activate
   set thisStory to index of every story whose name of applied paragraph style of paragraph 1 is "BTitel"
   tell story thisStory
      tell (every paragraph whose name of applied paragraph style is "Petit")
         set CountLegends to count of (every paragraph whose word 1 is "Figure")
      end tell
   end tell
end tell

CreateFrames(CountLegends, thisStory)

on CreateFrames(CountLegends, thisStory)
   set ItemNum to 1
   repeat CountLegends times
      tell document 1 of application "Adobe InDesign CS2"
         activate
         make page
         set Seitenzahl to name of last page
         if side of page Seitenzahl is left hand then
            set theBounds to {"29 mm", "28.5 mm", "59 mm", "193 mm"}
         else
            set theBounds to {"29 mm", "227 mm", "59 mm", "391.5 mm"}
         end if
         tell page Seitenzahl
            set Bildlegende to make text frame
            tell Bildlegende
               set geometric bounds to theBounds
               set label to "Bildlegende_" & ItemNum
               my MoveLegend(thisStory, Bildlegende)
               search for return replacing with ""
               fit given frame to content
               --set LegNum to LegNum + 1--umgestellt
            end tell
         end tell
         --set ItemNum to LegNum - 1
         my BildImport(Seitenzahl, theBounds, ItemNum)
         my AlignItems(ItemNum)
         set ItemNum to ItemNum + 1
      end tell
   end repeat
end CreateFrames

on MoveLegend(thisStory, Bildlegende)
   tell document 1 of application "Adobe InDesign CS2"
      tell story thisStory
         tell (every paragraph whose name of applied paragraph style is "Petit")
            move (paragraph 1 whose word 1 is "Figure") to after insertion point 1 of Bildlegende
         end tell
      end tell
   end tell
end MoveLegend

on BildImport(Seitenzahl, theBounds, ItemNum)
   tell document 1 of application "Adobe InDesign CS2"
      activate
      set noneID to (id of every swatch whose name is "none")
      set noColor to swatch id noneID
      --set BilderPfad to (file path as Unicode text)
      set BilderPfad to (file path as Unicode text) & "Abbildungen"
      set ListFigs to list folder BilderPfad without invisibles
      set curFile to item ItemNum of ListFigs
      set InsertFig to BilderPfad & ":" & curFile
      if curFile ends with ".tif" then
         set curFile to text 4 thru -5 of curFile
      end if
      tell page Seitenzahl
         set Bildrahmen to make rectangle
         tell Bildrahmen
            set geometric bounds to theBounds
            set stroke color to noColor
            set fill color to noColor
            set label to "Rahmen_" & ItemNum
         end tell
      end tell
      place alias InsertFig on page item ("Rahmen_" & ItemNum)
      tell page item ("Rahmen_" & ItemNum)
         fit given frame to content
      end tell
   end tell
end BildImport

on AlignItems(ItemNum)
   tell document 1 of application "Adobe InDesign CS2"
      activate
      tell page item ("Rahmen_" & ItemNum) --"Rahmen_003"
         set BoundsWidth to (item 4 of geometric bounds) - (item 2 of geometric bounds)
         if BoundsWidth < 80.5 then
            set Einspaltig to 1
         else
            set Einspaltig to 0
            set NewWidth to (item 2 of geometric bounds) + 164.5
            set geometric bounds to {item 1 of geometric bounds, item 2 of geometric bounds, item 3 of geometric bounds, NewWidth}
            fit given center content
         end if
         set BoundsHeight to (item 3 of geometric bounds) - (item 1 of geometric bounds) + 2.5
      end tell
      tell page item ("Bildlegende_" & ItemNum)
         if Einspaltig = 1 then
            set NewWidth to (item 2 of geometric bounds) + 80
            set geometric bounds to {item 1 of geometric bounds, item 2 of geometric bounds, item 3 of geometric bounds, NewWidth}
            fit given frame to content
         end if
         set NewTop to (item 1 of geometric bounds) + BoundsHeight
         set NewBottom to (item 3 of geometric bounds) + BoundsHeight
         set geometric bounds to {NewTop, item 2 of geometric bounds, NewBottom, item 4 of geometric bounds}
      end tell
   end tell
end AlignItems


Hans, vielleicht fällt Dir ja noch ein schlimmer lapsus auf...
Es fehlt jetzt auch noch die Gruppierung von Bild und Legende, ist das zu bewerkstelligen?

Gruß
Jürgen


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

8. Okt 2006, 20:22
Beitrag # 12 von 17
Beitrag ID: #421215
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

ich war übers Wochenende abwesend. Country-Night in Grindelwald (CH)!
Gute Gruppen, guter Sound. :-)

Zur Frage mit dem zu entfernenden Return: Wenn sich am Ende des Textes eine
unbekannte Anzahl von Returns befinden, innerhalb des Textes aber auch Returns
vorkommen, dann kann man eine Schleife einrichten:
---
tell document 1 of application "Adobe InDesign CS2"
   activate
   tell text frame "Bildlegende_5"
      repeat while last character is return
         delete last character
      end repeat
      fit given frame to content
   end tell
end tell
---

Weil Du aber weisst, dass nur ein Return vorhanden ist, und zwar am Schluss,
dann kannst Du ruhig Deine einfachere Lösung einsetzen.

Die weiteren Antworten kommen häppchenweise, weil die Grenze von 6000 Zeichen
rasch erreicht ist, wenn CodeFormatter-behandelte Codes darunter sind.

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

8. Okt 2006, 20:25
Beitrag # 13 von 17
Beitrag ID: #421216
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

das horizontal alignment ist nur für verankerte Rahmen vorgesehen.
Es bleibt Dir also nichts anderes übrig, als die geometric bounds zu verlangen
und anzupassen.

Unsichtbare Dateien gibt es schon lange. Unter Mac OS 9 waren es die Icons
der Ordner. Unter Mac OS X sind es Dateien, deren Name mit einem Punkt
beginnt (wie ".DS_Store").

Der Trick, mit welchem die Referenz der Farbe "Keine" gespeichert wird,
ist notwendig, weil es sonst beim direkten Gebrauch eine Fehlermeldung
absetzen würde.

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

8. Okt 2006, 20:29
Beitrag # 14 von 17
Beitrag ID: #421217
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

ich habe mir noch nicht die Zeit genommen, um die Voraussetzungen für Dein
gepostetes Script zu schaffen. Aber ich habe schon mal versucht, die Funktion des
letzten Handlers zu verstehen.

Was man vereinfachen könnte: Statt die geometric bounds mehrmals zu verlangen,
diese nur je ein einziges Mal für die beiden Rahmen speichern und dann die Werte
kombinieren. Normalerweise verwende ich {y1, x1, y2, x2}. Nachstehend sind aber
"p" und "t" vorangestellt, um die Werte des Bild- und des Textrahmens auseinander-
halten zu können.

Bitte erstelle ein neues InDesign Dokument. Auf Seite 1 ein Bildrahmen (mit
"Rahmen_003" benennen). Und auch ein Textrahmen (mit "Bildlegende_003"
benennen). Dann das Fenster "Verlauf des Event-Protokolls" öffnen und dieses Script
abspielen:
---
set ItemNum to "003"

AlignItems(ItemNum)

on AlignItems(ItemNum)
   tell document 1 of application "Adobe InDesign CS2"
      activate
      tell page item ("Rahmen_" & ItemNum) --"Rahmen_003"
         set {py1, px1, py2, px2} to geometric bounds
         if (px2 - px1) is less than 80.5 then
            set Einspaltig to true
         else
            set Einspaltig to false
            set geometric bounds to {py1, px1, py2, px1 + 164.5}
            fit given center content
         end if
      end tell
      tell page item ("Bildlegende_" & ItemNum)
         set {ty1, tx1, ty2, tx2} to geometric bounds
         if Einspaltig then
            set geometric bounds to {ty1, tx1, ty2, tx1 + 80}
            fit given frame to content
         end if
         set geometric bounds to {ty1 + (py2 - py1) + 2.5, tx1, ty2 + (py2 - py1) + 2.5, tx2}
      end tell
   end tell
end AlignItems
---
Und dann den Handler on AlignItems(ItemNum) durch Deinen ersetzen, das Script nochmals abspielen
und schliesslich die beiden Aufzeichnungen vergleichen ...

Gruss, Hans


als Antwort auf: [#421204]

Indesign_Textpassage in neuen Textrahmen

Hans Haesler
  
Beiträge gesamt: 5799

8. Okt 2006, 20:31
Beitrag # 15 von 17
Beitrag ID: #421218
Bewertung:
(3058 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Jürgen,

Ein schlimmer Lapsus? Eigentlich nicht. Aber es ist immer sicherer, wenn man die Masseinheiten zu Beginn
festlegt und sie falls notwendig am Schluss wieder zurücksetzt. So beugt man unerwarteten Ergebnissen vor.
---
tell document 1 of application "Adobe InDesign CS2"
   activate
   tell view preferences
      set {hMu, vMu} to {horizontal measurement units, vertical measurement units}
      if {hMu, vMu} is not {millimeters, millimeters} then
         set {horizontal measurement units, vertical measurement units} to {millimeters, millimeters}
      end if
   end tell
   
   -- hier die weiteren Befehle
   
   -- der Originalzustand wiederherstellen (falls notwendig)
   tell view preferences
      try
         if {hMu, vMu} is not {millimeters, millimeters} then
            set {horizontal measurement units, vertical measurement units} to {hMu, vMu}
         end if
      end try
   end tell
end tell
---

Übrigens: Das activate muss nicht in jedem Handler wiederholt werden. Nur wenn zwischenhinein in den
Finder (oder so) gewechselt worden ist.

Und so kann man die beiden Rahmen gruppieren:
---
tell document 1 of application "Adobe InDesign CS2"
   activate
   make group with properties {group items:{page item "Rahmen_003", page item "Bildlegende_003"}, label:"Gruppe_003"}
end tell
---
Mit dem label wird gleichzeitig die Gruppe benannt. Kann vielleicht mal nützlich sein.

Gruss, Hans


als Antwort auf: [#421204]
X

Aktuell

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
05.02.2021 - 05.11.2021

Digicomp Academy AG, Limmatstrasse 50, 8005 Zürich
Freitag, 05. Feb. 2021, 13.00 Uhr - Freitag, 05. Nov. 2021, 17.00 Uhr

Lehrgang

Bilden Sie sich zum zertifizierten Publishing-Multimedia-Profi aus. Neben Fotografie und Video befassen Sie sich mit der Medienproduktion, digitalen Publikationen und dem Webdesign für Desktop- und mobile Endgeräte.

Preis: CHF 10'500.-
Dauer: 30 Tage (ca. 210 Lektionen) – Unterricht findet jeweils am Freitag von 13 - 19 Uhr und Samstag von 09 - 17 Uhr statt

Ja

Organisator: Digicomp Academy AG

Kontaktinformation: Kundenberater-Team, E-Mailkundenberatung AT digicomp DOT ch

digicomp.ch/d/9PM

Veranstaltungen
05.03.2021 - 30.04.2021

Digicomp Academy AG, Zürich oder virtuell
Freitag, 05. März 2021, 13.00 Uhr - Freitag, 30. Apr. 2021, 17.00 Uhr

Lehrgang

Im berufsbegleitenden Web Publisher Lehrgang vertiefen Sie Ihr Wissen rund um das Thema Screendesign und die Umsetzung von Websites. Wir befähigen Sie dazu selbständig und professionell Ihren Webauftritt zu planen und in die Realität umzusetzen.

Preis: CHF 3'250.–
Dauer: 8.5 Tage - Unterricht findet jeweils am Freitag von 13 - 19 Uhr und Samstag von 09 - 17 Uhr statt.

Ja

Organisator: Digicomp Academy AG

Kontaktinformation: Kundenberater-Team, E-Mailkundenberatung AT digicomp DOT ch

digicomp.ch/d/9PWEB