-- die Variable 'logFolder' als 'property' definieren, damit der Pfad zum Logdatei-Ordner gespeichert wird 
property logFolder : "" 
-- zwei weitere Variablen als 'global' definieren, damit sie in den Handlern erkannt werden 
global logPath 
global tSecs 
 
on open allObjects 
  -- den gespeicherten Pfad des Logdatei-Ordners prüfen 
  try 
    alias logFolder 
  on error 
    set logFolder to (choose folder with prompt "Bitte den Logdatei-Ordner wählen.") as Unicode text 
  end try 
   
  -- das akuelle Datum speichern 
  set curDate to current date 
  -- davon Jahr, Monat, Tag, Stunde, Minuten, Sekunden ausziehen und zusammensetzen 
  set y to text -2 thru -1 of ((year of curDate) as string) 
  set m to text -2 thru -1 of ((month of curDate as number) as string) 
  set d to text -2 thru -1 of ((day of curDate) as string) 
  set hh to text -2 thru -1 of ("0" & (hours of curDate)) 
  set mm to text -2 thru -1 of ("0" & (minutes of curDate)) 
  set ss to text -2 thru -1 of ("0" & (seconds of curDate)) 
  set timeString to y & m & d & "_" & hh & mm & ss 
   
  -- den  Pfad zur Logdatei zusammensetzen 
  set logPath to logFolder & "Log_" & timeString & ".txt" 
   
  -- das Datum in eine Textkette verwandeln und ... 
  set dateString to (curDate as string) & return 
  -- ... als ersten Eintrag in die Logdatei schreiben 
  writeLog(dateString) 
   
  -- die Variable 'tSecs' initialisieren 
  set tSecs to 0 
   
  -- Wiederholungsschleife, welche alle gedroppten Objekte zum Handler 'processObject' schickt 
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
   
  -- das Total Sekunden ins Format "hh:mm:ss" umrechnen lassen 
  set timeString to convToTime(tSecs) 
  -- die aktuelle Textkette zusammensetzen 
  set aString to (return & return & "Total" & tab & timeString) as string 
  -- und zum Handler schicken, welcher damit die Logdatei ergänzt 
  writeLog(aString) 
   
  -- den Anwender informieren 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
end open 
 
-- im folgenden Handler wird festgestellt, ob das Objekt ein Ordner oder eine Datei ist 
-- bei Ordnern wird eine Liste des Inhalts erstellt und die Elemente rekursiv behandelt  
-- (d.h. zum aktuellen Handler geschickt) 
-- Dateien werden zum Handler 'processFile' gesandt 
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner 
  -- die Liste dessen Inhalts wird erstellt (ohne unsichtbare Dateien)  
  if (aObject as string) ends with ":" then 
    set contentsList to list folder aObject without invisibles 
    -- dies ist das rekursive Teil: die Wiederholschleife schickt alle Objekte zum Handler,  
    -- in welchem sie sich selbst befindet  
    repeat with anItem in contentsList 
      set objPath to ((aObject as string) & anItem) 
      processObject(objPath as alias) 
    end repeat 
    -- wenn das Objekt eine Datei ist, dann wird der Pfad dem Handler 'processFile' übergeben 
  else 
    set okay to processFile(aObject as string) 
  end if 
end processObject 
 
-- in diesem Handler werden die Details zusammengetragen 
on processFile(aFile) 
  -- die Infos der Datei werden gespeichert 
  set fileInfo to (info for file aFile) 
  -- der Name der Datei wird ausgezogen 
  set fileName to name of fileInfo 
  -- das Erstellungs- und das Änderungsdatum 
  set creDate to creation date of fileInfo 
  set modDate to modification date of fileInfo 
  -- daraus die Sekunden errechnen 
  set nSecs to modDate - creDate 
  -- das Ergebnis zum Total addieren 
  set tSecs to tSecs + nSecs 
  -- zum Handler schicken, welcher die Sekunden in "hh:mm:ss" verwandelt 
  set timeString to convToTime(nSecs) 
  -- die aktuelle Textkette zusammensetzen 
  set aString to (return & fileName & tab & timeString) as string 
  -- und zum Handler schicken, welcher damit die Logdatei ergänzt 
  writeLog(aString) 
end processFile 
 
on writeLog(aString) 
  try 
    open for access file logPath with write permission 
    write aString to file logPath starting at eof 
    close access file logPath 
  on error 
    try 
      close access file logPath 
    end try 
  end try 
end writeLog 
 
on convToTime(nSecs) 
  set hh to text -2 thru -1 of ("0" & (nSecs div 3600)) 
  set restSecs to nSecs mod 3600 
  set mm to text -2 thru -1 of ("0" & (restSecs div 60)) 
  set ss to text -2 thru -1 of ("0" & (restSecs mod 60)) 
  return hh & ":" & mm & ":" & ss 
end convToTime 

 property ctr : 0 
property logFolder : "" 
global logPath 
 
on open droppedObject 
  try 
    alias logFolder 
  on error 
    set logFolder to (choose folder with prompt "Bitte den Logdatei-Ordner wählen.") as Unicode text 
  end try 
  set filePath to item 1 of droppedObject as Unicode text 
  if not (filePath ends with ":") then 
    set ctr to ctr + 1 
    set docName to name of (info for file filePath) as string 
    set logFile to logFolder & "Zeiterfassung.txt" 
    if ctr mod 2 is 1 then 
      try 
        tell application "Finder" to open file filePath 
      on error 
        display dialog "Diese Datei kann nicht geöffnet werden." buttons "OK" default button 1 with icon 2 
        set ctr to ctr - 1 
        error number -128 
      end try 
    end if 
    set curDate to current date 
    try 
      alias logFile 
      set curString to readCur(logFile) 
      set nPara to count of paragraphs of curString 
      if nPara = 3 then 
        writeEnd(logFile, curString, curDate) 
        display dialog "Der Eintrag ist gemacht." buttons ¬ 
          "OK" default button 1 with icon 1 giving up after 1 
      else if nPara is greater than 5 then 
        if ctr mod 2 is 1 then 
          writeBegin(logFile, curDate, docName) 
        else 
          writeEnd(logFile, curString, curDate) 
          display dialog "Der Eintrag ist gemacht." buttons ¬ 
            "OK" default button 1 with icon 1 giving up after 1 
        end if 
      end if 
    on error 
      writeBegin(logFile, curDate, docName) 
    end try 
  end if 
end open 
 
on readCur(logFile) 
  set curString to read file logFile 
  return curString 
end readCur 
 
on writeBegin(logFile, curDate, docName) 
  set aString to docName & return & "Beginn: " & curDate & return 
  try 
    open for access file logFile with write permission 
    write aString to file logFile starting at eof 
    close access file logFile 
  on error 
    try 
      close access file logFile 
    end try 
  end try 
end writeBegin 
 
on writeEnd(logFile, curString, curDate) 
  set oldTime to date (text 9 thru -1 of paragraph -2 of curString) 
  if oldTime > curDate then set oldTime to oldTime - 12 * hours 
  set nSecs to curDate - oldTime 
  set difTime to convToTime(nSecs) 
  set newString to "Ende:   " & curDate & return & "Dauer:  " & difTime & return & return 
  try 
    open for access file logFile with write permission 
    write newString to file logFile starting at eof 
    close access file logFile 
  on error 
    try 
      close access file logFile 
    end try 
  end try 
end writeEnd 
 
on convToSecs(nSecs, timeStr) 
  set AppleScript's text item delimiters to {":"} 
  set nSecs to nSecs + ((text item 1 of timeStr) as integer) * 3600 
  set nSecs to nSecs + ((text item 2 of timeStr) as integer) * 60 
  set nSecs to nSecs + ((text item 3 of timeStr) as integer) 
  set AppleScript's text item delimiters to {""} 
  return nSecs 
end convToSecs 
 
on convToTime(nSecs) 
  set difH to text -2 thru -1 of ("0" & (nSecs div 3600)) 
  set restSecs to nSecs mod 3600 
  set difM to text -2 thru -1 of ("0" & (restSecs div 60)) 
  set difS to text -2 thru -1 of ("0" & (restSecs mod 60)) 
  return difH & ":" & difM & ":" & difS 
end convToTime 

 property ctr : 0 
property logFolder : "" 
global logPath 
 
on open droppedObject 
 try 
  alias logFolder 
 on error 
  set logFolder to (choose folder with prompt "Bitte den Logdatei-Ordner wählen.") as Unicode text 
 end try 
 set filePath to item 1 of droppedObject as Unicode text 
 if not (filePath ends with ":") then 
  set ctr to ctr + 1 
  set docName to name of (info for file filePath) as string 
  set logFile to logFolder & " Zeiterfassung.txt" 
  if ctr mod 2 is 1 then 
   try 
    tell application "Finder" to open file filePath 
   on error 
    display dialog "Diese Datei kann nicht geöffnet werden." buttons "OK" default button 1 with icon 2 
    set ctr to ctr - 1 
    error number -128 
   end try 
  end if 
  set curDate to current date 
  try 
   alias logFile 
   set curString to readCur(logFile) 
   set nPara to count of paragraphs of curString 
   if nPara = 3 then 
    writeEnd(logFile, curString, curDate) 
    display dialog "Der Eintrag ist gemacht." buttons ¬ 
     "OK" default button 1 with icon 1 giving up after 1 
   else if nPara = 6 then 
    writeBegin1(logFile, curDate, docName) 
   else if nPara = 8 then 
    writeEnd(logFile, curString, curDate) 
    set curString to readCur(logFile) 
    writeTotal(logFile, curString) 
    display dialog "Der Eintrag ist gemacht." buttons ¬ 
     "OK" default button 1 with icon 1 giving up after 1 
   else if nPara > 8 then 
    if ctr mod 2 is 1 then 
     writeBegin2(logFile, curString, curDate, docName) 
    else 
     writeEnd(logFile, curString, curDate) 
     set curString to readCur(logFile) 
     writeTotal(logFile, curString) 
     display dialog "Der Eintrag ist gemacht." buttons ¬ 
      "OK" default button 1 with icon 1 giving up after 1 
    end if 
   end if 
  on error 
   writeBegin1(logFile, curDate, docName) 
  end try 
 end if 
end open 
 
on readCur(logFile) 
 set curString to read file logFile 
 return curString 
end readCur 
 
on writeBegin1(logFile, curDate, docName) 
 set aString to docName & return & "Beginn: " & curDate & return 
 try 
  open for access file logFile with write permission 
  write aString to file logFile starting at eof 
  close access file logFile 
 on error 
  try 
   close access file logFile 
  end try 
 end try 
 tell application "Finder" to set label index of file logFile to 6 
end writeBegin1 
 
on writeBegin2(logFile, curString, curDate, docName) 
 set aString to text 1 thru -17 of curString as string 
 set newString to aString & docName & return & "Beginn: " & curDate & return 
 try 
  open for access file logFile with write permission 
  set eof of file logFile to 0 
  write newString to file logFile starting at eof 
  close access file logFile 
 on error 
  try 
   close access file logFile 
  end try 
 end try 
 tell application "Finder" to set label index of file logFile to 6 
end writeBegin2 
 
on writeEnd(logFile, curString, curDate) 
 set oldTime to date (text 9 thru -1 of paragraph -2 of curString) 
 if oldTime > curDate then set oldTime to oldTime - 12 * hours 
 set nSecs to curDate - oldTime 
 set difTime to convToTime(nSecs) 
 set newString to "Ende:   " & curDate & return & "Dauer:  " & difTime & return & return 
 try 
  open for access file logFile with write permission 
  write newString to file logFile starting at eof 
  close access file logFile 
 on error 
  try 
   close access file logFile 
  end try 
 end try 
 tell application "Finder" to set label index of file logFile to 2 
end writeEnd 
 
on writeTotal(logFile, curString) 
 set nPara to count of paragraphs of curString 
 set nSecs to 0 
 repeat with i from 4 to nPara by 5 
  set timeStr to (text 9 thru -1 of paragraph i of curString) 
  set nSecs to convToSecs(nSecs, timeStr) 
 end repeat 
 set totTime to convToTime(nSecs) 
 set newString to "Total:  " & totTime 
 try 
  open for access file logFile with write permission 
  write newString to file logFile starting at eof 
  close access file logFile 
 on error 
  try 
   close access file logFile 
  end try 
 end try 
end writeTotal 
 
on convToSecs(nSecs, timeStr) 
 set AppleScript's text item delimiters to {":"} 
 set nSecs to nSecs + ((text item 1 of timeStr) as integer) * 3600 
 set nSecs to nSecs + ((text item 2 of timeStr) as integer) * 60 
 set nSecs to nSecs + ((text item 3 of timeStr) as integer) 
 set AppleScript's text item delimiters to {""} 
 return nSecs 
end convToSecs 
 
on convToTime(nSecs) 
 set difH to text -2 thru -1 of ("0" & (nSecs div 3600)) 
 set restSecs to nSecs mod 3600 
 set difM to text -2 thru -1 of ("0" & (restSecs div 60)) 
 set difS to text -2 thru -1 of ("0" & (restSecs mod 60)) 
 return difH & ":" & difM & ":" & difS 
end convToTime