(* 
NamenKuerzen_01d 
Die Namen von gedroppten PDF-Dateien auf fünf Zeichen kürzen. 
© 19.04.2011  /  Hans Häsler, Châtelard 52, CH-1018 Lausanne  /  E-mail: hsa@ringier.ch 
*) 
 
-- auf wieviele Zeichen sollen die Dateinamen reduziert werden  
property charNo : 5 
 
-- das Suffix der zu ändernden Dateien  
property fileSuffix : ".pdf" 
 
global ctr 
 
-- einen Dialog zeigen, falls der Anwender einen Doppelklick auf das Droplet macht 
on run 
  display dialog "Dateien und Ordner auf dem Icon 
dieses Droplets deponieren." buttons "OK" default button 1 with icon 0 
end run 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert 
on open allObjects 
  set ctr to 0 
  -- Wiederholschleife, welche alle gedroppten Objekte zum Handler 'processObject' schickt 
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  -- den Anwender über das Ergbenis der Aktion informieren 
  if ctr is 0 then 
    display dialog "Fertig." & return & return & "Alle PDF-Datei-Namen wurden gekürzt." buttons ¬ 
      "OK" default button 1 with icon 1 
  else if ctr is 1 then 
    display dialog "Fertig." & return & return & "Ein PDF-Datei-Name nicht gekürzt." buttons ¬ 
      "OK" default button 1 with icon 2 
  else 
    display dialog "Fertig." & return & return & ctr & " PDF-Datei-Namen nicht gekürzt." buttons ¬ 
      "OK" default button 1 with icon 2 
  end if 
end open 
 
-- im folgenden Handler wird festgestellt, ob das Objekt ein Ordner oder eine Datei ist. 
-- Bei Ordnern wird eine Liste des Inhalts erstellt und die Elemente rekursiv behandelt  
-- (d.h. zum aktuellen Handler geschickt) 
-- Dateien werden zum Handler 'processFile' gesandt 
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner 
  if (aObject as string) ends with ":" then 
    -- die Liste des Inhalts wird erstellt (ohne unsichtbare Dateien)  
    set contentsList to list folder aObject without invisibles 
    -- der Finder öffnet den Ordner, damit man sieht, dass etwas geschieht 
    tell application "Finder" to open folder aObject 
     
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte zum Handler,  
    -- in welchem sie sich selbst befindet  
    repeat with anItem in contentsList 
      set objPath to ((aObject as Unicode text) & anItem) 
      processObject(objPath as alias) 
    end repeat 
    -- der Finder schliesst den Ordner (dieses Öffnen/Schliessen zeigt  
    -- dem Anwender, was gerade geschieht) 
    tell application "Finder" to close window of folder aObject 
     
    -- wenn das Objekt eine Datei ist, dann wird der Pfad dem Handler 'processFile' übergeben 
  else 
    processFile(aObject as Unicode text) 
  end if 
end processObject 
 
-- in diesem Handler wird der Name der Datei festgestellt und gekürzt; dann wird die Datei umbenannt 
on processFile(aFile) 
  -- den Namen der Datei speichern 
  tell application "Finder" to set curName to name of file aFile 
  -- wenn es eine PDF-Datei ist 
  if curName ends with fileSuffix then 
    -- den Ordner-Pfad speichern 
    tell application "Finder" to set folderPath to (container of file aFile) as Unicode text 
    -- wenn der Name länger als 9 Zeichen ist 
    if (count of curName) is greater than 9 then 
      -- den neuen Namen zusammensetzen (5 Zeichen plus ".pdf") 
      set newName to text 1 thru 5 of curName & fileSuffix 
      set newFile to (folderPath & newName) as string 
      try 
        -- prüfen, ob die Datei existiert 
        alias newFile 
        -- den Zählerwert erhöhen 
        set ctr to ctr + 1 
        -- die Log-Datei ergänzen 
        writeFile(aFile) 
      on error 
        -- versuchen, die Datei umzubenennen 
        try 
          tell application "Finder" to set name of file aFile to newName 
        end try 
      end try 
    end if 
  end if 
end processFile 
 
-- in die Log-Datei schreiben  
on writeFile(aFile) 
  -- wo soll das Log gesichert werden, das nicht geänderte Dateien protokolliert  
  set logPath to (path to desktop folder as string) & "Log.txt" 
  try 
    set logFile to open for access file logPath with write permission 
    write (aFile & return) to logFile starting at eof 
    close access logFile 
  on error 
    try 
      close access logFile 
    end try 
  end try 
end writeFile