-- reverse path 
-- die üblichen Vorsichtsregeln gelten: wenn was kaputt gehen sollte und es war keine Sicherungskopie angelegt, kann ich nichts dafür 
tell application "Adobe InDesign CS2" 
	set aDoc to active document 
	set allSel to selection 
	set nSels to count allSel 
	if nSels is 0 then 
		return 
	end if 
	 
	repeat with i from 1 to nSels 
		set aSel to item i in allSel 
		set npaths to count paths in aSel 
		repeat with j from 1 to npaths 
			set pList to entire path of path j of aSel 
			set nuList to {} 
			repeat with n from (count pList) to 1 by -1 
				set tempPt to item n of pList 
				-- Ein Eckpunkt hat 2 Elemente, die Koordinaten 
				-- Ein Kurvenpunkt hat 3 Elemente, die 3 Anfasser, a 2 Elemente 
				if (count tempPt) is 3 then 
					set sndTempPt to {item 3 of tempPt, item 2 of tempPt, item 1 of tempPt} 
					set tempPt to sndTempPt 
				end if 
				copy tempPt to end of nuList 
			end repeat 
			set entire path of path j of aSel to nuList 
		end repeat 
	end repeat 
end tell 

-- de-mirror text path  
-- die üblichen Vorsichtsregeln gelten: wenn was kaputt gehen sollte und es war keine Sicherungskopie angelegt, kann ich nichts dafür 
 
tell application "Adobe InDesign CS2" 
	set aDoc to active document 
	set allSel to selection 
	set nSels to count allSel 
	if nSels is 0 then 
		return 
	end if 
	 
	repeat with i from 1 to nSels 
		set aSel to item i in allSel 
		set npaths to count paths in aSel 
		repeat with j from 1 to npaths 
			set oldTPath to text path 1 of aSel 
			if class of text path 1 of aSel is text path then 
				set pList to entire path of path j of aSel 
				tell parent of aSel to set nuPol to make polygon 
				set path type of path 1 of nuPol to open path 
				set entire path of path 1 of nuPol to pList 
				tell nuPol to set nuTPath to make text path 
				set start bracket of nuTPath to start bracket of oldTPath 
				set end bracket of nuTPath to end bracket of oldTPath 
				set next text frame of oldTPath to nuTPath 
				set end bracket of oldTPath to start bracket of oldTPath 
			end if 
		end repeat 
	end repeat 
end tell