(* 
OrdnerErzeugen_02d.app 
Dieses Script erzeugt Ordner aufgrund der ersten zwei Worte von Datei-Namen  
und verschiebt die Dateien hinein 
© 23.07.14 / Hans Häsler, Châtelard 52, CH-1018 Lausanne 
*) 
 
-- einen Dialog zeigen, falls der Anwender einen Doppelklick auf das Droplet macht   
on run 
  display dialog "Ordner oder Dateien auf dem Icon   
dieses Droplets deponieren." buttons "OK" default button 1 with icon 0 
end run 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert 
on open allObjects 
  set AppleScript's text item delimiters to " " 
  -- Wiederholschleife, welche die gedroppten Objekte zum Handler 'processObject' schickt   
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  set AppleScript's text item delimiters to {""} 
  -- den Anwender informieren   
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
end open 
 
-- im folgenden Handler wird festgestellt, ob das Objekt ein Ordner oder eine Datei ist; 
-- bei Ordnern wird eine Liste des Inhalts erstellt und die Elemente rekursiv behandelt  
-- (d.h. zum aktuellen Handler geschickt). Dateien werden zum Handler 'processFile' gesandt. 
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner  
  if (aObject as string) ends with ":" then 
    -- die Liste des Inhalts wird erstellt (ohne unsichtbare Dateien) 
    set contentsList to list folder aObject without invisibles 
     
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte zum Handler,  
    -- in welchem sie sich selbst befindet 
    repeat with anItem in contentsList 
      set objPath to ((aObject as Unicode text) & anItem) 
      processObject(objPath as alias) 
    end repeat 
     
    -- wenn das Objekt eine Datei ist ... 
  else 
    tell application "Finder" 
      -- den Namen der Datei ...  
      set fullName to name of file aObject 
      -- und den Pfad zum Ordner speichern 
      set contPath to (container of file aObject) as Unicode text 
    end tell 
    -- ... dann werden die Pfade und der Dateiname dem Handler 'processFile' übergeben 
    processFile(contPath, aObject, fullName) 
  end if 
end processObject 
 
-- die aktuelle Datei behandeln 
on processFile(contPath, aObject, fullName) 
  -- eine Liste der Worte des Dateinamens erzeugen 
  set partList to text items of fullName 
  -- wenn die Liste mehr als ein Element enthält ... 
  if (count of partList) is greater than 1 then 
    -- den Ordnernamen zusammensetzen 
    set folName to (text items 1 thru 2 of partList) as string 
    -- und auch den vollen Pfad zum Ordner 
    set curFolder to contPath & folName 
    tell application "Finder" 
      -- wenn der Ordner nicht vorhanden ist ... 
      if not (exists curFolder) then 
        -- den Ordner erzeugen  
        make new folder at contPath with properties {name:folName} 
      end if 
      -- die aktuelle Datei hineinverschieben  
      move file aObject to curFolder 
    end tell 
  end if 
end processFile 

(* 
DateienUmbenennen_01d.app 
Dieses Script löscht definierte Zeichenfolgen in Dateinamen  
© 26.07.14 / Hans Haesler, Châtelard 52, CH-1018 Lausanne 
*) 
 
global delList 
 
-- der 'run handler' wird benutzt, wenn das Script ab Menü gestartet wird   
on run 
  -- den Anwender auffordern, die Zeichenfolgen einzugeben 
  set delString to text returned of (display dialog "Zu löschende Zeichenfolgen (trennen mit \";\")" default answer "") 
  -- den "Text-Element-Trennern" einen Strichpunkt zuweisen 
  set AppleScript's text item delimiters to {";"} 
  -- die Liste der Zeichenfolgen 
  set delList to every text item of delString 
  if (count of delList) is 0 then 
    display dialog "Die Eingabe ist leer. Bitte nochmals." buttons "OK" default button 1 with icon 0 
    set AppleScript's text item delimiters to {""} 
    error number -128 
  end if 
  -- die "Finder"-Auswahl 
  tell application "Finder" 
    set allObjects to selection 
  end tell 
  -- Wiederholschleife, welche die ausgewählten Objekte zum Handler 'processObject' schickt   
  repeat with aObject in allObjects 
    processObject(aObject as string) 
  end repeat 
  set AppleScript's text item delimiters to {""} 
  -- den Anwender informieren 
  activate me 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
end run 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert 
on open allObjects 
  -- den Anwender auffordern, die Zeichenfolgen einzugeben 
  set delString to text returned of (display dialog "Zu löschende Zeichenfolgen (trennen mit \";\")" default answer "") 
  -- den "Text-Element-Trennern" einen Strichpunkt zuweisen 
  set AppleScript's text item delimiters to {";"} 
  -- die Liste der Zeichenfolgen 
  set delList to every text item of delString 
  if (count of delList) is 0 then 
    display dialog "Die Eingabe ist leer. Bitte nochmals." buttons "OK" default button 1 with icon 0 
    set AppleScript's text item delimiters to {""} 
    error number -128 
  end if 
  -- Wiederholschleife, welche die gedroppten Objekte zum Handler 'processObject' schickt   
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  set AppleScript's text item delimiters to {""} 
  -- den Anwender informieren 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
end open 
 
-- im folgenden Handler wird festgestellt, ob das Objekt ein Ordner oder eine Datei ist;  
-- bei Ordnern wird eine Liste des Inhalts erstellt und die Elemente rekursiv behandelt   
-- (d.h. zum aktuellen Handler geschickt). Dateien werden zum Handler 'processFile' gesandt.  
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner   
  if (aObject as string) ends with ":" then 
    -- die Liste des Inhalts wird erstellt (ohne unsichtbare Dateien)  
    set contentsList to list folder aObject without invisibles 
     
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte zum Handler,   
    -- in welchem sie sich selbst befindet  
    repeat with anItem in contentsList 
      set objPath to ((aObject as Unicode text) & anItem) 
      processObject(objPath as alias) 
    end repeat 
     
    -- wenn das Objekt eine Datei ist ...   
  else 
    tell application "Finder" 
      -- den Namen speichern 
      set fullName to name of file aObject 
    end tell 
    -- ... dann wird der Pfad dem Handler 'processFile' übergeben 
    processFile(aObject, fullName) 
  end if 
end processObject 
 
-- die aktuelle Datei behandeln 
on processFile(aObject, newName) 
  -- eine Schleife durch die Elemente der Liste 
  repeat with n from 1 to count of delList 
    -- den "Text-Element-Trennern" das aktuelle Element zuweisen 
    set AppleScript's text item delimiters to {item n of delList} 
    -- durch das Verwandeln in eine Liste wird die Zeichenfolge entfernt 
    set newList to (text items of newName) as list 
    -- die "Text-Element-Trenner" als leerer String definieren 
    set AppleScript's text item delimiters to {""} 
    -- die Elemente der Liste werden in einen String verwandelt 
    set newName to newList as string 
  end repeat 
  -- eventuelle doppelte Leerschläge entfernen 
  set AppleScript's text item delimiters to {"  "} 
  set newList to (text items of newName) as list 
  set AppleScript's text item delimiters to {" "} 
  set newName to newList as string 
  -- eventuellen führenden Leerschlag löschen 
  if newName starts with " " then 
    set newName to text 2 thru -1 of newName 
  end if 
  -- die aktuelle Datei umbenennen 
  tell application "Finder" 
    try 
      set name of file aObject to newName 
    end try 
  end tell 
end processFile