property cliclickPath : POSIX path of file ((path to "desk" as string) & "cliclick") 
 
--================== Der run-Handler ======================== 
-- Der Handler welcher durch den Doppelklick auf das Icon des Scripts aufgerufen wird 
--==================================================== 
 
on run 
 display dialog "Die XPress-Projekte (oder Ordner,  
welche XPress-Projekte enthalten) 
auf das Icon dieses Droplets ziehen." buttons "OK" default button 1 with icon 2 
end run 
 
--================= Der Open-Handler ======================== 
-- Der Handler, welcher aufgerufen wird, wenn Dateien auf das Icon des Scripts gezogen werden 
--==================================================== 
 
on open allObjects 
 -- prüfen, ob QuarkXPress läuft 
 testApp() 
 tell application "QuarkXPress 7.31" 
  activate 
 end tell 
 -- eine Schleife durch die gedroppten Objekte ... 
 repeat with aObject in allObjects 
  -- ... welche eines nach dem anderen zum Handler 'processObject()' gesandt werden 
  processObject(aObject) 
 end repeat 
 tell application "QuarkXPress 7.31" 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
 end tell 
end open 
 
 
--=================== Handler ============================ 
-- die Handlers (Subroutinen) welche von oben oder unereinander aufgerufen werden 
--==================================================== 
 
-- der Handler welcher die gedroppten Objekte untersucht 
-- er macht eine Liste des Ordnerinhalts und sendet die Elemente an sich selbst 
-- Dateien, welche XPress-Projekte sind (oder -Dokumente) werden dem Export-Handler übergeben 
on processObject(aObject) 
 -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner ... 
 if (aObject as Unicode text) ends with ":" then 
  -- die Liste der Objekte wird aufgestellt (ohne unsichtbare Dateien) 
  set contentsList to list folder aObject without invisibles 
  -- eine Schleife durch diese Liste 
  repeat with anItem in contentsList 
   -- der Pfad wird zusammengesetzt 
   set objPath to ((aObject as Unicode text) & anItem) 
   -- die Elemente (Dateien oder Ordner) werden zum aktuellen Handler gesandt 
   processObject(objPath as alias) 
  end repeat 
  -- ... sonst ist das Objekt eine Datei 
 else 
  set curFile to (aObject as Unicode text) 
  -- der Dateityp wird geprüft 
  set fileType to file type of (info for file curFile) 
  -- wenn der dateityp jenem eines XPress-Projekts oder -Dokuments entspricht, dann ... 
  if fileType = "XPRJ" or fileType = "XDOC" then 
   -- ... wird der Pfad dem Handler exportPDF() übergeben 
   set okay to exportPDF(curFile) 
   if okay then 
   else 
    stopRightNow() 
   end if 
  end if 
 end if 
end processObject 
 
-- in diesem Handler öffnet QuarkXPress die Datei, exportiert das Layout als PDF 
-- und schliesst das Projekt 
on exportPDF(qxpFile) 
 set okay to false 
 tell application "QuarkXPress 7.31" 
  try 
   open qxpFile as alias use doc prefs yes remap fonts ask do auto picture import yes 
   tell document 1 
    repeat with i from 1 to count of picture boxes 
     try 
      tell picture box i 
       tell image 1 
        set imgPath to file path 
        if imgPath is not null then 
         if imgPath is not no disk file then 
          if missing is true then 
           return false 
          end if 
         end if 
        end if 
       end tell 
      end tell 
     end try 
    end repeat 
   end tell 
   try 
    save document 1 
   end try 
   set okay to true 
  end try 
 end tell 
 if okay then 
  try 
   tell application "System Events" 
    tell process "QuarkXPress" 
     tell menu bar 1 
      tell menu bar item "File" 
       tell menu "File" 
        tell menu item "Export" 
         tell menu "Export" 
          click menu item "Layout as PDF..." 
         end tell 
        end tell 
       end tell 
      end tell 
     end tell 
     delay 0.5 
     my clickButton() 
    end tell 
   end tell 
   delay 1 
   tell application "QuarkXPress 7.31" 
    try 
     close document 1 saving no 
    end try 
   end tell 
  on error 
   tell application "QuarkXPress 7.31" 
    try 
     close document 1 saving no 
    end try 
   end tell 
  end try 
 end if 
 return true 
end exportPDF 
 
on testApp() 
 tell application "System Events" 
  activate 
  set curProc to (name of every process) as string 
 end tell 
 tell me to activate 
 if curProc does not contain "QuarkXPress" then 
  display dialog "Bitte QuarkXPress starten." buttons ¬ 
   "OK" default button 1 with icon 2 
  error number -128 
 end if 
end testApp 
 
on stopRightNow() 
 tell application "QuarkXPress 7.31" 
  display dialog "Mindestens ein Bild fehlt. 
 
Die Ausführung muss sofort beendet  
werden, sonst stürzt XPress ab." buttons ¬ 
 "OK" default button 1 with icon 0 
 end tell 
 error number -128 
end stopRightNow 
 
on clickButton() 
 set {xPos, yPos} to {780, 670} -- Button "Options..." 
 set clickCommand to (cliclickPath & " " & xPos & " " & yPos) 
 do shell script clickCommand 
 delay 1 
 set {xPos, yPos} to {770, 295} -- Button "Export pages as separte PDFs" 
 set clickCommand to (cliclickPath & " " & xPos & " " & yPos) 
 do shell script clickCommand 
 delay 0.5 
 set {xPos, yPos} to {647, 288} -- Artikel "Hyperlinks" 
 set clickCommand to (cliclickPath & " " & xPos & " " & yPos) 
 do shell script clickCommand 
 delay 0.5 
 set {xPos, yPos} to {745, 255} -- Checkbox "Include Hyperlinks" 
 set clickCommand to (cliclickPath & " " & xPos & " " & yPos) 
 do shell script clickCommand 
 set {xPos, yPos} to {1037, 541} -- Button "OK" 
 set clickCommand to (cliclickPath & " " & xPos & " " & yPos) 
 do shell script clickCommand 
 set {xPos, yPos} to {1081, 721} -- Button "Sichern" 
 set clickCommand to (cliclickPath & " " & xPos & " " & yPos) 
 do shell script clickCommand 
end clickButton