[GastForen Programme Print/Bildbearbeitung Adobe InDesign Platzieren von mehreren Worddokumenten

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Print/Bildbearbeitung - Photos, Layout, Design
Themen
Beiträge
Moderatoren
Letzter Beitrag

Platzieren von mehreren Worddokumenten

dima4ka
Beiträge gesamt: 51

25. Apr 2010, 23:59
Beitrag # 1 von 5
Bewertung:
(1269 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Zitat Also wenn es nur darum geht, 100 Worddateien in InDesign zu plazieren (jeweils auf einer neuen Seite beginnend), dann brauchst Du dafür keine Datenzusammenführung und vergißt die Sache mit den Excel-Tabellen am bessten wieder ganz schnell. - Aber möglicherweise habe ich die Anforderung nicht ganz verstanden.

Für den MAC habe ich zur fortlaufenden Plazierung einer größeren Menge an Dokumenten ein AppleScript: placeSelectedDocs.as.
Ein Dialog fordert zunächst zur Auswahl der zu plazierenden Dokumente auf, fügt eine neue Seite ein und plaziert die erste Datei (mit Autofluß, also so lange, bis kein Text mehr zu plazieren ist). Danach fügt das Skript eine neue Seite ein und plaziert die nächste Datei, usw.

Code
-- placeSelectedDocs.as
--
tell application "Adobe InDesign CS2"
set myDoc to active document
set myunsortedFiles to choose file with multiple selections allowed
set user interaction level of script preferences to never interact
tell myDoc
set myFiles to my sort(myunsortedFiles)
repeat with myCounter from 1 to length of myFiles
if (count of pages) > 1 then
set newPage to make page
end if
set myLeftMargin to left of (margin preferences of last page)
set myTopMargin to top of (margin preferences of last page)
place item myCounter of myFiles on page (count of pages) place point {myLeftMargin, myTopMargin} with autoflowing without showing options
end repeat
end tell
set user interaction level of script preferences to interact with all
end tell
on sort(the_list)
set old_delims to AppleScript's text item delimiters
set AppleScript's text item delimiters to {ASCII character 10} ¬
-- always a linefeed
set list_string to (the_list as string)
set new_string to do shell script "echo " & quoted form of list_string ¬
& " | sort -f"
set new_list to (paragraphs of new_string)
set AppleScript's text item delimiters to old_delims
return new_list
end sort


Martin Fischer

als Antwort auf:

(Dieser Beitrag wurde von Martin Fischer am 12. Mär 2006, 18:34 geändert)



Vorab ein großes Lob an Martin, der sich wirklich viel Mühe gemacht hat, und dieses perfekte Scirpt fabriziert hat. Es läuft gemäß der Berschreibung zu 100%. Ich hatte es mit 130 Dateien probiert!

Meine frage: wäre es evtl. möglich das Script so anzupassen, dass wenn die erste Datei platziert wurde neue Seite erstellt wird und dann das zweite Dokument so eingefügt wird, sodass eine Textverkettung zwischen dem ersten und dem zweiten Dokument entsteht?

Das wäre Die Lösung für mich, wäre dir echt sehr dankbar, denn ich bekomme so im schnitt 100-200 Worddokumente die ich als Broschüre gestalten muss, und damit kann man sich sehr helfen.

Wie gesagt, das Script ist super, aber ich habe dann immer die Leeren Seiten, bzw. wenn da nur eine Zeile steht.

Vielen Dank im Voraus

mfg
X

Platzieren von mehreren Worddokumenten

Martin Fischer
  
Beiträge gesamt: 12684

26. Apr 2010, 07:56
Beitrag # 2 von 5
Beitrag ID: #440137
Bewertung:
(1228 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo dima4ka,

versuch's mal mit der folgenden auf die Schnelle angepassten Version
Code
-- placeSelectedDocs.as  
--
tell application "Adobe InDesign CS4"
set myDoc to active document
set myunsortedFiles to choose file with multiple selections allowed
set user interaction level of script preferences to never interact
tell myDoc
set myFiles to my sort(myunsortedFiles)
repeat with myCounter from 1 to length of myFiles
if (count of pages) > 1 then
set newPage to make page
end if
set myLeftMargin to left of (margin preferences of last page)
set myTopMargin to top of (margin preferences of last page)
set new_story to place item myCounter of myFiles on page (count of pages) place point {myLeftMargin, myTopMargin} with autoflowing without showing options
if (myCounter = 1) then
set first_story to new_story
else
if (contents of last character of first item of first_story is not "return") then
set contents of last insertion point of first item of first_story to return
end if
set next text frame of last item of text containers of first item of first_story to first item of text containers of first item of new_story
end if
end repeat
end tell
set user interaction level of script preferences to interact with all
end tell
on sort(the_list)
set old_delims to AppleScript's text item delimiters
set AppleScript's text item delimiters to {ASCII character 10}
-- always a linefeed
set list_string to (the_list as string)
set new_string to do shell script "echo " & quoted form of list_string & " | sort -f"
set new_list to (paragraphs of new_string)
set AppleScript's text item delimiters to old_delims
return new_list
end sort



als Antwort auf: [#440132]

Platzieren von mehreren Worddokumenten

dima4ka
Beiträge gesamt: 51

26. Apr 2010, 09:58
Beitrag # 3 von 5
Beitrag ID: #440147
Bewertung:
(1198 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Guten Morgen Martin,

also, was soll ich dazu sagen?
schicke mir deine Adresse, ich schicke dir per Post eine Karte:

Best-Scripter every where, oder so was!

Ich meine es im Ernst!!!!


VIELEN DANK!!!

funktioniert zu 100%


als Antwort auf: [#440137]

Platzieren von mehreren Worddokumenten

Martin Fischer
  
Beiträge gesamt: 12684

26. Apr 2010, 10:47
Beitrag # 4 von 5
Beitrag ID: #440153
Bewertung:
(1181 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Dima,

Deine begeisterte Anwort und das Lob werte ich als Ausdruck Deiner Freude.
Prima, dass es so funktioniert, wie Du es erwartest.
Du brauchst die Post nicht weiter zu bemühen.


als Antwort auf: [#440147]

Platzieren von mehreren Worddokumenten

dima4ka
Beiträge gesamt: 51

26. Apr 2010, 22:32
Beitrag # 5 von 5
Beitrag ID: #440235
Bewertung:
(1137 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Doch, denn ich habe sehr oft solche Arbeit, und da spare ich bares Geld, also her mit der Adresse, bitte per PN!!!


als Antwort auf: [#440153]
X

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
02.02.2023

Prozesse optimieren und effizient gestalten

Zürich
Donnerstag, 02. Feb. 2023, 08.00 - 10.00 Uhr

Digitalisierung, Webauftritt

Digitalisierung mitgestalten - Worauf kommt es an? Wie wichtig ist die Webseite? Webseite mit Word Press? Interne Prozesse optimieren

Ja

Organisator: B. Isik - SNF Academy

Kontaktinformation: Birol Isik, E-Mailinfo AT bkcc DOT ch

https://digitalisierung-heute.ch/digitalisierung-informationstag-schweiz/

Veranstaltungen
01.03.2023 - 09.03.2023

Online
Mittwoch, 01. März 2023, 00.00 Uhr - Donnerstag, 09. März 2023, 00.00 Uhr

Online Webinar

Wie gehen wir mit diesen Veränderungen um? Was ist notwendig, damit wir die Digitalisierung im Unternehmen klappt? Veränderungsprozesse verstehen und entsprechend handeln Mitarbeiter als Botschafter Webseite mit WordPress erstellen SEA /SEO (Ads aufschalten)

Ja

Organisator: B. Isik - SNF Academy

Kontaktinformation: B. Isik, E-Mailinfo AT snfa DOT ch

https://www.fernstudiumfitness.ch/digitalisierung-schweiz/