on open mgItems 
	 
	set targetFolderPath to (choose folder with prompt "Bitte Ordner für das Verpacken auswählen.") as string 
	 
	tell application id "com.adobe.InDesign" 
		 
		set my_pdf_export to get the name of every PDF export preset 
		set my_pdf_choice to (choose from list my_pdf_export) as string 
		 
	end tell 
	 
	repeat with mgThisItem in mgItems 
		 
		tell application id "com.adobe.InDesign" 
			 
			try 
				 
				open mgThisItem 
				 
				set mgDocName to name of active document 
				 
				set text item delimiters of AppleScript to ".indd" 
				 
				set mgShortName to text item 1 of mgDocName 
				 
				 
				-- set up folder and file references 
				 
				set mgPackageFilePath to targetFolderPath & mgShortName & ":" 
				set mgProofFilePath to mgPackageFilePath & "PDF:" & mgShortName & ".pdf" as string 
				 
				set text item delimiters of AppleScript to "" 
				 
				-- create dat folder, main folder and internal PDF folder; passing in POSIX path, though most everything ele uses HFS paths 
				 
				my createFolders(POSIX path of file (mgPackageFilePath & "PDF:")) 
				 
				set properties of PDF export preferences to properties of PDF export preset my_pdf_choice 
				 
				tell the active document to export format PDF type to mgProofFilePath without showing options 
				 
				tell the active document to export format InDesign markup to mgPackageFilePath & mgShortName & ".idml" 
				 
				tell the active document to package to mgPackageFilePath with copying fonts, ignore preflight errors, copying profiles, updating graphics, including hidden layers, copying linked graphics and creating report 
				 
				close active document saving no 
				 
			on error e 
				 
				display dialog e 
				 
			end try 
			 
		end tell 
		 
		-- delete the instructions file 
		 
		tell application "System Events" 
			 
			try 
				delete file (mgPackageFilePath & "Anleitungen") 
			end try 
			 
			try 
				delete file (mgPackageFilePath & "Anleitungen.txt") 
			end try 
			 
		end tell 
		 
	end repeat 
	 
	tell application id "com.adobe.InDesign" 
		 
		display dialog "PDFs sind erstellt und InDesign Dateien verpackt." 
		 
	end tell 
	 
end open 
 
 
 
on createFolders(pathString) 
	 
	do shell script "mkdir -p " & quoted form of pathString 
	 
end createFolders