-- PlaylistCreator_03d.app 
-- Basiert auf "Playlist Creator v1.0" von Paul Withey 
-- http://www.malcolmadams.com/itunes/ 
 
(*  
Das Original-Script setzt die Dateien aller Unterordner in eine Wiedergabeliste 
 
Der folgende Code wirkt auch so. Aber wenn eine Auswahl von Ordnern  
gedroppt wird, dann erzeugt er von jedem Ordner eine Wiedergabeliste.  
*) 
 
global curTracks 
 
on open allObjects 
 set noDetails to true 
 set userChoice to button returned of (display dialog ¬ 
  "Die Wiedergabelisten ohne Nachfrage erzeugen?" buttons ¬ 
  {" Abbrechen ", "Titel-Listen zeigen", "Alle erzeugen"} default button 3) 
 if userChoice is "Titel-Listen zeigen" then 
  set noDetails to false 
 else if userChoice is " Abbrechen " then 
  error number -128 
 end if 
 repeat with aObject in allObjects 
  processObject(aObject, noDetails) 
 end repeat 
 display dialog "Fertig." buttons ¬ 
  "OK" default button 1 with icon 1 giving up after 1 
end open 
 
on processObject(aObject, noDetails) 
 set allTracks to {} 
 if (aObject as string) ends with ":" then 
  tell application "Finder" 
   set playlistName to name of aObject 
   set allTracks to every file in aObject 
  end tell 
  if allTracks is {} then 
   set curTracks to {} 
   set nameList to {} 
   set nameList to addMulti(aObject, curTracks, nameList) 
  else 
   set nameList to addTrack(allTracks) 
  end if 
  if nameList is not {} then 
   makeList(playlistName, nameList, noDetails) 
  end if 
 end if 
end processObject 
 
on addMulti(aObject, curTracks, nameList) 
 tell application "Finder" to set allTracks to every file in aObject 
 if allTracks is not {} then 
  repeat with nextTrack in allTracks 
   set trackName to name of nextTrack 
   if trackName ends with ".mp3" then 
    set trackName to text 1 thru -5 of trackName 
    set end of nameList to trackName 
    set nextTrack to nextTrack as alias 
    set end of curTracks to nextTrack 
   end if 
  end repeat 
 end if 
 tell application "Finder" to set allFolders to every folder in aObject 
 if allFolders is not {} then 
  repeat with nextFolder in allFolders 
   addMulti(nextFolder, curTracks, nameList) 
  end repeat 
 end if 
 return nameList 
end addMulti 
 
on addTrack(allTracks) 
 set curTracks to {} 
 set nameList to {} 
 repeat with nextTrack in allTracks 
  set trackName to name of nextTrack 
  if trackName ends with ".mp3" then 
   set trackName to text 1 thru -5 of trackName 
   set end of nameList to trackName 
   set nextTrack to nextTrack as alias 
   set end of curTracks to nextTrack 
  end if 
 end repeat 
 return nameList 
end addTrack 
 
on makeList(playlistName, nameList, noDetails) 
 if noDetails then 
  set userChoice to "Erzeugen" 
 else 
  activate me 
  set userChoice to button returned of (display dialog ¬ 
   "Die Wiedergabeliste »" & playlistName & "« wird erzeugt" buttons ¬ 
   {" Abbrechen ", "Titel zeigen", "Erzeugen"} default button 3) 
  if userChoice = "Titel zeigen" then 
   set curChoice to choose from list nameList with prompt ¬ 
    "Die Wiedergabeliste wird enthalten" OK button name ¬ 
    "Erzeugen" with empty selection allowed 
   if curChoice as string is not "false" then 
    set userChoice to "Erzeugen" 
   end if 
  else if userChoice is " Abbrechen " then 
   error number -128 
  end if 
 end if 
 if userChoice = "Erzeugen" then 
  tell application "iTunes" 
   set newPlaylist to make new user playlist 
   set name of newPlaylist to playlistName as string 
   add curTracks to newPlaylist 
  end tell 
 end if 
end makeList