Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

[Gast] Foren Programme Print/Bildbearbeitung Adobe InDesign Skriptwerkstatt Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Print/Bildbearbeitung - Photos, Layout, Design

Themen

Beiträge

Moderatoren

Letzter Beitrag

Adobe InDesign Skriptwerkstatt

2492

18050

Gerald Singelmann, Hans Haesler, Martin Fischer

9. Apr 2024, 08:56

typecookie

Wortsalat

Beiträge gesamt: 87

7. Dez 2017, 14:17
Beitrag # 1 von 20
Bewertung:
(7734 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo zusammen,
ich stehe gerade bei einem Script auf dem Schlauch und komme nicht weiter.

Innerhalb eines InDesign-Dokumentes sind mehrere InDesign Dateien als modulare Texte eingebunden. Da es diese Texte auf Deutsch und Englisch gibt, hat jede eingebundene Datei die Ebenen "DE" und "EN". Natürlich ist immer nur eine von den beiden Ebenen sichtbar.

Mit einem Script möchte ich jetzt die Sichtbarkeit dieser Ebenen umschalten. Also von Deutsch nach Englisch und entgegengesetzt. So zu sagen hin und her toggeln.

Bei meinem Script funktioniert das Einblenden der nicht sichtbaren Ebenen und auch das Ausblenden der sichtbaren. Allerdings nur, wenn ich nur eine Sache von beiden im Script aktiviere und die andere auskommentiere. Sind beide aktiv kommt es immer zu einem Fehler "Fehlernummer 30476 - Die angeforderte Aktion konnte nicht ausgeführt werden, da das Objekt nicht mehr existiert" Zeile 57.

Und genau hier komme ich nicht weiter.
Für Tipps und Hilfe bin ich sehr dankbar.

Grüße
Marcel

Hier das Script:

Code

Set myInDesign = CreateObject("InDesign.Application.cs6") 
Set myDocument = myInDesign.ActiveDocument 
 
Layer_DE = false 
Layer_EN = false 
 
REDIM e(1) 
 
 
Set Seiten = myDocument.pages 
For i = 1 to Seiten.count				'Seiten durchlaufen 
	Set Seite = Seiten(i)				'Seite i im Dokument 
 
	Set Dateien = Seite.allGraphics		'Alle eingebundenen Dateien der Datei	 
 
	For j = 1 to Dateien.count		'Eingebundene Dateien durchlaufen 
 
		Set Datei = Dateien(j) 
 
		Ebene_DE = false 
		Ebene_EN = false 
		 
		Set Ebenen = Datei.graphicLayerOptions.graphicLayers 
 
		for k = 1 to Ebenen.count 
			 
			'----- Prüfen, ob Ebenen vorhanden sind ------- 
 
			if Ebenen.item(k).Name = "DE" then		'DE vorhanden	 
				Ebene_DE = true 
			end if	 
			if Ebenen.item(k).Name = "EN" then		'EN vorhanden 
				Ebene_EN = true		 
			end if	 
			 
 
			'------------- Toggle Ebenen DE und EN --------------------- 
			 
 
			if (Ebene_DE = true) AND (Ebene_EN = true) then 
 
				if ebenen.Item("DE").CurrentVisibility = false then 
					e(0) = "DE" 
					e(1) = "EN" 
				end if	 
 
				if ebenen.Item("EN").CurrentVisibility = false then 
					e(0) = "EN"		'Ebene, die eingeblendet werden soll 
					e(1) = "DE"		'Ebene, die ausgeblendet werden soll 
				end if	 
			end if 
		 
		Next	'ENDE Ebenen durchlaufen 
 
			ebenen.Item(e(0)).CurrentVisibility = true 
			ebenen.Item(e(1)).CurrentVisibility = false 
	 
	Next		'ENDE Dateien durchlaufen 
Next			'ENDE Seiten durchlaufen

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Henry

Beiträge gesamt: 967

7. Dez 2017, 18:16
Beitrag # 2 von 20
Beitrag ID: #561297
Bewertung:
(7706 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hab es mir nur grob(!) angesehen.
1.) Die "k"-Schleife muss doch sicherlich VOR dem Toggeln beendet sein/werden?!
2.) Das Toggeln würde ich mittels des Not-Operators lösen, der schaltet von True auf False und umgekehrt.

Code

Set myInDesign = CreateObject("InDesign.Application.cs6")  
Set myDocument = myInDesign.ActiveDocument  
  
Layer_DE = false  
Layer_EN = false  
  
Set Seiten = myDocument.pages  
For i = 1 to Seiten.count				'Seiten durchlaufen  
	Set Seite = Seiten(i)				'Seite i im Dokument  
  
	Set Dateien = Seite.allGraphics		'Alle eingebundenen Dateien der Datei	  
  
	For j = 1 to Dateien.count		'Eingebundene Dateien durchlaufen  
  
		Set Datei = Dateien(j)  
  
		Ebene_DE = false  
		Ebene_EN = false  
		  
		Set Ebenen = Datei.graphicLayerOptions.graphicLayers  
 
		for k = 1 to Ebenen.count  
			'----- Prüfen, ob Ebenen vorhanden sind -------  
			if Ebenen.item(k).Name = "DE" then		'DE vorhanden	  
				Ebene_DE = true  
			end if	  
			if Ebenen.item(k).Name = "EN" then		'EN vorhanden  
				Ebene_EN = true		  
			end if	  
		Next k 
 
		'------------- Toggle Ebenen DE und EN ---------------------  
		if (Ebene_DE = true) AND (Ebene_EN = true) then  
			ebenen.Item("DE").CurrentVisibility = Not(ebenen.Item("DE").CurrentVisibility) 
			ebenen.Item("EN").CurrentVisibility = Not(ebenen.Item("EN").CurrentVisibility) 
		end if			 
 
	Next j		'ENDE Dateien durchlaufen  
Next i			'ENDE Seiten durchlaufen

als Antwort auf: [#561295]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

7. Dez 2017, 21:05
Beitrag # 3 von 20
Beitrag ID: #561302
Bewertung:
(7676 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Henry,

danke für die Hilfe.
Nicht schlecht die Idee mit dem Not-Operator.
Macht es auch etwas kürzer.
Allerdings läuft das Script genau so weit wie meins.

In dem Testdokument habe ich drei InDesign Dateien mit den "DE" und "EN" Ebenen eingebunden.

Beim Test sind die "DE" Ebenen sichtbar. Beim Ausführen des Scripts wird bei der Ersten Datei die "DE" Ebene ausgeblendet und dann kommt der Fehler "... da das Objekt nicht mehr existiert" Zeile 38.

Das ist dann in Deinem Script hier:

Code

ebenen.Item("EN").CurrentVisibility = Not(ebenen.Item("EN").CurrentVisibility)

und bei mir ist das hier:

Code

ebenen.Item(e(1)).CurrentVisibility = false

Der Fehler kommt, wenn innerhalb einer Datei die Sichtbarkeit der nächste Ebene umgeschaltet werden soll. Ich frage mich, welches Objekt in dem Moment nicht mehr existiert.
Die Ebene ist ja noch da.

als Antwort auf: [#561297]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

8. Dez 2017, 09:25
Beitrag # 4 von 20
Beitrag ID: #561313
Bewertung:
(7625 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Kurzer Zwischenstand,
ich bin etwas weiter.

Durch rumtesten ist mir aufgefallen, dass das Script nur mit der letzten (untersten) Ebene einer eingebundenen Datei funktioniert.

Die Ebene "DE" befindet sich unterhalb der Ebene "EN".
DE geht, EN gibt den Fehler. Befinden sich oberhalb DE weitere Ebenen, so erscheint der Fehler sobald eine dieser Ebenen umgeschaltet werden sollen.

als Antwort auf: [#561302]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Henry

Beiträge gesamt: 967

8. Dez 2017, 09:26
Beitrag # 5 von 20
Beitrag ID: #561314
Bewertung:
(7625 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Mmmh, da bin ICH als Nicht-Experte überfragt.

Du kannst dir Variablenwerte mit der MsgBox-Funktion ausgeben lassen, also z.B. eine solche Zeile hier einfügen:

Code

		'------------- Toggle Ebenen DE und EN ---------------------   
		if (Ebene_DE = true) AND (Ebene_EN = true) then   
MsgBox "Ebene DE visible? " & ebenen.Item("DE").CurrentVisibility & VbCr & "Ebene EN visible? " & ebenen.Item("EN").CurrentVisibility 
			ebenen.Item("DE").CurrentVisibility = Not(ebenen.Item("DE").CurrentVisibility)  
			ebenen.Item("EN").CurrentVisibility = Not(ebenen.Item("EN").CurrentVisibility)  
		end if

als Antwort auf: [#561302]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

8. Dez 2017, 09:53
Beitrag # 6 von 20
Beitrag ID: #561315
Bewertung:
(7615 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Das habe ich bereits an allen möglichen Stellen gemacht.
Ansprechen kann man die anderen (oberen) Ebenen immer und alle möglichen Informationen abrufen/ausgeben.
Nur bei .CurrentVisibility geht es schief.

...

als Antwort auf: [#561314]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

pixxxelschubser

Beiträge gesamt: 1708

8. Dez 2017, 10:52
Beitrag # 7 von 20
Beitrag ID: #561317
Bewertung:
(7597 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo zusammen,
mit InDesign-Scripting habe ich mich schon lange nicht mehr beschäftigt. Und die VBS-Syntax beherrsche ich auch nicht.

Wenn ich allerdings von der Javascript-Syntax in Illustrator ausgehe, dann sollte doch eine Vorgehensweise in der folgenden Art zielführend sein:

stelle eine definierte Ausgangslage her
Prüfe ob Layer DE existiert
schalte Layer DE sichtbar
Prüfe ob Layer EN existiert
schalte Layer EN sichtbar

wähle den Layer der sichtbar bleiben soll
schalte den Layer (nochmals) sichtbar
schalte den anderen Layer unsichtbar

Der nachfolgende [JS] Code ist zwar für Illustrator aber vielleicht könnt ihr den selbst portieren.

Code

var aDoc = app.activeDocument; 
// prüfe ob Layer mit Namen DE existiert 
try { 
	var layDE = aDoc.layers["DE"]; 
	layDE.visible = true; 
	//active 
	} 
catch (e) { 
	var layDE = aDoc.layers.add(); 
	layDE.name = "DE"; 
} 
// prüfe ob Layer mit Namen EN existiert 
try { 
	var layEN = aDoc.layers["EN"]; 
	layEN.visible = true; 
	//active 
	} 
catch (e) { 
	var layEN = aDoc.layers.add(); 
	layEN.name = "EN"; 
} 
 
var x = prompt ("Ebene sichtbar schalten: (DE/EN)", "DE", "Ebenentoggle"); 
 
if (x && x == "DE") { 
	// set visibility Deutsch 
	layDE.visible = true; 
	layEN.visible = !layDE.visible; 
} else { 
	if (x && x == "EN") { 
		// oder set visibility Englisch 
		layEN.visible = true; 
		layDE.visible = !layEN.visible; 
	} else { 
	alert ("kein gültiger Ebenenname"); 
	} 
}

Das ist nur ein sehr allgemein gehaltener Code. Er sollte aber zeigen, wie es auf jeden Fall funktionieren muss – unabhängig von der Scriptsprache oder Programm. Das man Teile des Codes weglassen, praktischer programmieren oder auch verfeinern kann ist selbstredend.

als Antwort auf: [#561315]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Kai Rübsamen

Beiträge gesamt: 4684

8. Dez 2017, 12:14
Beitrag # 8 von 20
Beitrag ID: #561323
Bewertung:
(7579 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo!

Auch nur JS, aber man sollte das adaptieren können. Das Problem ist, dass ein Objekt, dass in einer Variable liegt, nach dem Ändern einer Ebene nicht mehr vorhanden ist:

Code

var curDoc = app.activeDocument; 
var allLinks = curDoc.links; 
var layernames = ["DE", "EN"]; 
 
for (var i = allLinks.length-1; i >= 0; i--) { 
  var curItem = allLinks[i].parent; 
  if (curItem.constructor.name == "ImportedPage") { 
    for (var k = 0; k < layernames.length; k++) { 
      var curLayer = curItem.graphicLayerOptions.graphicLayers.item(layernames[k]); 
      if (curLayer.isValid) { 
        curLayer.currentVisibility = !curLayer.currentVisibility; 
      } 
    } 
  } 
}

Wenn ich beim zweiten Durchlauf "curItem" prüfe, gibt es das nicht mehr. Frage ich das Objekt jedes Mal erneut ab, geht es:

Code

var curDoc = app.activeDocument; 
var allLinks = curDoc.links; 
var layernames = ["DE", "EN"]; 
 
for (var i = allLinks.length-1; i >= 0; i--) { 
  if (allLinks[i].parent.constructor.name == "ImportedPage") { 
    for (var k = 0; k < layernames.length; k++) { 
      var curLayer = allLinks[i].parent.graphicLayerOptions.graphicLayers.item(layernames[k]); 
      if (curLayer.isValid) { 
        curLayer.currentVisibility = !curLayer.currentVisibility; 
      } 
    } 
  } 
}

als Antwort auf: [#561317]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Henry

Beiträge gesamt: 967

8. Dez 2017, 13:20
Beitrag # 9 von 20
Beitrag ID: #561328
Bewertung:
(7559 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Antwort auf: … Das Problem ist, dass ein Objekt, dass in einer Variable liegt, nach dem Ändern einer Ebene nicht mehr vorhanden ist…

Ah, das macht Sinn ;-)
…grrr, wer soll denn auf sowas kommen???

@Marcel, probier dann mal sowas

Code

		'------------- Toggle Ebenen DE und EN ---------------------   
		if (Ebene_DE = true) AND (Ebene_EN = true) then   
			ebenen.Item("DE").CurrentVisibility = Not(ebenen.Item("DE").CurrentVisibility)  
Set Ebenen = Datei.graphicLayerOptions.graphicLayers 
			ebenen.Item("EN").CurrentVisibility = Not(ebenen.Item("EN").CurrentVisibility)  
		end if

Also vor dem zweiten "Toggeln" (nur) das "Ebenen"-Objekt neu zuweisen.

als Antwort auf: [#561323]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

8. Dez 2017, 13:23
Beitrag # 10 von 20
Beitrag ID: #561329
Bewertung:
(7558 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Ich habe jetzt das Problem gefunden.
Ein Eintrag in einem anderen Forum hat mich auf die Spur gebracht.

Bei Indesign ist es so, das sich die ID einer eingebundenen Datei nach dem Ein-/Ausblenden einer Ebene ändert.
Die Datei ist danach zwar noch vorhanden, wegen der neuen ID aber plötzlich unbekannt.

Wie ich sehe, hat Kai das Problem auch schon erkannt.

als Antwort auf: [#561317]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Uwe Laubender

Beiträge gesamt: 5318

8. Dez 2017, 14:15
Beitrag # 11 von 20
Beitrag ID: #561332
Bewertung:
(7546 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Wortsalat,

wir hatten das Problem mit der sich ändernden ID auch schon hier diskutiert.
Allerdings im Hinblick auf platzierte AI-Dateien, die nach dem Platzieren geändert und dann upgedatet wurden. Ist ein paar Jahre her, denke ich…

als Antwort auf: [#561329]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

8. Dez 2017, 14:23
Beitrag # 12 von 20
Beitrag ID: #561333
Bewertung:
(7543 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Uwe,

auf eine sich ändernde ID soll man auch mal kommen.
Da rechnet man ja eigentlich nicht mit. Wobei InDesign ja immer wieder für Überraschungen und Eigenheiten gut ist.

@Kai Rübsamen
Dein Script läuft so wie ich es mir gedacht habe. Danke
Ich sollte mich mehr mit JavaScript befassen. VB ist offensichtlich nicht so weit verbreitet und vielleicht auch veraltet". Scheinbar bietet JS auch mehr Möglichkeiten.

@Alle
Danke für die vielen Rückmeldungen.

Grüße
Marcel

als Antwort auf: [#561332]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

WernerPerplies

Beiträge gesamt: 2762

8. Dez 2017, 14:41
Beitrag # 13 von 20
Beitrag ID: #561334
Bewertung:
(7535 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Uwe,

sich ändernde IDs sind das eine, eine veränderte Reihenfolge von Elementen in einer Collection sind ein weiteres Problem.

Deshalb macht es Sinn, bei identischer ID immer über die ID, bei eindeutigem Namen über den Namen zuzugreifen.

Für dieses Beispiel vielleicht so:

Code

main(); 
 
/*void*/function main() 
{ 
    try 
    { 
        /*Document*/var doc = app.activeDocument, /*Pages*/pages = doc.pages.everyItem().getElements(),  
            /*Graphics*/graphics = null, 
            /*Int*/l = pages.length, /*Int*/li = -1; 
        for (var i = 0; i < l; i++) 
        { 
            graphics = pages[i].allGraphics; 
            ll = graphics.length; 
            for (var ii = 0; ii < ll; ii++) 
            { 
                if ((app.activeDocument.layers.itemByName("DE").isValid) || (app.activeDocument.layers.itemByName("EN").isValid)) 
                { 
                    app.activeDocument.layers.itemByName("DE").visible = !(app.activeDocument.layers.itemByName("DE").visible); 
                    app.activeDocument.layers.itemByName("EN").visible = !(app.activeDocument.layers.itemByName("EN").visible);                    
                }                     
            }             
        } 
    } 
    catch (error) 
    { 
        alert("Fehlermeldung: " + error.message + "\nin Datei: " + error.fileName + "\nin Zeile: " + error.line ); 
    } 
}

Wobei natürlich noch einige mögliche Fehlerbedingungen herauszuprüfen sind.

als Antwort auf: [#561332]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

pixxxelschubser

Beiträge gesamt: 1708

8. Dez 2017, 14:51
Beitrag # 14 von 20
Beitrag ID: #561335
Bewertung:
(7533 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Zitat … VB ist offensichtlich nicht so weit verbreitet und vielleicht auch veraltet". Scheinbar bietet JS auch mehr Möglichkeiten …

Nein. VBS ist nicht veraltet. Genausowenig wie Applescript. Und diese beiden plattformspezifischen Sprachen bieten genaugenommen sogar mehr Möglichkeiten als Javascript (genauer: Adobe Extendscript).

Der große Vorteil von Javascript ist einfach der: Diese Sprache ist plattformübergreifend und funktioniert im Großen und Ganzen (mit klitzekleinen Ausnahmen) sowohl unter Windows und MacOS

als Antwort auf: [#561333]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

WernerPerplies

Beiträge gesamt: 2762

8. Dez 2017, 15:12
Beitrag # 15 von 20
Beitrag ID: #561337
Bewertung:
(7527 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Zitat Der große Vorteil von Javascript ist einfach der: Diese Sprache ist plattformübergreifend und funktioniert im Großen und Ganzen (mit klitzekleinen Ausnahmen) sowohl unter Windows und MacOS

Und nicht zu vergessen, für praktisch jedes Anwendungsproblem gibt es irgendwo eine Library.
Deshalb entwickle ich ich heute fast ausschließlich mit JavaScript.
Und es ist zusatzlich auch noch die Skriptsprache für Browseranwendungen. -> Nodes, Electron u. ä.

als Antwort auf: [#561335]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

WernerPerplies

Beiträge gesamt: 2762

9. Dez 2017, 08:41
Beitrag # 16 von 20
Beitrag ID: #561355
Bewertung:
(4306 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

:-)
Ok, offensichtlich fand niemand meinen Code interessant genug um ihn auszuprobieren, denn die Umschaltung funktioniert natürlich nur für das Dokument.

Wortsalat möchte hingegen die Ebenen im Dokument ausdrücklich nicht umschalten, denn die englische Ebene ist in seinem Beispieldokument leer.

Ich habe deshalb diesen Teil, im jetzt hoffentlich richtig funktionierenden Skript, auskommentiert.

Es ist übrigens nicht so, dass sich die ID der importierten Seite ändert, sondern es wird beim Umschalten der Sichtbarkeit ein komplett neues Objekt "ImportedPage" erzeugt.

Damit kann man das Objekt nicht über den Namen oder ein eingefügtes Label wiederfinden.

Der Container (Parent), im Beispiel ein Rectangle, bleibt hingegen erhalten und wird im folgenden Skript benutzt.

Code

/*Any*/ Array.prototype.parentsOfImportedPages=function() 
{ 
    /*Int*/l = this.length, /*Array*/parents = new Array(this.length), /*Int*/c = -1; 
    for (var i = 0; i < l; i++) 
    { 
        if (!("parent" in this[i])) 
            continue; 
        if (("importedPages" in this[i].parent) && (this[i].parent.importedPages.length > 0)) 
        parents[++c] = this[i].parent;     
    } 
    parents.length= ++c; 
    return parents; 
} 
 
 
main(); 
 
/*void*/function main() 
{ 
    try 
    { 
        /*Document*/var doc = app.activeDocument, /*Graphics*/parentsOfImportedPages = doc.allGraphics.parentsOfImportedPages(), /*Int*/l = parentsOfImportedPages.length, 
            /*Graphic*/parentsOfImportedPage = null, /*ImportedPage*/ importedPage = null,  /*Int*/ll = -1; 
       /*  
        if ((doc.layers.itemByName("DE").isValid) || (doc.layers.itemByName("EN").isValid)) 
        { 
            doc.layers.itemByName("DE").visible = !(doc.layers.itemByName("DE").visible); 
            doc.layers.itemByName("EN").visible = !(doc.layers.itemByName("EN").visible);                    
        }    
    */ 
        for (var i = 0; i < l; i++) 
        { 
            parentsOfImportedPage = parentsOfImportedPages[i]; 
            ll = parentsOfImportedPage.importedPages.length; 
            for (var ii = 0; ii < ll; ii++) 
            { 
                importedPage = parentsOfImportedPage.importedPages[ii]; 
                if (("graphicLayerOptions" in importedPage) && ("graphicLayers" in importedPage.graphicLayerOptions)) 
                { 
                    if ((importedPage.graphicLayerOptions.graphicLayers.itemByName("DE").isValid) || (importedPage.graphicLayerOptions.graphicLayers.itemByName("EN").isValid)) 
                    { 
                        importedPage.graphicLayerOptions.graphicLayers.itemByName("DE").currentVisibility = !(importedPage.graphicLayerOptions.graphicLayers.itemByName("DE").currentVisibility); 
                        importedPage = parentsOfImportedPage.importedPages[ii]; 
                        importedPage.graphicLayerOptions.graphicLayers.itemByName("EN").currentVisibility = !(importedPage.graphicLayerOptions.graphicLayers.itemByName("EN").currentVisibility);                    
                    }    
                } 
            } 
        } 
    } 
    catch (error) 
    { 
        alert("Fehlermeldung: " + error.message + "\nin Datei: " + error.fileName + "\nin Zeile: " + error.line ); 
    } 
}

als Antwort auf: [#561334]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Uwe Laubender

Beiträge gesamt: 5318

10. Dez 2017, 18:33
Beitrag # 17 von 20
Beitrag ID: #561371
Bewertung:
(4132 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Werner,
ich möchte noch vor einer "bösen Falle" warnen:

Ein bestimmter Name einer Ebene mag in InDesign nur ein einziges mal vergebbar sein, in beispielsweise PhotoShop oder Illustrator ist das nicht der Fall. Da können beliebige Ebenen den gleichen Namen tragen.

als Antwort auf: [#561355]

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

WernerPerplies

Beiträge gesamt: 2762

11. Dez 2017, 07:52
Beitrag # 18 von 20
Beitrag ID: #561375
Bewertung:
(4037 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Moin Uwe,

Zitat Ein bestimmter Name einer Ebene mag in InDesign nur ein einziges mal vergebbar sein, in beispielsweise PhotoShop oder Illustrator ist das nicht der Fall. Da können beliebige Ebenen den gleichen Namen tragen.

Und ich halte InDesigns Design dieses Features für einen Fehler.

Aber richtig schlimm es natürlich, dass sich das Design innerhalb einer Produktfamilie unterscheidet.

Natürlich möchte ich mehrere Ebenen gleich benennen können, das zeigt gerade die Verwendung von Länderkennzeichen. Es könnte durchaus gewünscht sein, dass man mehrere Ebenen für ein Land verwenden möchte.

Deshalb wäre es vermutlich sinnvoller, das Skript so zu ändern, dass abgefragt würde, ob ein LKZ enthalten ist.

Generell würde ich allerdings in einem professionellen Skript die Ebenen als Parameter in zwei Arrays ([visible],[invisible]) übergeben und keinesfalls irgendwelche Abfragen hart codieren.

als Antwort auf: [#561371]
(Dieser Beitrag wurde von WernerPerplies am 11. Dez 2017, 08:06 geändert)

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

11. Dez 2017, 11:25
Beitrag # 19 von 20
Beitrag ID: #561377
Bewertung:
(3995 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Moin zusammen,

@Herr Perplies

Antwort auf: ...
Ok, offensichtlich fand niemand meinen Code interessant genug um ihn auszuprobieren, denn die Umschaltung funktioniert natürlich nur für das Dokument.

Ich habe es getestet und es ist mir auch aufgefallen ;-)

@Kai Rübsamen
Ich habe versucht, das Script in VBS zu schreiben.
Komme aber mit "parent" nicht klar. Dafür programmiere ich dann doch zu selten.

Dafür habe ich jetzt noch eine andere Variante in VBS geschrieben. Vielleicht etwas umständlich aber es funktioniert.
In diesem Script lese ich die IDs der eingebundenen InDesign Dateien in ein Array ein (separate Funktion).
Das Ansprechen der Dateien erfolgt über die IDs.
Nach jedem Umschalten einer Ebene wird das Array mit den IDs aktualisiert.

Code

'*********************************************************** 
'11.12.2017 
'Ebenen bei eingebundenen InDesign-Dateien umschalten (Toggeln) 
'HINWEIS: Beim Umschalten einer Ebene ändert sich die ID! 
'*********************************************************** 
 
Set myInDesign = CreateObject("InDesign.Application.cs6") 
Set myDocument = myInDesign.ActiveDocument 
LinksID = F_Array_DateiID 
 
For x = 1 to UBOUND(LinksID) 
 
  LinksID = F_Array_DateiID 
  Set Datei = MyDocument.allGraphics.ItemById(LinksID(x)) 
  Set Ebenen = Datei.graphicLayerOptions.graphicLayers 
  Ebenen.item("DE").CurrentVisibility = Not(Ebenen.item("DE").CurrentVisibility) 
	 
  LinksID = F_Array_DateiID 
  Set Datei = myDocument.allGraphics.ItemById(LinksID(x)) 
  Set Ebenen = Datei.graphicLayerOptions.graphicLayers 
  Ebenen.item("EN").CurrentVisibility = Not(Ebenen.item("EN").CurrentVisibility) 
 
Next 
	 
 
'****************************************************************** 
'ID der eingebundenen Dateien (Typ: InDesign) in ein Array schreiben 
'Aufruf:	F_Array_DateiID() 
'================================================================== 
 
Public Function F_Array_DateiID() 
 
Set myInDesign = CreateObject("InDesign.Application.CS6") 
Set myDocument = myInDesign.ActiveDocument 
REDIM e(1 
 
For n = 1 to myDocument.allGraphics.count 
  Set Datei = myDocument.allGraphics.Item(n) 
  If Datei.ImageTypeName = "InDesign" then 
    e(UBOUND(e)) = Datei.ID 
    REDIM PRESERVE e(UBOUND(e)+1) 
  End if 
Next 
 
REDIM PRESERVE e(UBOUND(e)-1) 
F_Array_DateiID = e 
 
End Function

als Antwort auf: [#561355]
(Dieser Beitrag wurde von Wortsalat am 11. Dez 2017, 11:42 geändert)

Zustand der Sichtbarkeit bei Ebenen hin und her toggeln

Wortsalat

Beiträge gesamt: 87

12. Dez 2017, 14:01
Beitrag # 20 von 20
Beitrag ID: #561391
Bewertung:
(3807 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Mein letztes Script führt zu einem Fehler, wenn in einer eingebundenen Datei die Ebene "DE" oder "EN" nicht vorhanden ist.
Hier noch eine Erweiterung, in der geprüft wird, ob die Ebenen vorhanden sind.

Code

'****************************************************************************************** 
'11.12.2017 
'Ebenen bei eingebundenen InDesign-Dateien umschalten (Toggeln) 
'HINWEIS: Beim Umschalten einer Ebene ändert sich die ID! 
'****************************************************************************************** 
 
Set myInDesign = CreateObject("InDesign.Application.cs6") 
Set myDocument = myInDesign.ActiveDocument 
LinksID = F_Array_DateiID 
 
For x = 1 to UBOUND(LinksID) 
 
	LinksID = F_Array_DateiID 
	Set Datei = myDocument.allGraphics.ItemById(LinksID(x)) 
	Set Ebenen = Datei.graphicLayerOptions.graphicLayers 
	If F_EbeneExist(LinksID(x), "DE") = True then 
		Ebenen.item("DE").CurrentVisibility = Not(Ebenen.item("DE").CurrentVisibility) 
	end if 
	 
	LinksID = F_Array_DateiID 
	Set Datei = myDocument.allGraphics.ItemById(LinksID(x))	 
	Set Ebenen = Datei.graphicLayerOptions.graphicLayers 
	If F_EbeneExist(LinksID(x), "EN") = True then 
		Ebenen.item("EN").CurrentVisibility = Not(Ebenen.item("EN").CurrentVisibility) 
	End if 
Next 
 
 
 
'****************************************************************************************** 
'ID der eingebundenen Dateien (Typ InDesign) in ein Array schreiben 
'Aufruf:	F_Array_DateiID() 
'========================================================================================== 
 
Public Function F_Array_DateiID() 	 
 
Set myInDesign = CreateObject("InDesign.Application.CS6") 
Set myDocument = myInDesign.ActiveDocument 
REDIM e(1) 
 
For n = 1 to myDocument.allGraphics.count		'Alle Grafiken durchlaufen		 
	Set Datei = myDocument.allGraphics.Item(n)	 
	If Datei.ImageTypeName = "InDesign" then	'Prüfen, ob Typ InDesign 
		e(UBOUND(e)) = Datei.ID			'ID in Array schreiben 
		REDIM PRESERVE e(UBOUND(e)+1)	 
	End if	 
Next 
 
REDIM PRESERVE e(UBOUND(e)-1)				'Array, letzte Stelle löschen 
F_Array_DateiID = e 
 
End Function 
 
 
 
'****************************************************************************************** 
'Prüfen, ob eine Ebene existiert 
'Aufruf:    F_EbeneExist(LinkID, Ebene) 
'Parameter: LinkID = ID der eingebundenen Datei, Ebene = Name der gesuchten Ebene  
'========================================================================================== 
 
Public Function F_EbeneExist(LinkID, Ebene)			 	 
 
F_EbeneExist = False 
 
Set myInDesign = CreateObject("InDesign.Application.CS6")	 
Set myDocument = myInDesign.ActiveDocument 
Set Datei = myDocument.allGraphics.ItemById(LinkID) 
 
For x1 = 1 to Datei.graphicLayerOptions.graphicLayers.count 
	If Datei.graphicLayerOptions.graphicLayers.Item(x1).Name = Ebene then 
		F_EbeneExist = True 
	End if 
Next 
End Function

als Antwort auf: [#561377]

Aktuell

Diverses

Tipps zum Aufräumen und Ordnung schaffen

| 29.11.2023

Weitere Events

Neuste Foreneinträge

Mit Preflight Registerfarbe ALL nach Grau konvertieren geht nicht

Quark Objekte lassen sich nicht neben Layout ziehen.

Absatzsetzer in CC24 ME lösen Probleme aus

Barrierefreie PDFs | Mögliche unangebrachte Verwendung des Strukturelements xy

Barrierefreiheit in indesign 2022: figure-Tags haben als Attributobjekt "block" statt "inline"?

Kontrollkästchen in PDF-Formular

Indesign Tabelle ausrichten

Mehrfach geschichtete und übereinander gelagerte PDFs bereinigen

InDesign 19.2 konvertiert 19.3-Dateien beim Öffnen ungefragt

Platzierte Vektorgrafiken skalieren

Weitere Stellenangebote