Quarkscript für Seite vergrössern

[Gast] Foren Programmierung/Entwicklung AppleScript Quarkscript für Seite vergrössern

Programmierung/Entwicklung

Themen

Beiträge

Moderatoren

Letzter Beitrag

AppleScript

1260

8218

Hans Haesler

8. Nov 2023, 13:38

mb_new

1 2

Anonym

Beiträge gesamt: 22827

7. Nov 2005, 09:23
Beitrag # 1 von 29
Bewertung:
(4809 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Scripter,
wie kann ich per Applescript eine Quarkseite vergrössern ?

Das Script soll wie folgt ablaufen:
Per Dialogbox möche ich festlegen wieviel die Seite vergrössert werden soll (ist ja auch logisch), aber dann möchte ich gerne, das alle elemente auf der Seite wieder mittig ausgereichtet werden.

Also wenn ich vorher z.B. eine Bildbox hatte die mittig stand, dann würde Sie nach vergrössern der Seite ja links versetzt sein, da Quark die Seite immer nach unten und rechts vergrössert.

Deswegen soll das Script das ausgleichen.

Frage, gehts irgendwie. ?

Danke und Grüsse
Mike

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

7. Nov 2005, 09:38
Beitrag # 2 von 29
Beitrag ID: #420308
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

irgendwie wird's schon gehen. :-)

Fragen: Welche Version von QuarkXPress? Unter welchem Mac OS?
Enthält das Layout nur eine Seite? Einzel- oder doppelseitig?
Ist die Vergrösserung ein Prozentwert? Oder Angaben für Breite und Höhe?
Alle Elemente auf der Seite: Wie sieht das aus? Würdest Du mir bitte
ein Musterprojekt zustellen?

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Anonym

Beiträge gesamt: 22827

7. Nov 2005, 10:28
Beitrag # 3 von 29
Beitrag ID: #420309
Bewertung:
(4809 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Hans,

das das irgendwie geht und das Du das hinkriegst war mir schon klar :)))
Also, gedacht ist das ganze für Dokumente, mehrere Seiten enthalten können, aber keine Doppelseiten.

Die Angaben sollen in Breite und Höhe gemacht werden.

Und alle Elemente auf der Seite sollen dann wieder gleichmässig ausgerichtet werden.

Das heisst, wenn ich z.B. 8cm zugebe für Höhe und Breite, dann müssen alle Elemente um 4cm nach unten und rechts verschoben werden um wieder mittig zu stehen.

Im Prinzip soll das Ganze eine variable Beschnittzugabe werden.

Es soll unter MacOSX und Quark 6.1

Gruss Mike

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

7. Nov 2005, 11:49
Beitrag # 4 von 29
Beitrag ID: #420310
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

das folgende Script habe ich mit QuarkXPress 6.5 unter Tiger getestet.

Die Werte "Breite" und "Höhe" werden auf eine Dezimalstelle gerundet (weil sonst unter Umständen im Dialog Dinger
wie 210.000106811523 erscheinen könnten). Wenn die Zahl mit ".0" endet, wird sie zur einer Ganzzahl konvertiert.

Die Seitengrösse wird nach der Eingabe des Anwenders verändert. Dann geht eine Wiederholungssschleife
durch alle Seiten, wählt auf der aktuellen Seite alle Boxen aus, stellt die Breite und Höhe dieser Boxengruppe aus,
errechnet daraus den neuen Wert der X- und Y-Position (= 'origin of bounds') und verschiebt die Gruppe entsprechend.
Am Schluss sorgt ein zweimaliges Ändern des Ansichtsprozents dafür, dass die "Geister"-Anfasserpunkte verschwinden.
---
tell document 1 of application "QuarkXPress 6.5"
activate
set selection to null
set pW to (((page width as real) + 0.05) div 0.1) / 10
if (pW as string) ends with ".0" then set pW to pW as integer
set pH to (((page height as real) + 0.05) div 0.1) / 10
if (pH as string) ends with ".0" then set pH to pH as integer
set pageSize to text returned of (display dialog ¬
"Seitengrösse: Breite = " & pW & " / Höhe = " & pH & ¬
return & return & "Neue Breite / Höhe:" default answer "" & pW & " " & pH)
set pW to (word 1 of pageSize) as real
set pH to (word 2 of pageSize) as real
set properties to {page width:pW, page height:pH}
repeat with i from 1 to count of pages
tell page i
set selected of every generic box to true
tell group box 1
set {bW, bH} to {(width of bounds) as real, (height of bounds) as real}
set y to (pH - bH) / 2
set x to (pW - bW) / 2
set origin of bounds to {y, x}
end tell
end tell
set selection to null
end repeat
set view scale to (view scale as real) - 1
set view scale to (view scale as real) + 1
display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end tell
---
Man sollte noch ein paar Tests einfügen: Ist ein Projekt geöffnet? Ist die Eingabe des Anwenders in zwei "Worten",
welche reine Zahlen sind? Und sind die Werte innerhalb des Möglichen? Weil im Moment auch kein 'try'-Wickel verwendet
wird, kommt bei einem eventuellen Problem eine mehr oder weniger verständliche Meldung.

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Anonym

Beiträge gesamt: 22827

7. Nov 2005, 13:11
Beitrag # 5 von 29
Beitrag ID: #420311
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Hans,

erstmal Danke für die Hilfe. das mit den Fehlerroutinen, werde ich versuchen selbst hinzubekommen.

Jetzt habe ich allerdings noch eine Frage:
Könnte man das Ganze auch mit unregelmäsigem beschnitt machen ?

Ich stell mir das so vor:
z.B. oben beschnitt hinzugeben: 8cm
unten 3 cm, links 4cm rechts 4cm

das script soll dann wieder alles richtig plazieren sowie bei dem obigen script.

Nochmal Danke und Grüsse
Mike

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

7. Nov 2005, 14:11
Beitrag # 6 von 29
Beitrag ID: #420312
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

jetzt brauch' ich eine Zeichnung ... Würdest Du mir bitte zwei Projekte senden. Das erste im Zustand,
wie es das Script antrifft; das zweite, wie es manuell nach Deinen Angaben geändert worden ist.

Und auch: QXP 4.11? 5.01? 6.1? 6.5? Und Panther? Tiger?

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Anonym

Beiträge gesamt: 22827

7. Nov 2005, 14:23
Beitrag # 7 von 29
Beitrag ID: #420313
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Hans,

die Quarkfiles sende ich Dir per Email.

ZUm Verständniss:
Die Datei 200x400_Orginalzustand.qxp enthält die Seite im Orginalzustand.
Die Datei 200x400_neuer_Beschnitt.qxp enthält die Seite mit meinen Veränderungen die vom Script durchgeführt werden sollen.

Also:
Die neue Seitengrösse habe ich auf 210 x 420 eingestellt.
Ich brauchte für die Seite einen Beschnitt von Oben 6mm und unten 14 mm.
Und von links und rechts 5mm.

Ich möchte also unterschiedliche Beschnittzugaben machen.

Ich hoffe ich hab das verständlich erklärt.

Grüsse und viel Spass :)))
Miike

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

7. Nov 2005, 22:01
Beitrag # 8 von 29
Beitrag ID: #420314
Bewertung:
(4809 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

ja, dank Deinen Files habe ich jetzt kapiert, worum es geht. Das folgende Script deckt
beide Möglichkeiten (gleichmässig und asymmetrisch) ab. Zwei Änderungen waren notwendig.
1) Im Eingabedialog wird nicht mehr die Seitengrösse, sondern die Zugabe eingetippt.
Bei einem Wert wird ringsum gleichviel gerechnet. Bei vier Werten übernimmt das Script
die Zahlen für oben, links, unten und rechts.
2) Die Boxengruppe wird nicht mehr auf der Seite neu zentriert, sondern um die Werte y1
und x1 verschoben.
Weitere Kommentare sind im Script enthalten (entwickelt mit QXP 6.1 unter Panther):
---
-- feststellen, ob der Dezimalseparator ein Komma oder ein Punkt ist
set decSep to ""
try
"1.5" as real
set decSep to "."
on error
set decSep to ","
end try

tell document 1 of application "QuarkXPress 6.1"
activate
-- die Auswahl aufheben
set selection to null
-- den Eingabedialog zeigen
set marVals to text returned of (display dialog ¬
"Zugabewerte in mm (mit Zwischenräumen trennen)" & return & return & ¬
"(1 Wert = alle gleich / 4 = verschiedene Werte)" & return & ¬
"oben links unten rechts" default answer "")
-- die Ränderwerte testen
if marVals is not "" then
if marVals contains "-" then
display dialog "Ungültige Eingabe für die Zugabe." buttons "OK" default button 1 with icon 0
error number -128
end if
-- den Handler aufrufen, welcher überflüssige Zwischenräume entfernt
set marVals to my stripSpaces(marVals)
if marVals is not "" then
repeat with i from 1 to count of marVals
if character i of marVals is not in "0123456789,. " then
display dialog "Die Eingabe für die Zugabe ist ungültig." buttons "OK" default button 1 with icon 0
error number -128
end if
end repeat
else
display dialog "Du hast anstelle des Zugabewertes einen Zwischenraum getippt." buttons "OK" default button 1 with icon 0
error number -128
end if
set AppleScript's text item delimiters to {" "}
-- wenn vier Werte vorhanden, die Liste aufbauen
if (count of text items of marVals) = 4 then
set marginList to {}
repeat with i from 1 to 4
-- den Handler aufrufen, welcher die einzelnen Werte prüft
set end of marginList to my checkReal(text item i of marVals, decSep)
end repeat
set {ry1, rx1, ry2, rx2} to marginList
-- wenn nicht vier Werte gefunden wurden, dann den vier Elementen jenen der ersten Zahl zuweisen
else
set r1 to my checkReal(text item 1 of marVals, decSep)
set {ry1, rx1, ry2, rx2} to {r1, r1, r1, r1}
end if
set AppleScript's text item delimiters to {""}
else
display dialog "Bitte mindestens einen Wert für die Zugabe eingeben." buttons "OK" default button 1 with icon 0
error number -128
end if
-- die Masseinheiten vorübergehend in Punkte ändern
set properties to {vertical measure:points, horizontal measure:points}
-- die vier Zugabewerte in Punkte umrechnen
set ry1 to ("" & ry1 & "mm") as point units as real
set rx1 to ("" & rx1 & "mm") as point units as real
set ry2 to ("" & ry2 & "mm") as point units as real
set rx2 to ("" & rx2 & "mm") as point units as real
-- die aktuelle Seitengrösse speichern
set pW to (page width as point units as real)
set pH to (page height as point units as real)
-- die neue Seitengrésse ausrechnen
set pW to pW + rx1 + rx2
set pH to pH + ry1 + ry2
-- versuchen, die Grösse der Seite zu ändern
try
set properties to {page width:pW, page height:pH}
on error
set properties to {vertical measure:millimeters, horizontal measure:millimeters}
display dialog "Das Seitenformat kann nicht geändert werden. Zu grosse Werte?" buttons "OK" default button 1 with icon 0
error number -128
end try
-- eine Wiederholungsschleife durch die Seiten
repeat with i from 1 to count of pages
tell page i
-- alle Boxen der Seite auswählen
set selected of every generic box to true
-- die Position Y und X der Gruppe festellen
-- und um die beiden ersten Werte der Eingabe verschieben
tell group box 1
set {y, x} to origin of bounds as list
set origin of bounds to {(y as real) + ry1, (x as real) + rx1}
end tell
end tell
set selection to null
-- den Handler aufrufen, um die vier Boxen zu erzeugen
my makeBoxes(pH, pW, ry1, rx1, ry2, rx2)
end repeat

set properties to {vertical measure:millimeters, horizontal measure:millimeters}
set view scale to (view scale as real) - 1
set view scale to (view scale as real) + 1
display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end tell

-- störende Zwischenräume entfernen (mehrfache, oder zu Beginn oder am Schluss des Strings)
on stripSpaces(aString)
set tmpString to ""
set okay to false
set oneSpace to false
repeat with i from 1 to count of aString
set curChar to character i of aString
if curChar is not " " and okay is false then set okay to true
if okay then
if curChar = " " then
if not oneSpace then
set tmpString to tmpString & curChar
end if
else
set tmpString to tmpString & curChar
set oneSpace to false
end if
if curChar = " " then set oneSpace to true
end if
end repeat
if tmpString is not "" then
repeat while character -1 of tmpString is " "
set tmpString to text 1 thru -2 of tmpString
end repeat
end if
return tmpString
end stripSpaces

on checkReal(curItem, decSep)
set okVal to ""
set nChar to count of curItem
if nChar is 1 then
if curItem is in ",." then
tell application "QuarkXPress 6.1"
display dialog "Die Eingabe für die Zugabe enthält ein einzelnes \"" & curItem & "\"" buttons "OK" default button 1 with icon 0
error number -128
end tell
end if
end if
repeat with i from 1 to nChar
set curChar to character i of curItem
if curChar is in "0123456789" then
set okVal to okVal & curChar
else if curChar is in ",." then
set okVal to okVal & decSep
else
tell application "QuarkXPress 6.1"
display dialog "Die Eingabe für die Zugabe enthält ein ungültiges Zeichen." buttons "OK" default button 1 with icon 0
error number -128
end tell
end if
end repeat
return (okVal as real)
end checkReal

on makeBoxes(pH, pW, ry1, rx1, ry2, rx2)
tell document 1 of application "QuarkXPress 6.1"
make graphic box at beginning with properties {bounds:{0, 0, pH, rx1}, color:"Magenta", shade:100}
make graphic box at beginning with properties {bounds:{0, pW - rx2, pH, pW}, color:"Magenta", shade:100}
make graphic box at beginning with properties {bounds:{0, 0, ry1, pW}, color:"Magenta", shade:100}
make graphic box at beginning with properties {bounds:{pH - ry2, 0, pH, pW}, color:"Magenta", shade:100}
end tell
end makeBoxes
---
Das Masssystem wird vorübergehend in Punkte gewechselt, dadurch können Ungenauigkeiten bei Positionen
ab 272 mm vermieden werden.

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Anonym

Beiträge gesamt: 22827

8. Nov 2005, 17:12
Beitrag # 9 von 29
Beitrag ID: #420315
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Hans,

erstmal Danke für das Script.

Leider bekomm ich folgende Fehlermeldung bei der Ausführung:

Script Fehler: -1753
item 2 of {origin of bounds of group box 1 of page 1 of document 1 of group box 1 of page of document 1 of application "quarkXpress Passport"} kann nicht gelesen werden.

Ich habe es mit verschiedenen Dokumenten versucht, immer der gleiche Fehler.

Grüsse Mike

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

8. Nov 2005, 17:19
Beitrag # 10 von 29
Beitrag ID: #420316
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

bitteschön. Hast Du es auch mit dem Testprojekt versucht, welches Du mir gesandt hast?
Bei mir hat es wunderbar funktioniert. Die Fehlermeldung ist komisch, denn sie wiederholt das Objekt.

Ich gehe jetzt nach Hause und werde mir die Sache im Laufe des Abends ansehen.

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

8. Nov 2005, 21:27
Beitrag # 11 von 29
Beitrag ID: #420317
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

offenbar weisen Deine verschiedenen Dokumente nur eine einzige Box (pro Seite) auf.
Damit sowohl dieser Fall als auch multiple Boxenpräsenz abgedeckt werden kann, muss der Befehl
'tell group box 1' durch 'tell current box' ersetzt werden. Bitte wechsle den folgenden Code
(ungefähr in der Mitte des Scripts) aus:
---
-- eine Wiederholungsschleife durch die Seiten
repeat with i from 1 to count of pages
tell page i
-- alle Boxen der Seite auswählen
set selected of every generic box to true
-- die Position Y und X der Gruppe festellen
-- und um die beiden ersten Werte der Eingabe verschieben
tell current box
set {y, x} to origin of bounds as list
set origin of bounds to {(y as real) + ry1, (x as real) + rx1}
end tell
end tell
set selection to null
-- den Handler aufrufen, um die vier Boxen zu erzeugen
my makeBoxes(pH, pW, ry1, rx1, ry2, rx2)
end repeat
---
So sollte es funktionieren.

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Anonym

Beiträge gesamt: 22827

9. Nov 2005, 10:16
Beitrag # 12 von 29
Beitrag ID: #420318
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Wiedermal absolut perfekt Hans,

grosse Klasse, jetzt funzt es wuderbar, Danke, Danke, Danke !!!!

grüsse mike

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

9. Nov 2005, 10:38
Beitrag # 13 von 29
Beitrag ID: #420319
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

bitteschön. Nun, ich hätte von Anfang an 'current box' verwenden sollen,
dann hätte es auf Anhieb funktioniert.

Gruss, Hans

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Anonym

Beiträge gesamt: 22827

10. Nov 2005, 09:41
Beitrag # 14 von 29
Beitrag ID: #420320
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Hans,

jetzt ist mir doch noch was aufgefallen.

Also das Script funzt wie gesagt wunderbar, aber die roten Bildrahmen werden immer nur auf der ersten Seite eines Dokuments erzeugt. Bei mehrseitigen Dokumenten ändert das Script zwar die Layoutgrössse und versetzt auch die Posiionen richtig, aber die roten Rahmen fehlen.

Kannst Du das noch irgendwie einbauen, das es auch mit mehreren Seiten funzt ? Natürlich nur wenns nicht zu viel Aufwand ist.

Danke und Grüsse

Mike

als Antwort auf: [#420307]

Quarkscript für Seite vergrössern

Hans Haesler

Beiträge gesamt: 5826

10. Nov 2005, 11:19
Beitrag # 15 von 29
Beitrag ID: #420321
Bewertung:
(4808 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Mike,

ja, wenn ich das Script mit einem mehrseitigen Projekt getestet hätte ...

Damit die Magentaboxen nicht ständig auf der ersten Seite erzeugt werden, genügt es, im Handler
'makeBoxes' ein 'tell page i' einzufügen. Der Wert von 'i' muss aber auch übergeben werden.
Am einfachsten wird im Aufruf des Handlers ein 'i' eingeschoben ...

Code

      [b]my makeBoxes(i, pH, pW, ry1, rx1, ry2, rx2)

... und so sieht der Handler aus:
---
on makeBoxes(i, pH, pW, ry1, rx1, ry2, rx2)
tell document 1 of application "QuarkXPress 6.1"
tell page i
make graphic box at beginning with properties {bounds:{0, 0, pH, rx1}, color:"Magenta", shade:100}
make graphic box at beginning with properties {bounds:{0, pW - rx2, pH, pW}, color:"Magenta", shade:100}
make graphic box at beginning with properties {bounds:{0, 0, ry1, pW}, color:"Magenta", shade:100}
make graphic box at beginning with properties {bounds:{pH - ry2, 0, pH, pW}, color:"Magenta", shade:100}
end tell
end tell
end makeBoxes
---

Ich habe aber noch weitere Änderungen vorgenommen ...
 Die Zugabeboxen werden benannt.
 Zu Beginn wird getestet, ob eine Zugabebox existiert (wenn ja, wird der Anwender gewarnt und er kann
entscheiden, ob er die Seiten wirklich nochmals vergrössern will).
 Die Seite wird ins Fenster eingepasst.
 Die aktuelle Seite wird angezeigt.
 Bei einer leeren Seite wird eine Fehlermeldung unterdrückt (aber die Boxen werden trotzdem erzeugt).
 Am Schluss wird wieder die erste Seite angezeigt.

... deshalb werde ich Dir das Script nächstens zustellen.

Gruss, Hans

als Antwort auf: [#420307]

1 2

Aktuell

InDesign / Illustrator

axaio MadeToTag für Adobe InDesign 2024 verfügbar

| 12.10.2023

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen

14.05.2024

Einsparpotenziale in der Weiterverarbeitung

Online
Dienstag, 14. Mai 2024, 10.00 - 10.30 Uhr

Webinar

Prozessoptimierung ist ein Teamsport! Keine Software und keine Maschine allein kann Ihnen helfen, die Effizienzpotenziale Ihres Betriebes maximal auszuschöpfen. Von der Auftragsannahme über die Vorstufe und den Druck bis hin zur Weiterverarbeitung – alles muss optimal ineinandergreifen. Apropos Weiterverarbeitung – in vielen Druckbetrieben fristet sie in Sachen Prozessoptimierung immer noch ein Schattendasein. Dabei liegen hier mittlerweile die größten Einsparpotenziale! In einem Webinar von Horizon und Impressed erfahren Sie, wie Sie diese Einsparungen realisieren können. Horizon, bekannt für innovative Lösungen in der Druckweiterverarbeitung, bietet mit iCE LiNK eine Workflowlösung für die Weiterverarbeitung. iCE LiNK überwacht, visualisiert und analysiert Produktionsabläufe und unterstützt bei der Wartung – damit immer alles reibungslos läuft. Den gleichen Anspruch hat der von Impressed entwickelte Impressed Workflow Server – er ist die smarte PDF-Workflow-Lösung für Druckereien, die Datenmanagement, Preflight und Produktionssteuerung übernimmt. Im Webinar zeigen Ihnen die Experten von Horizon und Impressed, wie beide Lösungen im Team die Effizienz und Produktivität Ihres Betriebes steigern können. Melden Sie sich am besten gleich an, wir freuen uns auf Sie! PS: Melden Sie sich in jedem Fall an – sollten Sie zum Termin verhindert sein, erhalten Sie die Aufzeichnung.

kostenlos

Organisator: Impressed / Horizon

https://www.impressed.de/schulung.php?c=sDetail&sid=327

Einsparpotenziale in der Weiterverarbeitung

Veranstaltungen

16.05.2024

Und es geht doch: Automatisierung im Großformatdruck!

Online
Donnerstag, 16. Mai 2024, 10.00 - 10.30 Uhr

Webinar

Komplizierte, kleinteilige Aufträge; alles sehr speziell; seit Jahren bewährte Prozesse – da können wir nichts standardisieren und automatisieren! Das sagen viele Großformatdrucker – aber stimmt das wirklich, ist dem tatsächlich so? Günther Business Solutions und Impressed treten in einem Webinar den Gegenbeweis an. Experten beider Unternehmen zeigen, wie Großformatdrucker vom Einsatz zweier bewährter Lösungen profitieren können: • von advanter print+sign von Günther Business Solutions, dem ERP-System für den Großformatdruck, dass alle Phasen der Wertschöpfung im Large Format Printing abdeckt • von Impressed Workflow Server, der smarten PDF-Workflow-Lösung für Druckereien, die Datenmanagement, Preflight und Produktionssteuerung übernimmt Über die Kombination beider Lösungen können Großformatdrucker ihre Prozesse mit modernen Workflows Schritt für Schritt automatisieren – und so zügig deutliche Zeit- und Kosteneinsparungen realisieren. Das Webinar sollten Sie sich nicht entgehen lassen – damit Sie keine Effizienzpotenziale mehr liegen lassen. Melden Sie sich am besten gleich an, wir freuen uns auf Sie! PS: Melden Sie sich in jedem Fall an – sollten Sie zum Termin verhindert sein, erhalten Sie die Aufzeichnung.

kostenlos

Nein

Organisator: Impressed / Günther Business Solutions

https://www.impressed.de/schulung.php?c=sDetail&sid=326

Und es geht doch: Automatisierung im Großformatdruck!

Weitere Events

Neuste Foreneinträge

Datum aktualisiert auf allen Seiten

Bitte um Unterstützung bei FindChang....

"Wendebuch": Wie komplette Datei um 180° drehen?

Rechtschreibprüfung

Katalog-Gestaltung: Elemente am Bund spiegeln und platzieren mittels Indesign oder -EasyCatalog

PDF | Barrierefrei | Bilder werden nicht erkannt

Problem mit RGB> CMYK in Vektor-Smartobjekt

Adobes Konvertierungsdienst per Script aufrufen

Mit Preflight Registerfarbe ALL nach Grau konvertieren geht nicht

Switch/PitStop: Sprachdatei vom Report ändern

Weitere Stellenangebote