(*   
DateienVerschieben_01d.app 
Dieses Script verschiebt Dateien in entsprechende Ordner des Hauptordners  
aufgrund der acht Zeichen zu Beginn der Datei-Namen 
© 24.09.16 / Hans Haesler, Châtelard 52, CH-1018 Lausanne 
*) 
 
global targetFolder 
 
-- einen Dialog zeigen, falls der Anwender einen Doppelklick auf das Droplet macht     
on run 
  display dialog "Den Ordner auf dem Icon  
dieses Droplets deponieren." buttons "OK" default button 1 with icon 0 
end run 
 
-- der 'open handler', welcher auf das Fallenlassen von Objekten reagiert   
on open allObjects 
  -- den Hauptordnerpfad speichern 
  if (item 1 of allObjects as string) ends with ":" then 
    set targetFolder to (item 1 of allObjects) 
  else 
    tell application "Finder" 
      set targetFolder to (container of item 1 of allObjects) as Unicode text 
    end tell 
  end if 
  -- Wiederholschleife, welche die gedroppten Objekte zum Handler 'processObject' schickt     
  repeat with aObject in allObjects 
    processObject(aObject) 
  end repeat 
  -- den Anwender informieren  
  activate me 
  display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1 
end open 
 
-- im folgenden Handler wird festgestellt, ob das Objekt ein Ordner oder eine Datei ist;   
-- der Inhalt des Hauptordners wird aufgelistet; Dateien werden zum Handler 'processFile' gesandt.  
on processObject(aObject) 
  -- wenn der Pfad mit einem Doppelpunkt endet, ist das Objekt ein Ordner  
  if (aObject as string) ends with ":" then 
    -- die Liste des Inhalts wird erstellt 
    tell application "System Events" 
      set contentsList to name of every file of folder (aObject as Unicode text) 
    end tell 
    -- die Wiederholschleife schickt die Dateien zum Handler 'processFile' 
    repeat with curItem in contentsList 
      set objPath to ((aObject as Unicode text) & curItem) 
      -- unsichtbare Dateien ausschliessen 
      if not (curItem starts with ".") then 
        -- die Dateipfad und Name senden 
        if (count of curItem) is greater than 11 then 
          processFile(objPath as alias, curItem) 
        end if 
      end if 
    end repeat 
    -- wenn das Objekt eine Datei ist ...  
  else 
    tell application "Finder" 
      -- den Namen der Datei ...   
      set fullName to name of file aObject 
    end tell 
    -- ... wird der Pfad und der Dateiname dem Handler 'processFile' übergeben  
    processFile(aObject, fullName) 
  end if 
end processObject 
 
-- die aktuelle Datei behandeln  
on processFile(aObject, fullName) 
  -- den Ordnernamen ausziehen 
  set folName to text 3 thru 8 of fullName 
  -- und auch den vollen Pfad zum Unterordner  
  set curFolder to ((targetFolder as string) & folName) as string 
  tell application "Finder" 
    -- wenn der Ordner vorhanden ist ...  
    if (exists curFolder) then 
      -- ... versuchen, die aktuelle Datei hineinzuverschieben  
      try 
        move file aObject to curFolder with replacing 
      end try 
    else 
      -- sonst den Ordner zuerst erzeugen ... 
      set curFolder to make new folder at folder targetFolder with properties {name:folName} 
      -- ... und dann die Datei verschieben 
      try 
        move file aObject to curFolder with replacing 
      end try 
    end if 
  end tell 
end processFile