[GastForen Programmierung/Entwicklung AppleScript Ordner aus Filename erzeugen

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

22. Jul 2004, 22:29
Beitrag # 1 von 29
Bewertung:
(4935 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

wieder so ein spezieller Wunsch.

In den Ordner "Daten-Sortiert" werden Tiffs oder PDFs abgelegt (zur Archivierung). Es wird dann manuell ein neuer Ordner erzeugt und per Copy/Paste der Filename als Ordnername (ohne Suffix) eingefügt.

Kann man so was per Ordnerscript erzeugen?
xname.tif oder xname.pdf werden in Ordner "Daten-Sortiert" kopiert und sollen in die dann gleichnamigen Ordner gemovt werden.

ps
der Filename ist stets einmalig, sollte trotzdem ein File gleichen Namens eintreffen, könnte der Ordnername ein "_2" erhalten.

Bei dem Versuch eines Scripts stürzte der Rechner ab.

Gruss willem
X

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

23. Jul 2004, 10:03
Beitrag # 2 von 29
Beitrag ID: #418922
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

wenn es Dich nicht gäbe, müsste man Dich erfinden! ;-) Immer wieder für eine knifflige Aufgabe gut!

Nun, ich meine, dass die neuen Ordner entweder ausserhalb des Hotfolders erzeugt werden müssen, oder der Einfachheit halber in einem fixen Ordner, welcher sich innerhalb des Hotfolders befindet. Sonst wird damit jedes Mal die Aktion ausgelöst und stört den Ablauf der aktuellen Ausführung.

Ich schlage deshalb vor, dass im Ordner "Daten-Sortiert" der Ordner "Archiv" erzeugt wird, in welchem dann die neuen Ordner erzeugt werden.
---
on adding folder items to thisFolder after receiving fileList
  try
    -- prüfen, ob der Ordner "Archiv" existiert ...
    alias ((thisFolder as string) & "Archiv")
  on error
    -- ... wenn nicht, dann erzeugen
    tell application "Finder" to make new folder at folder thisFolder with properties {name:"Archiv"}
  end try
  -- die Liste der zu erzeugenden Ordner zusammenstellen 
  set folderList to {}
  set AppleScript's text item delimiters to {":"}
  repeat with aFile in fileList
    set filePath to aFile as string
    if filePath does not end with ":" then
      set fileName to text item -1 of filePath
      if character -4 of fileName = "." then
        set folderName to text 1 thru -5 of fileName
      else
        set folderName to fileName
      end if
      if folderName is not in folderList then
        set end of folderList to folderName
      end if
    end if
  end repeat
  set AppleScript's text item delimiters to {""}
  -- die Ordner erzeugen und sofort die Dateien hineinverschieben
  set archiveFolder to ((thisFolder as string) & "Archiv:")
  repeat with i from 1 to count of folderList
    set curName to item i of folderList
    set folName to curName
    set okay to 0
    set ctr to 1
    -- teste, ob der Ordner schon existiert. Wenn ja, den Namen mit einer Zahl ergänzen
    repeat
      try
        alias (archiveFolder & folName)
      on error
        exit repeat
      end try
      set ctr to ctr + 1
      if character -2 of folName is not "_" then
        set folName to folName & "_" & ctr
      else
        set folName to text 1 thru -3 of folName & "_" & ctr
      end if
    end repeat
    tell application "Finder" to make new folder at folder archiveFolder with properties {name:folName}
    try
      tell application "Finder" to move file (curName & ".tif") of folder thisFolder to folder (archiveFolder & folName)
    end try
    try
      tell application "Finder" to move file (curName & ".pdf") of folder thisFolder to folder (archiveFolder & folName)
    end try
    try
      tell application "Finder" to move file curName of folder thisFolder to folder (archiveFolder & folName)
    end try
  end repeat
end adding folder items to
---
Der Test, welcher bei Namensgleichheit dem neuen Ordnernamen eine Zahl anhängt ist etwas rudimentär.
Aber weil dies die Ausnahme ist, genügt die Struktur. Sie deckt immerhin die Anhängsel von "_2" bis "_10" ab …
Nun hoffe ich, dass mit diesem Script Deine Maschine nicht mehr abstürzt.

Hans Haesler <[email protected]>


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

23. Jul 2004, 12:09
Beitrag # 3 von 29
Beitrag ID: #418923
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,
wie gut dass es DICH gibt.

Danke!!!
werde es gleich ausprobieren

Gruss willem


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

24. Jul 2004, 10:14
Beitrag # 4 von 29
Beitrag ID: #418924
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

bin echt begeistert wie die Files versorgt werden.

Eine weitere Überlegung
(bestimmt sehr aufwendig, wenn überhaupt machbar - nur eine Idee)

Momentan erzeugen die 2 Files: "ba31s0203.tif" oder "ko24s0607.pdf":
"archiv"
"ba31s0203" (mit Inhalt ba31s0203.tif)
"ko24s0607" (mit Inhalt ko24s0607.pdf)

habe mit der Zeit unterschiedliche Aufträge in einem Ordner, und erstelle
manuelle eine Ordnerstruktur wie Beispiele 1+2
______________

Beispiel 1:

b31s0203.tif  erzeugt die Ordner:

Backen      --anstelle von archiv
  b31           --neuer Ordner falls nicht vorh. (Zeichen "b" + Ziffern "31")
      b31s0203   --aus Filename
        b31s0203.tif  --Inhalt

Beispiel 2:

b32magnat.pdf erzeugt Ordnerstruktur:

1. Backen
2.    b32
3.      b32magnat
4.          b32magnat.pdf

oder

bas12s1617.pdf erzeugt Ordnerstruktur:

1. BackenSonderHeft
2.      bas12
3.        bas12s1617
4.          bas12s1617.pdf
 
Die möglichen Kombinationen =

b22  1 Zeichen, 2 Ziffern (Backen)
ko22 2 Zeichen, 2 Ziffern (Kochen)
bas22 3 Zeichen, 2 Ziffern (BackenSondHeft)
sh222 2 Zeichen, 3 Ziffern (Sonderheft)

Gibt es eine Dt. Script-Handbuch für Dummis wie mich?

Gruss aus dem Schwarzwald
willem


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

24. Jul 2004, 11:20
Beitrag # 5 von 29
Beitrag ID: #418925
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

waren wir nicht doch kürzlich genau diese Strasse runtergeschlendert?!?
(Thema "Dateien nach ersten 2 Buchstaben sortieren" http://www.page-online.de/page/forum/viewthread/2276 )

Bitte schaue dort nochmals nach und dann sage mir, was an der zuletzt präsentierten Lösung nicht
funktioniert. Sollten die Ordner automatisch erstellt werden? Kann man noch einführen. Aber auch
dann muss eine Liste zum Übersetzen der Kürzel definiert sein.

Von wegen Buch für AS-Dummies: Gibt es sehr wahrscheinlich schon. Ziemlich sicher in Englisch.
Aber zum erfolgreich Scripten gehört auch ein klares Vorstellungsvermögen, eine tüchtige Portion
Phantasie, sehr viel Erfindungsgabe, ein guter Überblick über die Abläufe und ein sehr gutes
Erinnerungsvermögen. Doch all dies kann man in keinem Buch lernen &#133;

Hans Haesler <[email protected]>


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

25. Jul 2004, 10:37
Beitrag # 6 von 29
Beitrag ID: #418926
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

tschuldigung lieber Hans,
was ich meinte wäre eine Kombination aus beiden.

Momentan wird der Ordner "Archiv" erstellt, ein Unterordner mit dem Namen des Files erstellt und das File in diesen Unterordner gemovt.
Das funktioniert einwandfrei.

>> Sollten die Ordner automatisch erstellt werden?

Ja das meinte ich, dass anstelle von Archiv
bei ba22s0405.pdf ein BACKEN erstellt wird
bei ko14s8889.pdf ein KOCHEN erstellt wird

Gruss und Dank
willem


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

26. Jul 2004, 10:39
Beitrag # 7 von 29
Beitrag ID: #418927
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

nun, der Ordner "Archiv" (oder wie Du ihn immer benennen willst) muss bleiben. Dieser Ordner wird ganz zu Beginn automatisch erstellt, falls er nicht schon besteht. Aber anschliessend dürfen im Hotfolder keine neuen Ordner erzeugt werden. Sonst wird der Ablauf der Ordneraktion gestört. Deshalb werden die Hauptordner "Backen", "Kochen" usw. im Überordner "Archiv" erzeugt.

Ein zweites Problem ist das Übersetzen der Kennbuchstaben in Ordnernamen. Das Script kann dies nicht. Es ist nicht intelligent. Nur der Scriptentwickler (sollte es sein &#133;).

Wenn alle vorkommenden Kürzel und deren Umsetzung bekannt sind, dann ist meines Erachtens eine 'if / else if'-Schleife am effizientesten. Die folgende Lösung beruht auf dieser Annahme. Wenn aber die Liste bei laufendem Script ergänzt werden sollte, dann könnte dies über einen Dialog vorgenommen werden. Wenn ein unbekanntes Objekt erfasst wird, dann zieht das Script die Kennbuchstaben aus, zeigt diese mit einem Dialog an und der Anwender tippt den Namen des Ordners ein. Dieser wird samt Kürzel registriert und ist beim nächsten Mal bekannt.

Neu &#150; bei Deiner Aufgabenstellung &#150; ist der erste Unterordner, z.B. "b31". Diese Information muss zusätzlich beschafft werden. Mal schauen &#133;
---
on adding folder items to thisFolder after receiving fileList
  -- den Pfad zum Archiv-Ordner zusammensetzen
  set archiveFolder to ((thisFolder as string) & "Archiv:")
  try
    -- prüfen, ob der Ordner "Archiv" existiert ...
    alias archiveFolder
  on error
    -- ... wenn nicht, dann erzeugen
    tell application "Finder" to make new folder at folder thisFolder with properties {name:"Archiv"}
  end try
  -- den Namen der aktuellen Datei feststellen und daraus die Namen der Ordner ableiten
  set AppleScript's text item delimiters to {":"}
  repeat with aFile in fileList
    set filePath to aFile as string
    if filePath does not end with ":" then
      set fileName to text item -1 of filePath
      if character -4 of fileName = "." then
        set fileName to text 1 thru -5 of fileName
      end if
      if fileName starts with "bas" then
        set folName1 to "BackenSonderHeft"
        set folName2 to text 1 thru 5 of fileName
        set folName3 to fileName
      else if fileName starts with "b" then
        set folName1 to "Backen"
        set folName2 to text 1 thru 3 of fileName
        set folName3 to fileName
      else if fileName starts with "ko" then
        set folName1 to "Kochen"
        set folName2 to text 1 thru 4 of fileName
        set folName3 to fileName
      else if fileName starts with "sh" then
        set folName1 to "Sonderheft"
        set folName2 to text 1 thru 5 of fileName
        set folName3 to fileName
      else
        set folName1 to ""
      end if
      -- wenn der erste Ordnername nicht leer ist ...
      if folName1 is not "" then
        -- ... wird geprüft, ob die drei Ordner schon existieren, wenn nicht, wird ein fehlender erzeugt
        set subFolder1 to archiveFolder & folName1
        try
          alias subFolder1
        on error
          tell application "Finder" to make new folder at folder archiveFolder with properties {name:folName1}
        end try
        set subFolder2 to subFolder1 & ":" & folName2
        try
          alias subFolder2
        on error
          tell application "Finder" to make new folder at folder subFolder1 with properties {name:folName2}
        end try
        set subFolder3 to subFolder2 & ":" & folName3
        try
          alias subFolder3
        on error
          tell application "Finder" to make new folder at folder subFolder2 with properties {name:folName3}
        end try
        -- die aktuelle Datei wird in den Zielordner verschoben
        try
          tell application "Finder" to move file aFile to folder subFolder3 with replacing
        end try
      end if
    end if
  end repeat
end adding folder items to
---
Das 'with replacing' überschreibt im Zielordner eine Datei, wenn eine gleichnamige in den Hotfolder gelegt wird. Ohne diesen Zusatz würde die Datei nicht verschoben. Die Erzeugung eines Ordners mit "_2" ergänzt wäre sehr aufwendig.

Wenn neue Kennbuchstaben auftauchen, dann muss zuerst im Script die 'if / else if'-Schleife entsprechend ergänzt werden.

Hans Haesler <[email protected]>


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

26. Jul 2004, 19:23
Beitrag # 8 von 29
Beitrag ID: #418928
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,
Super!!! Super!!! Toll !!!
genau das was ich wollte. Hans du bist der Grösste!!!

werde mich revanchieren.

Bezüglich:
>Wenn aber die Liste bei laufendem Script ergänzt werden sollte, dann >könnte dies über einen Dialog vorgenommen werden. Wenn ein >unbekanntes Objekt erfasst wird, dann zieht das Script die >Kennbuchstaben aus, zeigt diese mit einem Dialog an und der Anwender >tippt den Namen des Ordners ein. Dieser wird samt Kürzel registriert und >ist beim nächsten Mal bekannt.

wie funktioniert so was? kann man das einbauen?

Das mit den "_2" vergess ich schnell, besser ist wenn die Dateien überschrieben werden.

Gruss und Tausend Dank
willem


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

26. Jul 2004, 21:56
Beitrag # 9 von 29
Beitrag ID: #418929
Bewertung:
(4935 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,
Zitat Super!!! Super!!! Toll !!!
genau das was ich wollte. Hans du bist der Grösste!!!

Na, diesen Ausbruch muss ich jetzt schnell meiner Frau Marlise zeigen! :-)

Die Möglichkeit, neue Kennbuchstaben und deren Ordnernamen "fliegend" dem Script beibringen zu können, ist theoretisch möglich. Doch in der Praxis ziehe ich allemal das manuelle Ergänzen des Scripts dem erwähnten Halb-Automatismus vor. Dieser ist ja nur notwendig, wenn dem Script unbekannte Kürzel auftauchen. Solche, die es "kennt", werden problemlos in die Ordnernamen übersetzt, die Ordner erzeugt und die Dateien hineinverschoben. Z.B. alle Wochen-Nummern von b (wie "Backen") b29sXXXX.tif, b30sXXXX.tif, b31sXXXX.tif &#133;

Warum so skeptisch? Weil bei der automatischen Lösung jede Menge Fehlerbehandlungen eingebaut werden müssten. Der grössere Nachteil ist aber, dass man Abschied von der schnellen 'if / else if'-Schleife nehmen müsste. Denn diese kann man nicht automatisch ausbauen. Man müsste den jetzt bekannten Grundstock in eine Liste (oder zwei, oder drei) umwandeln. Dann kann man neue Elemente anfügen mit 'set end of folList to newFolder' (oder so ähnlich).

Bei jeder neuen Datei müsste dann mit der von Goar vorgestellten Methode der Kürzel ausgezogen werden. Mit diesem Kürzel müsste man mit einer Wiederholschleife die erste Liste durchgehen, mit einem automatischen Zähler die Position des Kürzels feststellen, dann den beiden anderen Variablen den entsprechenden Wert aus ihrer Liste zuweisen. Und wenn keine Übereinstimmung gefunden wird, den Anwender per Dialog um die neuen Ordnernamen bitten.

Wer hat mitgezählt? Jede Menge von "müsste man" &#133; Tönt nicht so enthusiastisch wie sonst &#133; Deshalb, wie gesagt: Lieber manuell eingreifen, wenn mal eine Datei im Hotfolder liegenbleibt, weil sie nicht zustellbar ist. Es genügt, das Script zu öffnen, eine der dreifachen 'else if'-Befehle zu kopieren, einzusetzen und die Namen an den Neuling anzupassen.
Zitat Das mit den "_2" vergess ich schnell, besser ist wenn die Dateien überschrieben werden.

Ufff!!! Ja, so ist es viel einfacher! ;-)

Hans Haesler <[email protected]>


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

26. Jul 2004, 22:41
Beitrag # 10 von 29
Beitrag ID: #418930
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

habe bis jetzt (ausser 1 Std Waldspaziergang mit meinem Hund) das Script getestet und bin immer noch von den Socken, einfach AffenTurboGeil!!!

Das Editieren bei diesem Script ist kein Problem!

nochmal herzlichen Dank,
Gruss auch an Deine Frau Marlise

willem


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

27. Jul 2004, 00:37
Beitrag # 11 von 29
Beitrag ID: #418931
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

bitteschön!
Zitat ... einfach AffenTurboGeil!!!

:-) Sehe ich auch so!

Zitat Das Editieren bei diesem Script ist kein Problem!

&#133; und sicherer und bequemer als der problembehaftete Halb-Automatismus.

Auch einen Gruss von meiner Frau (welche die ganze Aufregung nicht versteht &#133; aber froh
für den Hund ist, weil sein Herrchen ab sofort wieder mehr Zeit für ihn hat ;-).

Hans Haesler <[email protected]>


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

4. Aug 2004, 19:56
Beitrag # 12 von 29
Beitrag ID: #418932
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

kann man aus dem letzten Script ein 2. Script erstellen, bei dem anstatt Files, die eintreffenden Ordner (mit Inhalt) sortiert werden?
Das Script würde an einen Neuen Ordner angehängt und der Zielordner ist ebenfalls Neu ("NeueDaten" statt "Archiv")

z.B.: Ordner: b31s0203 soll sortiert werden in:
NeueDaten
      Backen
            b31

habe mal beim 1.Script probiert den ":" rauszunehmen, aber so einfach wird es wohl doch nicht sein.
   
Gruss und Danke
willem

ps
Bin immer noch hin & weg
könntest Du mir nochmal Deine Anschrift mailen?


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

4. Aug 2004, 23:23
Beitrag # 13 von 29
Beitrag ID: #418933
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

nun, der Doppelpunkt darf nicht herausgenommen werden. Aber man muss den Test anders formulieren. Die Zeile &#133;
Code
if filePath does not end with ":" then 

&#133; bedeutet ganz einfach "wenn der Pfad nicht mit einem Doppelpunkt endet, dann" &#133; handelt es sich um eine Datei.

Deshalb muss man sagen &#133;
Code
if filePath ends with ":" then 

&#133; und schliesst damit Dateien aus, weil uns nur noch die Ordner interessieren.

Damit aber die Bezeichungen übereinstimmen, sollte man auch überall statt 'file' das korrektere 'folder' benutzen.
Auch wenn es "nur" fürs Auge ist.

Ganz wichtiger Punkt: Die Namen der gedroppten Ordner muss man so ausziehen &#133;
Code
set folderName to text item [b]-2 of folderPath 

&#133; weil die Textkette 'folderPath mit einem Doppelpunkt endet und durch Benutzung des 'text item delimiters' {":"}
das 'text item -1' ein leerer String ist. Im Gegensatz zu einer Datei, bei welcher der Pfad mit dem letzen
Buchstaben des Namens der Datei endet, welcher mit 'text item -1' ausgezogen wird.

Hier das komplette Script, abgeändert für das Archivieren der Ordner:
---
on adding folder items to thisFolder after receiving folderList
  -- den Pfad zum Archiv-Ordner zusammensetzen
  set archiveFolder to ((thisFolder as string) & "NeueDaten:")
  try
    -- prüfen, ob der Ordner "NeueDaten" existiert ...
    alias archiveFolder
  on error
    -- ... wenn nicht, dann erzeugen
    tell application "Finder" to make new folder at folder thisFolder with properties {name:"NeueDaten"}
  end try
  -- den Namen des aktuellen Ordners feststellen und daraus die Namen der Ordner ableiten
  set AppleScript's text item delimiters to {":"}
  repeat with aFolder in folderList
    set folderPath to aFolder as string
    if folderPath ends with ":" then
      set folderName to text item -2 of folderPath
      if folderName starts with "bas" then
        set folName1 to "BackenSonderHeft"
        set folName2 to text 1 thru 5 of folderName
      else if folderName starts with "b" then
        set folName1 to "Backen"
        set folName2 to text 1 thru 3 of folderName
      else if folderName starts with "ko" then
        set folName1 to "Kochen"
        set folName2 to text 1 thru 4 of folderName
      else if folderName starts with "sh" then
        set folName1 to "Sonderheft"
        set folName2 to text 1 thru 5 of folderName
      else
        set folName1 to ""
      end if
      -- wenn der erste Ordnername nicht leer ist ...
      if folName1 is not "" then
        -- ... wird geprüft, ob die beiden Ordner schon existieren, wenn nicht, wird ein fehlender erzeugt
        set subFolder1 to archiveFolder & folName1
        try
          alias subFolder1
        on error
          tell application "Finder" to make new folder at folder archiveFolder with properties {name:folName1}
        end try
        set subFolder2 to subFolder1 & ":" & folName2
        try
          alias subFolder2
        on error
          tell application "Finder" to make new folder at folder subFolder1 with properties {name:folName2}
        end try
        -- der aktuelle Ordner wird in den Zielordner verschoben
        try
          tell application "Finder" to move folder aFolder to folder subFolder2 with replacing
        end try
      end if
    end if
  end repeat
end adding folder items to
---
Hans Haesler <[email protected]>


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Anonym
Beiträge gesamt: 22827

5. Aug 2004, 19:39
Beitrag # 14 von 29
Beitrag ID: #418934
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

Ein herrliches Script das "Ordner_archivieren" vielen Dank
Es läuft richtig flott.

ein schönes Wochenende wünscht Euch

willem


als Antwort auf: [#418921]

Ordner aus Filename erzeugen

Hans Haesler
  
Beiträge gesamt: 5816

6. Aug 2004, 09:36
Beitrag # 15 von 29
Beitrag ID: #418935
Bewertung:
(4934 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Bitteschön. Gut zu wissen, dass es Dir nützlich ist.

Und ich nehme an, dass Du inzwischen auch den Code studiert und den
Unterschied in der Behandlung von Dateien und Ordnern verstanden hast. ;-)

Ebenfalls ein schönes Wochenende!

Hans Haesler <[email protected]>


als Antwort auf: [#418921]
X

Aktuell

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
02.02.2023

Prozesse optimieren und effizient gestalten

Zürich
Donnerstag, 02. Feb. 2023, 08.00 - 10.00 Uhr

Digitalisierung, Webauftritt

Digitalisierung mitgestalten - Worauf kommt es an? Wie wichtig ist die Webseite? Webseite mit Word Press? Interne Prozesse optimieren

Ja

Organisator: B. Isik - SNF Academy

Kontaktinformation: Birol Isik, E-Mailinfo AT bkcc DOT ch

https://digitalisierung-heute.ch/digitalisierung-informationstag-schweiz/

Veranstaltungen
01.03.2023 - 09.03.2023

Online
Mittwoch, 01. März 2023, 00.00 Uhr - Donnerstag, 09. März 2023, 00.00 Uhr

Online Webinar

Wie gehen wir mit diesen Veränderungen um? Was ist notwendig, damit wir die Digitalisierung im Unternehmen klappt? Veränderungsprozesse verstehen und entsprechend handeln Mitarbeiter als Botschafter Webseite mit WordPress erstellen SEA /SEO (Ads aufschalten)

Ja

Organisator: B. Isik - SNF Academy

Kontaktinformation: B. Isik, E-Mailinfo AT snfa DOT ch

https://www.fernstudiumfitness.ch/digitalisierung-schweiz/