-- Diese vier Ordnerpfade müssen angepasst werden:  
property idPath : ((path to desktop as text) & "test:ID:") --hier liegen die ID-Dokumente  
property aPath : ((path to desktop as text) & "test:Adresse:") --hier liegen die Adress-PDF-Dokumente  
property tPath : ((path to desktop as text) & "test:Text:") --hier liegen die Text-PDF-Dokument  
property logPath : POSIX path of ((path to desktop as text) & "test:Logs:") --hier wird die Error.log geschrieben  
 
my main() 
 
on main() 
	set TID to AppleScript's text item delimiters 
	set idFileNameList to my getIdFileNameList() --associated list {{cleanName, origName} , ...}  
	my placePDFs(idFileNameList) 
	set AppleScript's text item delimiters to TID 
end main 
 
on getIdFileNameList() 
	set associatedNameList to {} 
	set idFileNames to list folder idPath without invisibles 
	set AppleScript's text item delimiters to "-" 
	repeat with i from 1 to count of idFileNames 
		set theName to item i of idFileNames 
		if text -5 thru -1 of theName is ".indd" then 
			if (count of text items of theName) is greater than 1 then 
				set end of associatedNameList to {text item 1 of theName, theName} 
			else 
				set end of associatedNameList to {text 1 thru -6 of (text item 1 of theName), theName} 
				 
			end if 
		end if 
	end repeat 
	return associatedNameList 
end getIdFileNameList 
 
on placePDFs(associatedNameList) 
	repeat with p from 1 to count of associatedNameList 
		set AppleScript's text item delimiters to "" 
		set idFile to alias (idPath & (item 2 of (item p of associatedNameList)) as text) 
		tell application "Adobe InDesign CS3" 
			open idFile 
			tell active document 
				set {tFrame, aFrame} to {item 1 of (every page item whose label is "TFeld"), item 1 of (every page item whose label is "AFeld")} 
				try 
					place ((tPath & (item 1 of (item p of associatedNameList)) & ".pdf") as text) on tFrame with properties {PDF crop:crop trim} --Optionen: crop content/‌crop art/‌crop PDF/‌crop trim/‌crop bleed/‌crop media)  
				on error e 
					do shell script "echo " & quoted form of (e) & " >> " & quoted form of (logPath & "Error.log") 
				end try 
				try 
					place ((aPath & (item 1 of (item p of associatedNameList)) & ".pdf") as text) on aFrame with properties {PDF crop:crop trim} --Optionen: crop content/‌crop art/‌crop PDF/‌crop trim/‌crop bleed/‌crop media)  
				on error e 
					do shell script "echo " & quoted form of (e) & " >> " & quoted form of (logPath & "Error.log") 
				end try 
			end tell 
			close active document saving yes 
		end tell 
	end repeat 
	 
end placePDFs