property msgSubject : "Korrekturlesen" 
property msgBody : "Hallo!" 
property msgSender : "Absender <abc@def.de>" 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert  
on open allObjects 
  -- Wiederholschleife, welche alle gedroppten Objekte zum Handler 'processObject' schickt   
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 2 
end open 
 
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner   
  if (aObject as Unicode text) ends with ":" then 
    -- ein Ordner wird geöffnet, damit man sieht, dass etwas geschieht  
    tell application "Finder" to open folder aObject 
    -- die Liste der Objekte wird erstellt (ohne unsichtbare Dateien)   
    set contentsList to list folder aObject without invisibles 
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte   
    -- zum Handler, in welchem sie sich selbst befindet   
    repeat with anItem in contentsList 
      set objPath to ((aObject as Unicode text) & anItem) 
      processObject(objPath as alias) 
    end repeat 
    -- den Ordner wieder schliessen  
    tell application "Finder" to close folder aObject 
  else 
    processFile(aObject) 
  end if 
end processObject 
 
-- in diesem Handler wird die aktuelle Datei behandelt   
on processFile(aObject) 
  set filePath to aObject as Unicode text 
  -- das Suffix prüfen ...  
  if filePath ends with ".pdf" then 
    -- wenn ".pdf" mit "Skim" den Text ausziehen 
    tell application "Skim" 
      open filePath 
      set allText to (get text for document 1) as text 
      close document 1 
    end tell 
    -- die E-Mail-Adresse ausziehen 
    try 
      set msgAddress to find text "(<e-mail>)(.*)(<e-mail>)" in allText using "\\2" with regexp and string result 
    on error 
      return 
    end try 
    -- die Meldung vorbereiten und senden 
    tell application "Mail" 
      set newMessage to make new outgoing message with properties ¬ 
        {subject:msgSubject, content:msgBody & return & return} 
      tell newMessage 
        set visible to true 
        set sender to msgSender 
        make new to recipient at end of to recipients with properties {address:msgAddress} 
        tell content 
          make new attachment with properties {file name:filePath as alias} at after the last paragraph 
        end tell 
      end tell 
      activate 
      try 
        save newMessage 
        send newMessage 
      end try 
    end tell 
  end if 
end processFile 

property msgSubject : "Korrekturlesen" 
property msgBody : "Hallo!" 
property msgSender : "Absender <abc@def.de>" 
 
on adding folder items to sourceFolder after receiving itemList 
  repeat with aFile in itemList 
    set filePath to aFile as string 
    -- das Suffix prüfen ...  
    if (filePath ends with ".pdf") then 
      processFile(filePath) 
    end if 
  end repeat 
end adding folder items to 
 
-- in diesem Handler wird die aktuelle Datei behandelt   
on processFile(filePath) 
  -- mit "Skim" den Text ausziehen 
  tell application "Skim" 
    open filePath 
    set allText to (get text for document 1) as text 
    close document 1 
  end tell 
  -- die E-Mail-Adresse ausziehen 
  try 
    set msgAddress to find text "(<e-mail>)(.*)(<e-mail>)" in allText using "\\2" with regexp and string result 
  on error 
    return 
  end try 
  -- die Meldung vorbereiten und senden 
  tell application "Mail" 
    set newMessage to make new outgoing message with properties ¬ 
      {subject:msgSubject, content:msgBody & return & return} 
    tell newMessage 
      set visible to true 
      set sender to msgSender 
      make new to recipient at end of to recipients with properties {address:msgAddress} 
      tell content 
        make new attachment with properties {file name:filePath as alias} at after the last paragraph 
      end tell 
    end tell 
    activate 
    try 
      save newMessage 
      send newMessage 
    end try 
  end tell 
end processFile 

<a href="http://www.hilfdirselbst.ch" target="_blank">http://www.hilfdirselbst.ch</a> 

property msgSender : "Absender <abc@def.de>" 

property msgBody : "Und hier ist der Link: http://www.hilfdirselbst.ch" 

property msgSender : "Mein Name <buchkorrektur@kunde.de>" 

property msgSender : "Mein Name <buchkorrektur@kunde.de>" 

display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 2 

property msgSubject : "Korrekturlesen" 
property msgBody : "Hallo!" 
property msgSender : "Absender <abc@def.de>" 
property msgBccAddress : "Empfängerin <uvw@xyz.de>" 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert   
on open allObjects 
  -- Wiederholschleife, welche alle gedroppten Objekte zum Handler 'processObject' schickt    
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  activate me 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 2 
end open 
 
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner    
  if (aObject as Unicode text) ends with ":" then 
    -- ein Ordner wird geöffnet, damit man sieht, dass etwas geschieht   
    tell application "Finder" to open folder aObject 
    -- die Liste der Objekte wird erstellt (ohne unsichtbare Dateien)    
    set contentsList to list folder aObject without invisibles 
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte    
    -- zum Handler, in welchem sie sich selbst befindet    
    repeat with anItem in contentsList 
      set objPath to ((aObject as Unicode text) & anItem) 
      processObject(objPath as alias) 
    end repeat 
    -- den Ordner wieder schliessen   
    tell application "Finder" to close folder aObject 
  else 
    processFile(aObject) 
  end if 
end processObject 
 
-- in diesem Handler wird die aktuelle Datei behandelt    
on processFile(aObject) 
  set filePath to aObject as Unicode text 
  -- das Suffix prüfen ...   
  if filePath ends with ".pdf" then 
    -- wenn ".pdf" mit "Skim" den Text ausziehen  
    tell application "Skim" 
      open filePath 
      set allText to (get text for document 1) as text 
      close document 1 
    end tell 
    -- die E-Mail-Adresse ausziehen  
    try 
      set msgAddress to find text "(<e-mail>)(.*)(<e-mail>)" in allText using "\\2" with regexp and string result 
    on error 
      return 
    end try 
    -- die Meldung vorbereiten und senden  
    tell application "Mail" 
      set newMessage to make new outgoing message with properties ¬ 
        {subject:msgSubject, content:msgBody & return & return} 
      tell newMessage 
        set visible to true 
        set sender to msgSender 
        make new to recipient at end of to recipients with properties {address:msgAddress} 
        make new bcc recipient at end of bcc recipients with properties {address:msgBccAddress} 
        tell content 
          make new attachment with properties {file name:filePath as alias} at after the last paragraph 
        end tell 
      end tell 
      activate 
      try 
        send newMessage 
      end try 
    end tell 
  end if 
end processFile 

property msgSubject : "Korrekturlesen" 
property msgBody : "Hallo!" 
property msgSender : "Absender <abc@def.de>" 
property msgAddress2 : "Empfängerin <uvw@xyz.de>" 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert   
on open allObjects 
  -- Wiederholschleife, welche alle gedroppten Objekte zum Handler 'processObject' schickt    
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  activate me 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 2 
end open 
 
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner    
  if (aObject as Unicode text) ends with ":" then 
    -- ein Ordner wird geöffnet, damit man sieht, dass etwas geschieht   
    tell application "Finder" to open folder aObject 
    -- die Liste der Objekte wird erstellt (ohne unsichtbare Dateien)    
    set contentsList to list folder aObject without invisibles 
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte    
    -- zum Handler, in welchem sie sich selbst befindet    
    repeat with anItem in contentsList 
      set objPath to ((aObject as Unicode text) & anItem) 
      processObject(objPath as alias) 
    end repeat 
    -- den Ordner wieder schliessen   
    tell application "Finder" to close folder aObject 
  else 
    processFile(aObject) 
  end if 
end processObject 
 
-- in diesem Handler wird die aktuelle Datei behandelt    
on processFile(aObject) 
  set filePath to aObject as Unicode text 
  -- das Suffix prüfen ...   
  if filePath ends with ".pdf" then 
    -- wenn ".pdf" mit "Skim" den Text ausziehen  
    tell application "Skim" 
      open filePath 
      set allText to (get text for document 1) as text 
      close document 1 
    end tell 
    -- die E-Mail-Adresse ausziehen  
    try 
      set msgAddress1 to find text "(<e-mail>)(.*)(<e-mail>)" in allText using "\\2" with regexp and string result 
    on error 
      return 
    end try 
    -- die Meldungen vorbereiten und senden  
    tell application "Mail" 
      -- erste Meldung 
      set newMessage1 to make new outgoing message with properties ¬ 
        {subject:msgSubject, content:msgBody & return & return} 
      tell newMessage1 
        set visible to true 
        set sender to msgSender 
        make new to recipient at end of to recipients with properties {address:msgAddress1} 
        tell content 
          make new attachment with properties {file name:filePath as alias} at after the last paragraph 
        end tell 
      end tell 
      activate 
      try 
        send newMessage1 
      end try 
      -- Kontroll-Meldung 
      set newMessage2 to make new outgoing message with properties ¬ 
        {subject:msgSubject, content:msgAddress1 & return} 
      tell newMessage2 
        set visible to true 
        set sender to msgSender 
        make new to recipient at end of to recipients with properties {address:msgAddress2} 
      end tell 
      activate 
      try 
        send newMessage2 
      end try 
    end tell 
  end if 
end processFile