[GastForen Programmierung/Entwicklung AppleScript Dateien umbenennen mit Hilfe einer Excel-Tabelle

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza
Beiträge gesamt: 29

19. Mär 2018, 16:48
Beitrag # 16 von 37
Beitrag ID: #562941
Bewertung:
(5758 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

ich habe dir per Mail einen Screenshot meiner Dateien geschickt und noch eine kurze Erklärung zu dem Ablauf des Scripts.

Danke dir schon mal
viele Grüße
tony


als Antwort auf: [#562939]
X

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

19. Mär 2018, 17:20
Beitrag # 17 von 37
Beitrag ID: #562946
Bewertung:
(5757 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

danke für die näheren Erklärungen und den Screenshot.
Ich werde das alles in Ruhe studieren.

Gruss, Hans


als Antwort auf: [#562941]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

21. Mär 2018, 08:37
Beitrag # 18 von 37
Beitrag ID: #562996
Bewertung:
(5724 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

ich konnte mich gestern erst abends mit der Aufgabe beschäftigen.
Und musste mich herantasten, um eine effiziente Lösung zu finden.

Mit Deiner Zeile ...

Code
tell application "Microsoft Excel" 
tell workbook 1
set lastRow to (count of rows of used range of active sheet)
end tell
end tell
display dialog "" & lastRow

... ist das Ergebnis 17636. Obwohl in der Datei "nur" 3376 Zeilen belegt sind.

Mit diesem Befehl ...

Code
tell application "Microsoft Excel" 
tell active sheet
# den Index für die letzte benutzte Zelle der ersten Spalte holen
set lastRow to first row index of (get end (last cell of column 1) direction toward the top)
end tell
end tell
display dialog "" & lastRow

... ist das Ergebnis 3376. Die zu holende Tabelle wird viel handlicher sein.

Ich habe mit beiden Beispiel-Namen, welche Du in der Erklärung genannt hattest, einen Versuch gemacht.
Sowohl "TB1897" als auch "TB1898" kommt je zwei Mal vor. Bei der ersten sind die Farben "olive" und "black" eingetragen. Bei der zweiten sind es "grey" und "black".

Im Dialog werden also drei Namen angeboten:
"black"
"grey"
"olive".

Wenn Du nun "black" wählst, dann ist es okay, denn diese Farbe ist bei beiden Artikelnummern vorhanden. Aber ein "grey" ist nur bei der zweiten Artikelnummer eingetragen.

Frage 1: Werden dann dennoch beide Datei-Namen mit "00111%grey" ergänzt?
Frage 2: Wieviele Dateien droppst Du pro Arbeitsgang?

Zudem ist noch nicht klar, wie das Script bei "nicht gleichen Farbcodes" agieren soll. Es muss ja vor dem Umbenennen einer Datei deren Artikelnummer holen, dann nachschauen, wie der Code der gewählten Farbe ist. "So far, so good"? Eher kompliziert ...

Aber: Was tun, wenn z.B. "grey" nicht vorhanden ist?

Gruss, Hans


als Antwort auf: [#562941]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza
Beiträge gesamt: 29

21. Mär 2018, 11:22
Beitrag # 19 von 37
Beitrag ID: #563006
Bewertung:
(5710 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

Zitat Im Dialog werden also drei Namen angeboten:
"black"
"grey"
"olive".


genau so habe ich mir die Liste vorgestellt.

Zitat Wenn Du nun "black" wählst, dann ist es okay, denn diese Farbe ist bei beiden Artikelnummern vorhanden. Aber ein "grey" ist nur bei der zweiten Artikelnummer eingetragen.


Hierzu muss ich sagen, dass ich ja unabhängig von der Artikelnummer immer die gleichen Farben nach Sicht auswähle.

Somit müsste ja die von mir gesuchte Farbe auf jeden Fall im Dialog erscheinen.

Momentan ist mein Script noch so aufgebaut, dass ich die Farbnamen eingeben muss. In diesem Fall "black".

Das Script schaut bei der TB1897 nach ob es black gibt, wenn gefunden, schaut er in der anderen Spalte nach dem Farbcode und benennt mir alle Dateien der TB1897 um, dann schaut er bei der TB1898 nach ob es black gibt, in diesem Fall findet er auch black, schaut nach dem Farbcode und benennt mir alle Dateien der TB1898 um.

Zitat Frage 1: Werden dann dennoch beide Datei-Namen mit "00111%grey" ergänzt?


Wenn ich jetzt grey auswähle bzw. eintippe, dann findet er bei der TB1897 nichts, dann werden die Dateien mit dieser Artikelnummer auch nicht umbenannt. Das Script geht weiter zur nächsten Artikelnummer und schaut dort ob es grey gibt, wenn gefunden, werden die Dateien umbenannt.

Ich muss am Ende, wenn der Arbeitsablauf abgeschlossen ist, nur mal schnell durch den Ordner mit den Dateien scrollen und sichten, ob alle ausgewählten Dateien umbenannt wurden.
In diesem Beispiel würde ich feststellen, dass die Dateien mit der Artikelnummer TB1898 in grey umbenannt wurden, die Dateien mit der Artikelnummer TB1897 aber nicht.

Zitat Frage 2: Wieviele Dateien droppst Du pro Arbeitsgang?


Das ist sehr unterschiedlich. Aber im Schnitt würde ich sagen, sind es 50 Dateien. 50 Dateien heisst jetzt aber nicht automatisch 50 Artikelnummern.
Das würden eher so 10 Artikelnummern sein.

Zitat Zudem ist noch nicht klar, wie das Script bei "nicht gleichen Farbcodes" agieren soll. Es muss ja vor dem Umbenennen einer Datei deren Artikelnummer holen, dann nachschauen, wie der Code der gewählten Farbe ist. "So far, so good"? Eher kompliziert ...

Aber: Was tun, wenn z.B. "grey" nicht vorhanden ist?


Bisher funktioniert das Script mit "nicht gleichen Farbcodes". Bleiben wir mal bei meinen Beispiel-Artikelnummern.
Änder doch einfach mal bei der TB1898 den Farbcode von black in eine andere Zahl. Änder 00007 zu 77777 und führe mein Script so aus wie es ist.


Dateinamen der Artikel sehen dann so aus:

TB1897_0 1-00007%black.jpg

TB1898_0 3-77777%black.jpg

Das funktioniert also schon mal.


Und so würden die Dateien im Ordner aussehen, wenn grey ausgewählt würde:

TB1897_0 1.jpg

TB1898_0 3-00111%grey.jpg


Wie gesagt würde ich beim durchscrollen durch den Ordner sehen, dass das Script die Dateien mit der Artikelnummer TB1897 nicht umbenannt hätte.
Das zeigt mir, dass TB1897 doch nicht die Farbe grey hat. Diese Dateien würde ich einfach noch mal droppen und in der Liste würde ich dann sehen, dass die Artikel nicht in grey exisitieren, sondern in bspw. "dark-grey" (ja ich weiss dass der Artikel nur black und olive hat, aber stellen wir uns einfach mal anstatt olive "dark-grey" vor.
Mein Fehler, also wähle ich dark-grey aus und das Problem ist erledigt.
Wie gesagt wähle ich die Farben nach Sicht aus, da kann ich schon mal denken, dass ein Artikel grey ist, in Wirklichkeit aber dark-grey ist.
Oder der Artikel ist gar nicht black, sondern black-black.

Jedenfalls passiert nichts mit den Dataien, wenn nicht die richtige Farbe gefunden wurde.

Ich hoffe das ist irgendwie nachvollziehbar.


Gruß
tony


als Antwort auf: [#562996]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

21. Mär 2018, 11:53
Beitrag # 20 von 37
Beitrag ID: #563007
Bewertung:
(5704 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

okay, wenn es die gewählte Farbe nicht gibt, dann wird nicht umbenannt.

Ich werde nun mal eine Reihe von Dateien vorbereiten, welche ich zum Testen verwenden kann.
Wann die erste Version bereit sein wird, ist noch ungewiss, weil ich erneut einen guten Teil des Nachmittags auswärts sein werde.


*****
Doch hier schon mal eine Vereinfachung ... Beim Speichern der Farbcodes mit ...

Code
set that_cell to value of mod_cell 

... gehen ja die führenden Nullen verloren. Und müssen umständlich wieder eingefügt werden:

Code
if that_cell < 10 then 
set that_cell to "0000" & value of mod_cell
else if that_cell < 100 then
set that_cell to "000" & value of mod_cell
else if that_cell < 1000 then
set that_cell to "00" & value of mod_cell
else if that_cell < 10000 then
set that_cell to "0" & value of mod_cell
end if

Letzteres kann vereinfacht werden. Angenommen, der Wert von 'that_cell' ist "23":

Code
set that_cell to "23" 
set that_cell to text -5 thru -1 of ("0000" & that_cell)

Das Ergebnis wird immer auf 5 Stellen getrimmt: "00023"

Es geht aber noch einfacher. :-) Mit 'string value' bleiben die führenden Nullen erhalten:

Code
set that_cell to string value of mod_cell 

--> "00023"

Gruss, Hans


als Antwort auf: [#563006]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza
Beiträge gesamt: 29

21. Mär 2018, 12:00
Beitrag # 21 von 37
Beitrag ID: #563008
Bewertung:
(5698 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

vielen Dank für deine Erklärung.

Diesen Umweg gehe ich ja nur, weil ich mir nicht anders zu helfen weiss.

Manchmal ist es aber auch nur ein kleines Wort was den Unterschied macht. Man muss es aber wissen bzw. kennen.
Mir war es nicht bekannt :)

Aber danke für diesen Hinweis!

Okay Hans, dann wünsch ich dir mal einen schönen Nachmittag und bin gespannt von dir zu hören.

viele Grüße
tony


als Antwort auf: [#563007]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

21. Mär 2018, 22:02
Beitrag # 22 von 37
Beitrag ID: #563023
Bewertung:
(5656 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

heute ist wieder allerlei Unvorhergesehenes dazwischengekommen. Das Script ist noch nicht fertig.
Ich habe Dir einen Link zum Herunterladen der Betaversion 04 geschickt.

Nach dem Droppen der Dateien sollte ein Dialog die Farben zur Auswahl anbieten.
Einen der angezeigten Namen wählen und auf "OK" klicken. Ein Dialog meldet den gewählten Namen.
Würdest Du bitte prüfen, ob das bei Dir auch funktioniert.

Im Laufe des Donnerstags werde ich versuchen, diese erste Version fertigzustellen.

Gruss, Hans


als Antwort auf: [#563008]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

24. Mär 2018, 09:56
Beitrag # 23 von 37
Beitrag ID: #563102
Bewertung:
(5581 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

endlich ... ist die erste Version fertig.

Ich habe Dir per E-Mail den Link zum Herunterladen zugestellt.

Nun hoffe ich, dass das Droplet schon wie erwartet funktionieren wird.

Gruss, Hans


als Antwort auf: [#563008]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza
Beiträge gesamt: 29

24. Mär 2018, 12:43
Beitrag # 24 von 37
Beitrag ID: #563110
Bewertung:
(5326 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

ich habe deine Mail gesehen und vielen Dank für diese Version!
Funktioniert bei mir reibungslos und schnell ;)

Wie ich bereits in der Mail geschrieben habe, gebe ich dir am Montag bescheid wie das Script mit Dataien auf dem Server umgeht.

Bis dahin ein schönes Wochenende!

viele Grüße
tony


als Antwort auf: [#563102]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

24. Mär 2018, 15:55
Beitrag # 25 von 37
Beitrag ID: #563115
Bewertung:
(5313 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

ich bedanke mich für Deine positive Rückmeldung. Super, dass es auf Anhieb funktioniert!

Ich werde morgen noch das Sortieren der Farbnamen einbauen. Und prüfen, ob sich Dateien, welche auf einem Server liegen, umbenennen lassen.

Gruss, Hans


als Antwort auf: [#563110]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

25. Mär 2018, 10:51
Beitrag # 26 von 37
Beitrag ID: #563118
Bewertung:
(5260 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

ich habe Dir per E-Mail den Link zum erweiterten Droplet zugestellt.

Nun werden die Farbnamen sortiert. Das besorgt der Handler 'quickSort()'.

Den Test mit dem Server habe ich gemacht. Der Server ist gut zwei Kilometer entfernt. Habe mich per VPN mit einem Laptop eingeloggt, ein paar Dateien in einen Testordner kopiert.

Dann die Dateien auf das Droplet gezogen. Ergebnis: alle wurden umbenannt. Keine Probleme.

Gruss, Hans


als Antwort auf: [#563110]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza
Beiträge gesamt: 29

25. Mär 2018, 13:19
Beitrag # 27 von 37
Beitrag ID: #563120
Bewertung:
(5248 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

das Script funktioniert bestens :)

Sortierte Farbnamen macht es auf jeden Fall übersichtlicher und einfacher zum auswählen.

Ich bin wirklich gespannt wie sich das Script in der Praxis mit Dateien auf dem Server verhält. Mehr dazu dann morgen ;) Ich werde berichten!
Aber schon mal gut, dass das ohne Probleme bei dir funktioniert.

Danke für diese Modifizierung im Script.

Gruß
tony


als Antwort auf: [#563118]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

25. Mär 2018, 21:06
Beitrag # 28 von 37
Beitrag ID: #563124
Bewertung:
(5234 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

danke für Deine Bestätigung. Ich hoffe sehr, dass es bei Dir mit dem Server ebenfalls klappen wird.

Auf Deinen Wunsch ist das Droplet (samt Testdateien) bereit zum Veröffentlichen.
Aber ich warte noch Deinen Praxis-Bericht ab.

Gruss, Hans


als Antwort auf: [#563120]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza
Beiträge gesamt: 29

26. Mär 2018, 11:53
Beitrag # 29 von 37
Beitrag ID: #563129
Bewertung:
(5172 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

das Script funktioniert wunderbar! Ohne Probleme und rasend schnell.

Alle Dateien werden auf dem Server umbenannt.

Ich denke es ist nun an der Zeit das Script hier zu veröffentlichen (samt Testdateien).

Vielen Dank Hans für deinen Einsatz. Das Script ist mehr als gelungen ;) Genau so habe ich mir das gewünscht.

viele Grüße
tony


als Antwort auf: [#563124]

Dateien umbenennen mit Hilfe einer Excel-Tabelle

Hans Haesler
  
Beiträge gesamt: 5826

26. Mär 2018, 13:38
Beitrag # 30 von 37
Beitrag ID: #563133
Bewertung:
(5157 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Tony,

bitte sehr. Super, dass es jetzt auch mit Dateien auf dem Server klappt.

Dein Wunsch ist mein Befehl :-). Der Code ist am Schluss dieses Beitrages eingefügt.

Das angehängte Archiv "Testdateien.zip" enthält:
– den Ordner "Bilddateien";
– das gebrauchsfertige Droplet "DateienUmbenennen_02d.app";
– die Excel-Datei "Farbcodes.xlsx".

Es geht um Kleidungsstücke, deren Definition per Artikelnummer, Farbname und Farbcode.
Die 16 Test-Bilder enthalten je nur ein kleines, farbiges Quadrat (nicht die hübschen Damen der Originale ;-).
In der Excel-Datei ist der Inhalt der Spalten C bis E entfernt (Datenschutz). Zudem werden sie nicht benötigt.

Ausführung:
– Das Exceldokument öffnen;
– gleichfarbige Dateien auf das Droplet ziehen;
– im sich öffnenden Dialog einen Farbnamen wählen;
– mit "OK" bestätigen.

Hinweise:
Das Script macht eine Schleife durch die Dateien, prüft, ob die gewählte Farbe für die aktuelle Artikelnummer vorhanden ist.
Falls ja, holt es den zugehörigen Farbcode und ändert den Namen der Datei nach der vorgegebenen Namenskonvention.

Ist die Datei nicht im Excel-Dokument aufgeführt, wird ihr eine rote Etikette verpasst.

Und wenn die gewählte Farbe für die aktuelle Artikelnummer nicht vorhanden ist, wird eine blaue Etikette zugewiesen.

Die Nummer der ersten Datei ("TA1234_0 16.jpg") ist nicht im Excel-Dokument enthalten. Damit sie eingefärbt wird, muss sie mit mindestens einer zweiten Datei gedroppt werden.

Am sichersten ist, Dateien mit identischer Nummer zu wählen.

Denn: Wenn man "TB1897" und "TB1898" gleichzeitig droppt, kommt man nur mit "black" ungeschoren davon. Weil "grey" oder "olive" nicht für beide Artikelnummern erhältlich sind.

Code
(* 
DateienUmbenennen_02d.app
Dateien laut einem Excel-Dokument umbenennen.
© 25.03.2018 / Hans Haesler, Châtelard 52, CH-1018 Lausanne
*)

on open Dropped_Files
# Variablen als 'global' definieren
global artNumList
global indexList
global colNameList
global colCodeList

# die 'delimiters' definieren
set AppleScript's text item delimiters to "_"

# die Liste der Namen initialisieren
set nameList to {}

# eine Schleife durch die gedroppten Dateien
set nFiles to count of Dropped_Files
repeat with n from 1 to nFiles
# den Namen der aktuellen Datei der Variablen 'curName' zuweisen.
tell application "Finder" to set curName to name of (item n of Dropped_Files)
set tmpName to text item 1 of curName
if tmpName is not in nameList then
# den aktuellen Namen ans Ende der Liste anhängen
set end of nameList to tmpName
end if
end repeat

# die 'delimiters' definieren
set AppleScript's text item delimiters to ", "

tell application "Microsoft Excel"
tell active sheet

# den Index für die letzte benutzte Zelle der ersten Spalte holen
set numRows to first row index of (get end (last cell of column 1) direction toward the top)

# die Anzahl prüfen und warnen, falls notwendig
if numRows is 1 then
display dialog "Das Dokument scheint leer zu sein." buttons "OK" default button 1 with icon 0
error number -128
end if

# die erste Spalte auflisten
set artNumList to (value of range ("A1:A" & numRows))
set artNumList to (every text item of (artNumList as string))
# die zweite Spalte auflisten
set colCodeList to (string value of range ("B1:B" & numRows))
set colCodeList to (every text item of (colCodeList as string))
# die sechste Spalte auflisten
set colNameList to (value of range ("F1:F" & numRows))
set colNameList to (every text item of (colNameList as string))

end tell
end tell

# die 'delimiters' zurücksetzen
set AppleScript's text item delimiters to {""}

# die Anzahl Elemente zählen
set nItems to count items of artNumList

# die Indexliste initialisieren
set indexList to {}
# eine Schleife durch die Liste der Artikelnummern
repeat with n from 2 to nItems
# die aktuelle Artikelnummer
set curItem to item n of my artNumList
# wenn die Artikelnummer in der Liste der Namen ist ...
if curItem is in nameList then
# ... den aktuellen Index an die Liste anfügen
set end of indexList to n
end if
end repeat

# die Farbnamen-Liste initialisieren
set colList to {}
# eine Schleife durch die Indexliste
repeat with c from 1 to count of indexList
# der aktuelle Index
set curInd to item c of my indexList
# der entsprechende Farbname
set curCol to item curInd of my colNameList
# wenn dieser Name noch nicht in der Liste der Farben ist ...
if curCol is not in colList then
# ... die Liste damit ergänzen ...
set end of colList to curCol
end if
end repeat

# die Farbnamen zählen ...
set nColors to count colList
if nColors is greater than 1 then
# ... und den Handler aufrufen, welcher die Namen sortiert
quickSort(colList, 1, nColors)
end if

# den Dialog zum Wählen der Farbe anzeigen
set colorName to (choose from list colList without multiple selections allowed) as string
# falls Klick auf "Abbrechen": die Ausführung beenden
if colorName is "false" then error number -128

# die 'delimiters' definieren
set AppleScript's text item delimiters to "_"

# Variablen initialisieren
set noMatch to 0
set noCode to 0

# eine erneute Schleife durch die gedroppten Dateien
repeat with n from 1 to nFiles
set okay to false
set curFile to (item n of Dropped_Files)
tell application "Finder" to set curName to name of curFile
# der Name ohne Endung
set fullName to text 1 thru -5 of curName
# die Endung
set curSuf to text -4 thru -1 of curName
# der Stammname
set baseName to text item 1 of curName
# wenn dieser in der Liste der Artikelnummern ist ...
if baseName is in artNumList then
set sameName to false
set indList to {}
# ... eine Schleife durch die Artikelnummern-Liste
repeat with m from 2 to nItems
# die aktuelle Artikelnummer
set curItem to item m of my artNumList
# Übereinstimmung prüfen
if baseName is curItem then
set sameName to true
set end of indList to m
else
if sameName is true then exit repeat
end if
end repeat
set nInd to count of indList
repeat with c from 1 to nInd
set curInd to item c of indList
if item curInd of my colNameList is colorName then
# ... den Farbcode speichern
set curCode to item curInd of my colCodeList
set okay to true
exit repeat
end if
end repeat
if okay is true then
# den neuen Namen zusammensetzen
set newName to (fullName & "-" & curCode & "%" & colorName & curSuf) as string
# die Datei umbenennen
try
tell application "Finder" to set name of file curFile to newName
on error
set noCode to noCode + 1
try
tell application "Finder" to set label index of file curFile to 4
end try
end try
else
# kein Code gefunden: der Datei einen blauen Tag zuweisen
set noCode to noCode + 1
tell application "Finder" to set label index of file curFile to 4
end if
else
# Artikelnummer nicht im Exceldokument: der Datei einen roten Tag verpassen
set noMatch to noMatch + 1
tell application "Finder" to set label index of file curFile to 2
end if
end repeat

# die 'delimiters' zurücksetzen
set AppleScript's text item delimiters to {""}

# den Anwender informieren
set nProb to noCode + noMatch
if nProb is 0 then
display dialog "Fertig. Alle Dateien sind umbenannt." buttons "OK" default button 1 with icon 1 giving up after 2
else
if nProb is 1 then
display dialog "Achtung: Eine Datei ist nicht umbenannt." buttons "OK" default button 1 with icon 2
else
display dialog "Aufgepasst: " & nProb & " Dateien sind nicht umbenannt." buttons "OK" default button 1 with icon 2
end if
end if
end open

# der Handler zum Sortieren der Farbnamen
on quickSort(a, L, R)
script
property aList : a
end script
tell result
set ctr to L
set n to R
set aRef to item L of its aList
repeat while ctr < n
repeat while (aRef < item n of its aList) and (ctr < n)
set n to n - 1
end repeat
if n is not ctr then
set item ctr of its aList to item n of its aList
set ctr to ctr + 1
end if
repeat while (aRef > item ctr of its aList) and (ctr < n)
set ctr to ctr + 1
end repeat
if n is not ctr then
set item n of its aList to item ctr of its aList
set n to n - 1
end if
end repeat
set item n of its aList to aRef
if L < n then
quickSort(its aList, L, n - 1)
end if
if R > ctr then
quickSort(its aList, ctr + 1, R)
return its aList
end if
end tell
end quickSort

Gruss, Hans


als Antwort auf: [#563129]
Anhang:
Testdateien.zip (290 KB)
X