Hallo Hans,

kann man per Script (QuarkX4.11) bei gruppierten Bildern die Gruppierung auflösen?

Grund: Quark-Dokument wird in Indesign geöffnet.
Eine Grupierung in QX4.11 ergibt falsche Interpretation in ID2.02
(schräggestellte grupp. Bilder werden doppelt schräg gestellt)

Bei aufgelösten Gruppierung ist das Ergebnis ok.

Gruss Willem

Hallo Willem,

wenn man die Gruppe manuell auswählt, dann ist es am einfachsten, die Gruppierung mit Befehl-U aufzulösen.
Weil Du dies per Script ausführen willst, nehme ich an, dass der Anwender nicht eingreifen soll.

Das Problem wird sein, die Gruppe zu identifizieren. Im folgenden Script wird die 'picture box 1' ausgewählt. Du musst diese Adressierung so ändern, dass eine Bildbox, welche Mitglied einer Gruppe ist, ausgewählt wird.
---
tell application "QuarkXPress 4.11"
  activate
  tell document 1
    set selection to null
    set tool mode to drag mode
    set selected of picture box 1 to true
  end tell
  if box type of current box = group box type then
    select menu item 11 of menu 5
  end if
end tell
---
Nachdem XPress mit 'activate' in den Vordergrund geholt worden ist, wird zuerst eine eventuelle Auswahl aufgehoben (mit 'set selection to null'). Dann wird das Objektswerkzeug ausgewählt (mit 'set tool mode to drag mode'). Dann wird eine Box ausgewählt (mit 'set selected of ... to true'). Anschliessend wird der Boxentyp der Auswahl festgestellt. Wenn dies 'group box type' ist, dann wird der Menüartikel ausgewählt.

Beachte dass dieser Befehl direkt an das Programm gerichtet sein muss. Er darf sich nicht innerhalb eines anderen 'tell'-Blocks (welcher das Dokument oder die ausgewählte Box adressiert) befinden. Wenn die Konstruktion des Scripts dies nicht zulässt, dann kann der Befehl in einen Handler verschoben werden (z.B. 'on ungroupBoxes()'. Dem Aufruf muss das Wort 'my' vorangestellt werden (= my 'ungroupBoxes()'), weil man sich in einem 'tell XPress'-Block befindet.

Die Auswahl des Menüartikels ist ein nativer XPress-Befehl. Übersetzt: 'wähle den Menüartikel 11 des Menüs 5 aus'. Die Unterteilungslinien der Menüs zählen auch als Artikel. Und das Apfel-Menü ist die Nummer 1. Man könnte anstelle der Ziffern die tatsächlichen Worte einsetzen: 'select menu item "Gruppieren rückgängig" of menu "Objekt"'. Dies ist aber länger, nicht elegant, muss für eine andere Sprache übersetzt werden und auch eine Fehlerquelle z.B. wenn im Menü statt einer Ellipsis drei Punkte stehen.

Hans Haesler, hsa@ringier.ch

Hallo Hans,

beim QX-Dokument mit einem Bild funktioniert es wie beschrieben, aber bei meinen Scriptkenntnissen wird der Einbau in ein umfangreiches Script unmöglich.
Frage:
Kann man/ du das Auflösen der Gruppe in dein Script "DoppelSeitenEPS4.11_07d"  einbauen und dabei abfragen ob das erste Bild eine Gruppe ist, wenn ja die Gruppe auflösen, wenn nein zum nächsten Bild gehen u.s.w.?

Da man aber nicht weiß ob im QX-Dokument 5 oder 30 Bilder enthalten sind wird es warscheinlich schwierig dies zu realisieren.

Trotzdem vielen Dank für die schnelle Hilfe

Gruss Willem

Hallo Willem,

ja, man könnte das Doppel-Seiten-EPS-Script entsprechend erweitern. Besser wäre aber
ein eigenständiges Script, welches sich nur um das Gruppieren-Rückgängigmachen kümmert.

Versuch's bitte mal mit dieser Lösung:
---
tell application "QuarkXPress 4.11"
  activate
  set measurements showing to false
  tell document 1
    set tool mode to drag mode
    repeat with i from 1 to count of picture boxes
      set selection to null
      set selected of picture box i to true
      if box type of current box = group box type then
        my ungroupBoxes()
      end if
    end repeat
  end tell
end tell

on ungroupBoxes()
  tell application "QuarkXPress 4.11"
    select menu item 11 of menu 5
  end tell
end ungroupBoxes
---
In der Befehlszeile nach 'activate' wird mit 'set measurements showing to false' die
Masspalette versteckt, damit die Ausführung nicht durch das unablässige Anzeigen
der Parameter unnötig gebremst wird.

Mit einer Repeat-Schleife werden die Bildboxen abgefragt. Wenn der Boxen-Typ als
"gruppiert" gemeldet wird, dann wird der schon erwähnte Handler aufgerufen.

Hans Haesler, hsa@ringier.ch

Danke Hans,

Problem gelöst, Script funktioniert souverän.

Gruesse Willem  :D