[GastForen Programmierung/Entwicklung AppleScript Photoshop-Ebenen bemaßen

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Photoshop-Ebenen bemaßen

pixelstaub
Beiträge gesamt: 128

16. Dez 2009, 17:41
Beitrag # 1 von 19
Bewertung:
(7882 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Liebe Liste,

ich würde gern ein Applescript schreiben, welches folgendes macht:
Eine Ebene soll ausgewählt werden, Höhe und Breite des Inhalts sollen ermittelt werden (später auch Position) und die ermittelten Angaben auf einer neuen Textebene platziert werden.

Bisher muss ich dazu manuelle die Ebenentransparenz auswählen. Genau das würde ich aber gerne mit ins Script packen (um dann später alle Ebenen im Dokument zu bemaßen). Das Script sieht bisher folgendermaßen aus:

Code
tell application "Adobe Photoshop CS4" 
activate
set units to pixel units
--- list1 mit Platzhaltern füllen
set list1 to {1, 2, 3, 4}
--- Abmessungen der Auswahl ermitteln
get bounds of selection of current document
--- In list1 kopieren
copy bounds of selection of current document to list1
set x1 to first item of list1
set y1 to second item of list1
set x2 to third item of list1
set y2 to last item of list1
set laenge to x2 - x1
set hoehe to y2 - y1
get position of selected
set layerRef to make new art layer in current document with properties ¬
{kind:text layer}
set position of text object of layerRef to {x1, y1 + 10}
set contents of text object of layerRef to laenge
set layerRef to make new art layer in current document with properties ¬
{kind:text layer}
set position of text object of layerRef to {x1, y1 + 10}
set contents of text object of layerRef to " x " & hoehe
end tell


Wie wähle ich die Ebenentransparenz per AS aus? Und: Gibt es eine Möglichkeit, beide Werte auf eine Textebene zu schreiben (bisher sind’s ja zwei?)

Dankbar für jeden Tipp grüßt
Stephan
X

Photoshop-Ebenen bemaßen

pixelstaub
Beiträge gesamt: 128

16. Dez 2009, 17:56
Beitrag # 2 von 19
Beitrag ID: #428097
Bewertung:
(7878 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
ach, und noch eine Frage: Wie kann ich bei

Code
count art layers of current document 

auch die innerhalb der verschiedenen Ebenengruppen mitzählen lassen? Das Problem hierbei:
Ob ich layers oder art layers of layer sets of current document zählen lasse – das Ergebnis ist stets das gleiche …

Danke!


als Antwort auf: [#428093]
(Dieser Beitrag wurde von pixelstaub am 16. Dez 2009, 18:10 geändert)

Photoshop-Ebenen bemaßen

-hans-
Beiträge gesamt: 748

16. Dez 2009, 21:52
Beitrag # 3 von 19
Beitrag ID: #428110
Bewertung:
(7849 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Breite mal Höhe einer Ebene auf eine Ebene
leider nur photoshop CS vllt. tut's auch in CS4
Code
tell application "Adobe Photoshop CS" 
activate
tell settings
set ruler units to pixel units
end tell
--- list1 mit Platzhaltern füllen
set list1 to {1, 2, 3, 4}
--- Abmessungen der Auswahl ermitteln
set meinhutderhatvierecken to bounds of current layer of current document
--- In list1 kopieren
copy meinhutderhatvierecken to list1
set x1 to first item of list1
set y1 to second item of list1
set x2 to third item of list1
set y2 to last item of list1
set AppleScript's text item delimiters to ","
set laenge to text item 1 of (x2 - x1 as string)
set hoehe to text item 1 of (y2 - y1 as string)
set MeinHut to (laenge as string) & " x " & (hoehe as string) & " Pixel over all"
set layerRef to make new art layer in current document with properties {kind:text layer}
set position of text object of layerRef to {x1, y1 + 10}
set contents of text object of layerRef to MeinHut

end tell
set AppleScript's text item delimiters to ""


Zählen der Layer (sets + einzelne)
Code
tell application "Adobe Photoshop CS" 
activate
set AlleHutschachteln to count layers of layer sets of current document
set MinusHuete to count layer sets of current document
set AlteHuete to count layers of current document
set allemeinehuete to AlleHutschachteln + AlteHuete - MinusHuete
end tell
allemeinehuete


Ebenentransparenz:
Code
tell application "Adobe Photoshop CS" 
activate
set opacity of art layer "Muster" of current document to 50
end tell


mit fill opacity bekommt man die Flächendeckkraft

bonne nuit :)


als Antwort auf: [#428097]
(Dieser Beitrag wurde von -hans- am 16. Dez 2009, 22:31 geändert)

Photoshop-Ebenen bemaßen

pixelstaub
Beiträge gesamt: 128

17. Dez 2009, 00:22
Beitrag # 4 von 19
Beitrag ID: #428116
Bewertung:
(7824 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

wow, danke Dir für die umfassende Antwort – es funktioniert tatsächlich auch in CS4 :)
Dennoch habe ich noch zwei kleine Fragen: Wie schaffe ich es, nur die Ebenen zu zählen, die keinen Text enthalten? Ich habe es mal mit
Code
count (art layers of current document whose kind is not text) 

versucht – das Ergebnis ist aber das gleiche.

Und mit Ebenentransparenz meinte ich so etwas wie "Auswahl laden -> Kanal: Transparenz der aktuellen Ebene". Hast Du da vielleicht noch ’nen Tipp?

Tausend Dank, beste Grüße & bonne nuit a toi aussi aus Köln
Stephan


als Antwort auf: [#428110]
(Dieser Beitrag wurde von pixelstaub am 17. Dez 2009, 00:29 geändert)

Photoshop-Ebenen bemaßen

-hans-
Beiträge gesamt: 748

17. Dez 2009, 08:21
Beitrag # 5 von 19
Beitrag ID: #428125
Bewertung:
(7791 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
da fehlte nur der layer zum text ;-)
count (art layers of current document whose kind is not text layer)

wg. aktuelle ebene als auswahl muss ich später mal schauen ...


als Antwort auf: [#428116]

Photoshop-Ebenen bemaßen

-hans-
Beiträge gesamt: 748

18. Dez 2009, 11:31
Beitrag # 6 von 19
Beitrag ID: #428266
Bewertung:
(7728 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
hm, also der von dir genannte dialog wird wohl mit
Code
load selection from channel "Alpha 1" 

angesprochen, aber wie man jetzt die "'aktuelle Ebene' Transparenz" direkt (ohne irgendwelche umwege wie Alphakanal aus Ebene erzeugen) auswaehlt – welches ja auch die default einstellung ist – ist mir auch ein Rätsel ...

Das muss der "große Hans" mal ergründen ;-)


als Antwort auf: [#428125]

Photoshop-Ebenen bemaßen

Hans Haesler
  
Beiträge gesamt: 5826

18. Dez 2009, 11:58
Beitrag # 7 von 19
Beitrag ID: #428272
Bewertung:
(7717 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo "kleiner Hans" ;-),

(mit "klein" ist das Fast-alles-in-Kleinbuchstaben-Schreiben gemeint ...)

Herzlichen Dank für Deinen Einsatz, denn im Scripten von Photoshop kenne ich mich nicht gut aus.

Aber vielleicht hilft Euch Beiden eine Diskussion, welche kürzlich in der AppleScript-Users-Liste geführt worden ist.

Hier ist der Link zum ersten Beitrag: http://lists.apple.com/...09/Dec/msg00163.html

Für die Antworten jeweils ganz unten auf den Link "Next by thread" klicken.

Gruss, Hans


als Antwort auf: [#428266]

Photoshop-Ebenen bemaßen

-hans-
Beiträge gesamt: 748

18. Dez 2009, 17:24
Beitrag # 8 von 19
Beitrag ID: #428328
Bewertung:
(7691 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi, vorab: ich hab's nicht gefunden :(
quick'n dirty -> scripting listener

Der jeweils "current layer" wird als auswahl geladen:
Code
set theScript to "var id18 = charIDToTypeID( \"setd\" ); 
var desc4 = new ActionDescriptor();
var id19 = charIDToTypeID( \"null\" );
var ref4 = new ActionReference();
var id20 = charIDToTypeID( \"Chnl\" );
var id21 = charIDToTypeID( \"fsel\" );
ref4.putProperty( id20, id21 );
desc4.putReference( id19, ref4 );
var id22 = charIDToTypeID( \"T \" );
var ref5 = new ActionReference();
var id23 = charIDToTypeID( \"Chnl\" );
var id24 = charIDToTypeID( \"Chnl\" );
var id25 = charIDToTypeID( \"Trsp\" );
ref5.putEnumerated( id23, id24, id25 );
desc4.putReference( id22, ref5 );
executeAction( id18, desc4, DialogModes.NO );

"


tell application "Adobe Photoshop CS2"

tell current document
do javascript theScript
end tell
end tell



als Antwort auf: [#428272]

Photoshop-Ebenen bemaßen

jekyll
Beiträge gesamt: 2047

19. Dez 2009, 14:12
Beitrag # 9 von 19
Beitrag ID: #428386
Bewertung:
(7662 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi,
Antwort auf: angesprochen, aber wie man jetzt die "'aktuelle Ebene' Transparenz" direkt (ohne irgendwelche umwege wie Alphakanal aus Ebene erzeugen) auswaehlt – welches ja auch die default einstellung ist – ist mir auch ein Rätsel ...

Am besten über die Kanalbererechnungen :o)

Hier wird vom aktelle Ebene die Transparenz in eine Alphakanal gesichert.
Code
var idMk = charIDToTypeID( "Mk  " ); 
var desc2 = new ActionDescriptor();
var idNw = charIDToTypeID( "Nw " );
var idChnl = charIDToTypeID( "Chnl" );
desc2.putClass( idNw, idChnl );
var idUsng = charIDToTypeID( "Usng" );
var desc3 = new ActionDescriptor();
var idT = charIDToTypeID( "T " );
var ref1 = new ActionReference();
var idChnl = charIDToTypeID( "Chnl" );
var idChnl = charIDToTypeID( "Chnl" );
var idTrsp = charIDToTypeID( "Trsp" );
ref1.putEnumerated( idChnl, idChnl, idTrsp );
desc3.putReference( idT, ref1 );
var idClcl = charIDToTypeID( "Clcl" );
var idClcn = charIDToTypeID( "Clcn" );
var idMltp = charIDToTypeID( "Mltp" );
desc3.putEnumerated( idClcl, idClcn, idMltp );
var idSrctwo = charIDToTypeID( "Src2" );
var ref2 = new ActionReference();
var idChnl = charIDToTypeID( "Chnl" );
var idChnl = charIDToTypeID( "Chnl" );
var idTrsp = charIDToTypeID( "Trsp" );
ref2.putEnumerated( idChnl, idChnl, idTrsp );
desc3.putReference( idSrctwo, ref2 );
var idClcl = charIDToTypeID( "Clcl" );
desc2.putObject( idUsng, idClcl, desc3 );
executeAction( idMk, desc2, DialogModes.NO );



als Antwort auf: [#428266]

Photoshop-Ebenen bemaßen

pixelstaub
Beiträge gesamt: 128

20. Dez 2009, 12:18
Beitrag # 10 von 19
Beitrag ID: #428436
Bewertung:
(7617 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Sandor, hallo Hanse (oder heißt’s Hänse?),

vielen Dank Euch für Euren Einsatz!!! Ich werd mal weitertüfteln und mich wieder hier melden, wenn ich einen Schritt weiter bin.
Danke auch für den Link zur AppleScript-Mailinglist von Apple (alle Ebenen eines Photoshop-Dokuments zu ermitteln wäre meine nächste Frage an Euch Cracks gewesen :)

Schöne Grüße aus dem verschneiten Köln
Stephan


als Antwort auf: [#428386]

Photoshop-Ebenen bemaßen

jekyll
Beiträge gesamt: 2047

21. Dez 2009, 02:08
Beitrag # 11 von 19
Beitrag ID: #428465
Bewertung:
(7576 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi,
einpaar Anmerkungen zu den Skript:
Wenn man was verändert sollte man das auch wiederherstellen:
statt
--set units to pixel units
etwa so:
Code
set {originalEinheit, ruler units of settings} to {ruler units of settings, pixel units} 
set liste to bounds of selection of current document
set ruler units of settings to originalEinheit


oder hier:
Code
--- list1 mit Platzhaltern füllen  
set list1 to {1, 2, 3, 4}
copy bounds of selection of current document to list1

wäre es so einfacher:
Code
set liste to bounds of selection of current document 


ich würde das Skript etwa so schreiben (und es geht bestimmt noch eleganter ;o) ):
Ich habe die "Ebene Transparenz laden" Javascript vom "kleinen hans" übernommen, nachdem ich den ganzen Diskusion gelesen habe.

Code
tell application "Adobe Photoshop CS4" 
tell current document
do javascript "var id18 = charIDToTypeID( \"setd\" );
var desc4 = new ActionDescriptor();
var id19 = charIDToTypeID( \"null\" );
var ref4 = new ActionReference();
var id20 = charIDToTypeID( \"Chnl\" );
var id21 = charIDToTypeID( \"fsel\" );
ref4.putProperty( id20, id21 );
desc4.putReference( id19, ref4 );
var id22 = charIDToTypeID( \"T \" );
var ref5 = new ActionReference();
var id23 = charIDToTypeID( \"Chnl\" );
var id24 = charIDToTypeID( \"Chnl\" );
var id25 = charIDToTypeID( \"Trsp\" );
ref5.putEnumerated( id23, id24, id25 );
desc4.putReference( id22, ref5 );
executeAction( id18, desc4, DialogModes.NO ); "
end tell
set {originalEinheit, ruler units of settings} to {ruler units of settings, pixel units}
set liste to bounds of selection of current document
set ruler units of settings to originalEinheit
set {x1, y1, x2, y2} to {first item of liste, second item of liste, third item of liste, last item of liste}
set meinText to (((x2 - x1) as string) & " x " & (y2 - y1) as string) & " Pixel over all"
set layerRef to make new art layer in current document with properties {kind:text layer}
tell text object of layerRef
set position to {x1, y1 + 10}
set contents to meinText
set size to 10
end tell
end tell

Antwort auf: alle Ebenen eines Photoshop-Dokuments zu ermitteln

?? wie meinst Du das?
Willst Du erfahren wie viele Ebene du hast in den Dokument? oder

Willst Du eine Schleife die allen Ebenen abarbeitet?

und dieser Fragen wären auch noch offen:

Welche Ebenentypen müssen abgearbeitet werden?
Soll nur eine Textebene mit dem Beschreibung erzeugt werden oder mehreren?
Wäre nicht besser in den Exif oder in die Kommentare vom File, das alles hinein zu schreiben statt in eine Textebene?


als Antwort auf: [#428436]
(Dieser Beitrag wurde von jekyll am 21. Dez 2009, 02:16 geändert)

Photoshop-Ebenen bemaßen

pixelstaub
Beiträge gesamt: 128

21. Dez 2009, 10:35
Beitrag # 12 von 19
Beitrag ID: #428475
Bewertung:
(7530 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Sándor,

dank’ Dir!

Antwort auf: ?? wie meinst Du das?
Willst Du erfahren wie viele Ebene du hast in den Dokument? oder
Willst Du eine Schleife die allen Ebenen abarbeitet?


Von beidem ein wenig: Ich würde gerne am Anfang eine Liste mit all den Ebenennamen füllen, die bearbeitet werden sollen (entweder alle art layer, die keine textlayer sind oder – ich halte das für den besseren Weg: Alle Ebenen, deren Name mit "#" anfängt). So könnte ich nach dem Anlegen der neuen Textebene (mit Bemaßungen) die nächste Ebene aus meiner Liste selektieren, diese abarbeiten, usw.

Antwort auf: und dieser Fragen wären auch noch offen:
Welche Ebenentypen müssen abgearbeitet werden?
Soll nur eine Textebene mit dem Beschreibung erzeugt werden oder mehreren?
Wäre nicht besser in den Exif oder in die Kommentare vom File, das alles hinein zu schreiben statt in eine Textebene?


… alle Ebenen, deren Name mit "#" anfängt – man könnte dann beim Anlegen der PSD bereits steueren, welche Ebenen anschliessend bemaßt werden sollen (pro Ebene würde ich eine neue Textebene anlegen, die die Bemaßung enthält – am besten direkt ober- oder unterhalb der zu bemaßenden Ebene, damit es einigermaßen übersichtlich bleibt).
Ich würde lieber Textebenen benutzen als Exif oder Kommentare. Ich erstelle immer wieder Screendesigns, die anschliessend an einen Programmierer gehen, der wissen muss, welche Elemente wie groß sind und dem ich dafür bemaßte JPGs zuschicke (klar, es wäre einfacher, wenn dieser Photoshop besäße und sich die Maße selbst anschauen würde – aber so ist es nun mal nicht). Ein Script, was sich schon mal um die Bemaßung der Einzelelemente kümmern würde, wäre da eine Riesenhilfe.

Danke nochmal an alle fleißigen Helfer und feinste Weihnachtsgrüße!
Stephan


als Antwort auf: [#428465]

Photoshop-Ebenen bemaßen

jekyll
Beiträge gesamt: 2047

21. Dez 2009, 14:46
Beitrag # 13 von 19
Beitrag ID: #428496
Bewertung:
(7506 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
hi
probiere mal dieser hier:
Code
tell application "Adobe Photoshop CS4" 
set {originalEinheit, ruler units of settings} to {ruler units of settings, pixel units}
tell current document
set {ebenen, ebeneCt} to {layers, 0}
repeat with einEbene from 1 to count ebenen
set einEbeneRef to layer (einEbene + ebeneCt)
set current layer to einEbeneRef
if "#" is in ((name of einEbeneRef) as text) then
my ebeneAktion(einEbeneRef)
set ebeneCt to ebeneCt + 1
end if
end repeat
end tell
set ruler units of settings to originalEinheit
end tell

on ebeneAktion(einEbene)
tell application "Adobe Photoshop CS4"
set {x1, y1, x2, y2} to {first item of bounds of einEbene, second item of bounds of einEbene, ¬
third item of bounds of einEbene, last item of bounds of einEbene}
set meinText to (((x2 - x1) as string) & " x " & (y2 - y1) as string) & " Pixel over all for Layer \"" & name of einEbene & "\""
set layerRef to make new art layer before current layer of current document ¬
with properties {kind:text layer}
tell text object of layerRef
set position to {x1, y1 + 10}
set contents to meinText
set size to 10
end tell
end tell
end ebeneAktion


@ "kleine hans"
die korrekte Antwort wäre vorhin von mir "bounds of current layer of current document"
hier sind die ebenen masken auch mit einbezogen und bei vektor ebenen wird keine fehler produziert.


als Antwort auf: [#428475]
(Dieser Beitrag wurde von jekyll am 21. Dez 2009, 14:54 geändert)

Photoshop-Ebenen bemaßen

pixelstaub
Beiträge gesamt: 128

21. Dez 2009, 15:32
Beitrag # 14 von 19
Beitrag ID: #428507
Bewertung:
(7492 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hi Sándor,

Wahnsinn! Vielen Dank für ein schönes Weihnachtsgeschenk :)

Ich habe bei
Code
		set meinText to (((x2 - x1) as string) & " x " & (y2 - y1) as string) & " Pixel over all for Layer \"" & name of einEbene & "\"" 

jeweils noch ein "round" hinzugefügt, um keine Nachkommastellen zu haben und werde mal versuchen, das Script so umzubauen, dass auch die Ebenen innerhalb eines layersets mitgezählt werden (momentan ist es noch so, dass – wenn im Namen des layersets eine "#" vorkommt, die Proportionen des gesamten layersets (also die Auswahl aller darin befindlichen Ebenen) bemaßt werden.

Nochmals: Vielen Dank (ziehe meinen Hut!) und Grüße
Stephan


als Antwort auf: [#428496]

Photoshop-Ebenen bemaßen

jekyll
Beiträge gesamt: 2047

21. Dez 2009, 18:04
Beitrag # 15 von 19
Beitrag ID: #428523
Bewertung:
(7474 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Antwort auf: Ich habe bei
Code
set meinText to (((x2 - x1) as string) & " x " & (y2 - y1) as string) & " Pixel over all for Layer \"" & name of einEbene & "\""

jeweils noch ein "round" hinzugefügt, um keine Nachkommastellen zu haben

Ist nicht nötig zu runden weil die Pixels eh keine Nachkommastellen haben können ;o)

Antwort auf: werde mal versuchen, das Script so umzubauen, dass auch die Ebenen innerhalb eines layersets mitgezählt werden

Dieser Skript hier arbeitet Dir bis auf den ersten Sets (alle sets die nicht in eine set sind) alles richtig ab.

Wills Du die versachtelten sets auch abarbeiten kann ich Dir nur so weiter helfen:
ersetze die "art layers & art layers in layer sets" mit "art layers & art layers in layer sets & art layers in layer sets in layer sets"

Code
tell application "Adobe Photoshop CS4" 
set {originalEinheit, ruler units of settings} to {ruler units of settings, pixel units}
tell current document
set {ebenen, ebeneCt, ebeneCt2} to {art layers & art layers in layer sets, 0, 1}
repeat with einEbene in ebenen
set einEbeneRef to item (ebeneCt + ebeneCt2) of (art layers & art layers in layer sets)
set current layer to einEbeneRef
if "#" is in ((name of einEbeneRef) as text) then
my ebeneAktion(einEbeneRef)
set ebeneCt to ebeneCt + 1
end if
set ebeneCt2 to ebeneCt2 + 1
end repeat
end tell
set ruler units of settings to originalEinheit
end tell

on ebeneAktion(einEbene)
tell application "Adobe Photoshop CS4"
set {x1, y1, x2, y2} to {first item of bounds of einEbene, second item of bounds of einEbene, ¬
third item of bounds of einEbene, last item of bounds of einEbene}
set meinText to (((x2 - x1) as string) & " x " & (y2 - y1) as string) & " Pixel over all for Layer \"" & name of einEbene & "\""
set layerRef to make new art layer before current layer of current document ¬
with properties {kind:text layer}
tell text object of layerRef
set position to {x1, y1 + 10}
set contents to meinText
set size to 10
end tell
end tell
end ebeneAktion



als Antwort auf: [#428507]
X

Aktuell

Web / SEO / Blockchain / Betriebssystem
300

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
02.07.2024

Online
Dienstag, 02. Juli 2024, 10.00 - 10.30 Uhr

Webinar

In diesen beiden kostenlose Webinaren erfahren Sie, wie Sie mit Hilfe von Enfocus Griffin und dem Impressed Workflow Server Ihren LFP-Workflows optimieren können. 18.06.2024: So optimieren Sie Ihre Prozesse mit Enfocus Griffin 02.07.2024: So sparen Sie Zeit und Geld mit Impressed Workflow Server in der LFP-Edition Griffin: Griffin ist das leistungsstarke Kraftpaket für das automatische Nesting im Großformatdruck. Dank eines ausgeklügelten, KI-basierten Nesting-Algorithmus können Sie mit Griffin Vorlagen schnell und effizient vernutzen – und das klappt auch mit unregelmäßigen Formen perfekt. Das spart Ihnen unzählige Stunden, die Sie bisher mit dem manuellen Nesting und Ausschießen verbracht haben. Einige wichtige Funktionen ≡ Anlage von Beschnittzugaben ≡ Automatische Erzeugung der Schnittkontur ≡ Erstellung von Strichcodes, Textmarkierungen und Registrierungen IWS LFP Edition: Komplizierte, kleinteilige Aufträge; alles sehr speziell; seit Jahren bewährte Prozesse – da können wir nichts standardisieren und automatisieren! Das sagen viele Großformatdrucker – aber stimmt das wirklich, ist dem tatsächlich so? Mit dem IWS LFP Edition automatisieren Sie Ihre Produktion von der Übernahme der Daten aus dem ERP-System bis zur Erzeugung der verschachtelten Druckform und der Übergabe an den RIP. Phoenix Core ist eine hochentwickelte KI-Technologie für die Planung und das Nesting von Druckerzeugnissen. Anders als herkömmliche Ausschießlösungen arbeitet Phoenix nicht auf Basis von Vorlagen, sondern erzeugt entsprechend der Maschinen- und Produktionsanforderungen druckfertige Layouts „on-the-fly“.

kostenlos

Ja

Organisator: Impressed GmbH

Kontaktinformation: E-Mailschulungen AT impressed DOT de

https://www.impressed.de/schulung.php?c=sDetail&sid=328

So optimieren Sie Ihren LFP-Workflow