Hallo,
ich hane folgendes Vorhaben:
Es sollen via AppleScript Stilvorlagen bestimmten Absätzen zugewiesen werden.
Alle Absätze die sich auf einer linken Seite befinden sollen die Stilvorlage "AbsatzLinks" erhalten. Und das für das komplette Dokument.
Das Gleiche soll auch auf rechte Seiten passieren. Dort sol die Stilvorlage "AbsatzRechts" zum Einsatz kommen.

Im Dokument selbst befindet sich kein Text. Es handelt sich ledglich um
verankerte Bildrahmen.

Wie läßt sich das realisieren?

Gruss

Hallo cwenet,

hier eine Lösung: Eine Wiederholschleife, welche durch alle Seiten geht. Von jeder Seite wird der "Name", das
heisst die Seitennummer, welche als Pagina gedruckt würde, geprüft. Wenn die Zahl mit dem Operatoren 'mod'
geteilt wird, ist das Resultat (der Restwert) entweder '0' oder '1'. Je nach Ergebnis wird der Variablen 'curSheet'
die entsprechende Stilvorlage zugeteilt.

In der inneren Repeatschleife werden die Textboxen adressiert. Jedem Text wird gesagt, dass er jedem Absatz die
Stilvorlage 'curSheet' zuweisen soll:
---
tell document 1 of application "QuarkXPress 4.11"
    activate
    repeat with i from 1 to count of pages
        tell page i
            if (name as integer) mod 2 = 0 then
                set curSheet to "AbsatzLinks"
            else
                set curSheet to "AbsatzRechts"
            end if
            repeat with j from 1 to count of text boxes
                try
                    tell text box j
                        tell text 1
                            set style sheet of every paragraph to curSheet
                        end tell
                    end tell
                end try
            end repeat
        end tell
    end repeat
end tell
---
Problematisch wird es, wenn Textboxen vorhanden sind, welche nicht behandelt werden sollen (z.B. die Pagina).
Wenn dies der Fall sein sollte, bitte melden.

Gruss, Hans

Genial Hans.
Es geht. Danke.

Aber Du hast recht. Soweit habe ich garnicht gedacht. Es hat natürlich
noch andere Textboxen auf der Seite.
Es soll aber nur der Haubttextrahmen behandelt werden.
Ich könnte den betroffenen Textrahmen aber mit einem Namen versehen.

Wäre das hilfreich?

Gruss
Christoph

Hallo Christoph,

ja, das wäre sehr hilfreich. Damit werden alle anderen Boxen ausgeschlossen. Und die Repeatschleife erübrigt sich:
---
tell document 1 of application "QuarkXPress 4.11"
    activate
    repeat with i from 1 to count of pages
        tell page i
            if (name as integer) mod 2 = 0 then
                set curSheet to "AbsatzLinks"
            else
                set curSheet to "AbsatzRechts"
            end if
            try
                tell text box "hauptbox"
                    tell text 1
                        set style sheet of every paragraph to curSheet
                    end tell
                end tell
            end try
        end tell
    end repeat
end tell
---
Am besten wird beim Vorbereiten des Dokuments eine Box erstellt, benannt und auf die Musterseiten plaziert
(die Box muss auf einer Dokumentseite liegen, damit sie benannt werden kann).

Gruss, Hans

Ok. Läuft wunderbar.
Vielen Dank, Hans.