global DesktopPath 
global Exportordner 
 
on open DroppedDocs 
	set DesktopPath to path to desktop as Unicode text 
	set LogFilePath to DesktopPath & "Bildliste.txt" 
	 
	repeat with aDoc in DroppedDocs 
		tell application "Adobe InDesign CS3" 
			open aDoc  
			set docPath to full name of active document as string 
			my makeFolder(docPath) 
			 
			tell document 1 
				set allLinks to every link 
				 
				repeat with i from 1 to count of allLinks 
					set curLink to (item i of allLinks) 
					set PicturePath to (file path of curLink) as string 
					my copyImages(PicturePath, docPath) 
				end repeat 
				 
			end tell 
			 
			close every document 
		end tell 
		end repeat 
	display dialog "Die Dokumente wurden inklusive aller aktiven Verknüpfungen auf dem Schreibtisch zusammengetragen." 
end open 
 
on makeFolder(docPath) 
	set AppleScript's text item delimiters to ":" 
	set docName to (text item -1 of docPath) 
	set AppleScript's text item delimiters to "." 
	set docBaseName to (text item -2 of docName) 
	set AppleScript's text item delimiters to "" 
	set Exportordner to DesktopPath & docBaseName 
	 
	tell application "Finder" 
		try 
			Exportordner as alias 
			display dialog "Es ist schon ein mit dem Namen " & docName & " auf dem Schreibtisch vorhanden!" 
		on error 
			make new folder at folder DesktopPath with properties {name:docBaseName} 
			try 
				make new folder at folder Exportordner with properties {name:"Links"} 
				make new folder at folder (Exportordner & ":Links") with properties {name:"NEF"} 
			on error 
				display dialog "Konnte keinen Ordner mit dem Namen 'Links' im Exportordner erstellen" 
			end try 
		end try 
		try 
			copy file docPath to folder Exportordner 
		end try 
	end tell 
end makeFolder 
 
on copyImages(PicturePath, docPath) 
	set AppleScript's text item delimiters to "." 
	set nefName to (text item -2 of PicturePath & ".nef") 
	set AppleScript's text item delimiters to "" 
	 
	tell application "Finder" 
		try 
			copy file nefName to folder (Exportordner & ":Links:NEF") 
		on error 
			try 
				copy file PicturePath to folder (Exportordner & ":Links") 
			end try 
		end try 
	end tell 
	 
end copyImages