Ordnerstruktur aus Teil-Dateinamen erstellen

[Gast] Foren Programmierung/Entwicklung AppleScript Ordnerstruktur aus Teil-Dateinamen erstellen

Programmierung/Entwicklung

Themen

Beiträge

Moderatoren

Letzter Beitrag

AppleScript

1260

8218

Hans Haesler

8. Nov 2023, 13:38

mb_new

Klaus79

Beiträge gesamt: 341

7. Nov 2018, 16:47
Beitrag # 1 von 5
Bewertung:
(5772 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Forum,
ich bearbeite gerade mein erstes Applescript und bitte um Nachsicht wenn meine Fragen noch anfängerhaft sind.

Ich möchte Musiktitel in zu erstellende Ordner legen. Die Titel haben immer folgende Struktur:

Celtic Woman - May It Be.mp3
Everlast - This Kind of Lonely.mp3
Bryan Adams - Summer of '69.mp3
Everlast - Maybe.mp3
u.s.w.

Es sollten nun die Ordner Celtic Woman, Bryan Adams und Everlast angelegt und die Dateien in die jeweiligen Ordner verschoben werden. Folgendes Script habe ich bisher zusammengestellt:

tell application "Finder"
set theFolder to choose folder --Ordner mit den Dateien auswählen
set allFiles to every item of theFolder --alle Dateien im Ordner abfragen
repeat with theFile in allFiles
set theName to do shell script "name=\"" & name of theFile & "\"; echo ${name%.*}" --Den Namen der Datei ohne Endung abfragen
try
set newFolder to make new folder at theFolder with properties {name:theName} --neuen Ordner erstellen
end try
move theFile to newFolder --Datei verschieben
end repeat
display dialog "Fertig!"
end tell

Dabei habe ich noch zwei ungelöste Probleme. Zum einen wird der Ordnername bisher aus dem ganzen Dateinamen gebildet und nicht nur aus dem Interpreten, und zum zweiten müsste ein bereits angelegter Ordner erkannt und nicht doppelt angelegt werden.

Kann mir da jemand helfen?

Gruß
Klaus

Ordnerstruktur aus Teil-Dateinamen erstellen

Hans Haesler

Beiträge gesamt: 5826

7. Nov 2018, 17:55
Beitrag # 2 von 5
Beitrag ID: #567403
Bewertung:
(5754 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Klaus,

herzlich willkommen im AppleScript-Forum auf HDS! :-)

Nun, für ein erstes AppleScript ist das schon eine happige Aufgabe. Gratulation zu Deinem Versuch.

Ein paar Bemerkungen:
– 'choose folder' und 'display dialog' sind Befehle der "StandardAdditions" und nicht des "Finders".
Deshalb diese beiden Zeilen ausserhalb des tell-Finder-Blocks verschieben.
– Zum Auflisten der Dateien nicht 'item' benutzen, sondern 'file'. Sonst werden bestehende Ordner auch erfasst.
– Zum Ausziehen des zukünftigen Ordnernamens die 'AppleScript's text item delimiters' einsetzen.
Wenn diese als " - " bestimmt werden, kann das erste Text-Element herausgelöst und einer Variablen zugewiesen werden.
– Die Prüfung 'if not (exists folder folName of folder theFolder)' stellt sicher, dass bei bestehendem Ordner nicht versucht wird, einen zweiten anzulegen.
– Wenn der neue Ordner erstellt ist, wird die Datei hineinverschoben.
– Diese Aktion ist in einem 'try'-Wickel, um zu vermeiden, dass es eine Fehlermeldung absetzt, wenn eine gleichnamige Datei schon vorhanden ist.
– Wenn der Ordner schon existiert, wird die Datei in diesen verschoben.

Code

set theFolder to choose folder # Ordner mit den Dateien auswählen 
 
set AppleScript's text item delimiters to " - " # den Trenner bestimmen 
 
tell application "Finder" 
  set allFiles to every file of theFolder # alle Dateien im Ordner abfragen   
  repeat with theFile in allFiles 
    set theName to name of theFile # der Name der Datei 
    set folName to text item 1 of theName # das erste Text-Element des Namens 
    if not (exists folder folName of folder theFolder) then 
      set newFolder to make new folder at theFolder with properties {name:folName} # neuen Ordner erstellen 
      try 
        move theFile to newFolder # Datei verschieben 
      end try 
    else 
      try 
        move theFile to folder folName of folder theFolder # Datei verschieben 
      end try 
    end if 
    try 
    end try 
  end repeat 
end tell 
 
set AppleScript's text item delimiters to {""} # den Trenner zurücksetzen 
 
display dialog "Fertig!" buttons "OK" default button 1 with icon 1 giving up after 1

Hier funktioniert es wie erwartet. Hoffentlich bei Dir auch.

Gruss, Hans

als Antwort auf: [#567402]

Ordnerstruktur aus Teil-Dateinamen erstellen

Klaus79

Beiträge gesamt: 341

7. Nov 2018, 18:49
Beitrag # 3 von 5
Beitrag ID: #567407
Bewertung:
(5744 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Wow Hans, funktioniert einwandfrei! Herzlichen Dank!
Das erspart mir eine Menge an Arbeit.

Bei meiner Recherche war ich auch auf delimiters gestoßen, aber die Syntax war mir natürlich nicht geläufig. Ich komme mehr von Excel und VBA (als Hobby).

Gibt es auch noch die Möglichkeit das Ganze als Droplet zu speichern? Bisher habe eine App erstellt, aber irgendwo etwas von "on open" gelesen, aber nicht umsetzen können. Wäre aber nicht so wichtig, ich bin mit diesem Ergebnis schon vollauf zufrieden!

Herzlichen Dank noch einmal, Hans.

Gruß
Klaus

als Antwort auf: [#567403]

Ordnerstruktur aus Teil-Dateinamen erstellen

Hans Haesler

Beiträge gesamt: 5826

7. Nov 2018, 19:18
Beitrag # 4 von 5
Beitrag ID: #567408
Bewertung:
(5734 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Klaus,

bitte sehr. Super, dass es auf Anhieb klappte.

Ein Droplet? Das wollte ich Dir vorschlagen. Bitte, hier:

Code

(*MusikOrdner.app 
Zum Einordnen von Musik-Dateien 
*) 
 
on open droppedFolder 
  set theFolder to item 1 of droppedFolder as Unicode text # der gedroppte Ordner 
  set AppleScript's text item delimiters to " – " # den Trenner bestimmen 
   
  tell application "Finder" 
    set allFiles to every file of folder theFolder # alle Dateien im Ordner abfragen   
    repeat with theFile in allFiles 
      set theName to name of theFile # der Name der Datei 
      set folName to text item 1 of theName # das erste Text-Element des Namens 
      if not (exists folder folName of folder theFolder) then 
        set newFolder to make new folder at theFolder with properties {name:folName} # neuen Ordner erstellen 
        try 
          move theFile to newFolder # Datei verschieben 
        end try 
      else 
        try 
          move theFile to folder folName of folder theFolder # Datei verschieben 
        end try 
      end if 
      try 
      end try 
    end repeat 
  end tell 
   
  set AppleScript's text item delimiters to {""} # den Trenner zurücksetzen 
   
  display dialog "Fertig!" buttons "OK" default button 1 with icon 1 giving up after 1 
end open

Dieses Script – im Format "Programm" gespeichert –, ist gezippt unten angehängt.

Zur Ausführung: Den Ordner, welcher die Dateien enthält, auf das Icon des Droplets ziehen.
Der Ordner kann schon benannte Ordner enthalten. Dateien werden im entsprechenden Ordner versorgt. Oder in einem neuen, welcher angelegt wird.

Gruss, Hans

als Antwort auf: [#567407]

Anhang:

MusikOrdner.zip (56.4 KB)

Ordnerstruktur aus Teil-Dateinamen erstellen

Klaus79

Beiträge gesamt: 341

7. Nov 2018, 20:07
Beitrag # 5 von 5
Beitrag ID: #567410
Bewertung:
(5721 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen

Hallo Hans,

was soll ich dazu noch sagen. Einfach PERFEKT!
Das können bestimmt auch noch andere Leute gut gebrauchen.

Vielen Dank auch für Deine Anmerkungen zum Scripten.
Ich werde zwar wohl nicht mehr der große Applescripter werden,
aber wer weis ...

Eine schöne Restwoche für Dich
Danke

Klaus

als Antwort auf: [#567408]

Aktuell

PDF / Print

NEU: PitStop 2024.03 verfügbar!

| 16.04.2024

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen

17.04.2024

Und es geht doch: Automatisierung im Großformatdruck!

Online
Mittwoch, 17. Apr. 2024, 10.00 - 10.30 Uhr

Webinar

Komplizierte, kleinteilige Aufträge; alles sehr speziell; seit Jahren bewährte Prozesse – da können wir nichts standardisieren und automatisieren! Das sagen viele Großformatdrucker – aber stimmt das wirklich, ist dem tatsächlich so? Günther Business Solutions und Impressed treten in einem Webinar den Gegenbeweis an. Experten beider Unternehmen zeigen, wie Großformatdrucker vom Einsatz zweier bewährter Lösungen profitieren können: • von advanter print+sign von Günther Business Solutions, dem ERP-System für den Großformatdruck, dass alle Phasen der Wertschöpfung im Large Format Printing abdeckt • von Impressed Workflow Server, der smarten PDF-Workflow-Lösung für Druckereien, die Datenmanagement, Preflight und Produktionssteuerung übernimmt Über die Kombination beider Lösungen können Großformatdrucker ihre Prozesse mit modernen Workflows Schritt für Schritt automatisieren – und so zügig deutliche Zeit- und Kosteneinsparungen realisieren. Das Webinar sollten Sie sich nicht entgehen lassen – damit Sie keine Effizienzpotenziale mehr liegen lassen. Melden Sie sich am besten gleich an, wir freuen uns auf Sie! PS: Melden Sie sich in jedem Fall an – sollten Sie zum Termin verhindert sein, erhalten Sie die Aufzeichnung.

kostenlos

Organisator: Impressed / Günther Business Solutions

https://www.impressed.de/schulung.php?c=sDetail&sid=326

Und es geht doch: Automatisierung im Großformatdruck!

Weitere Events

Neuste Foreneinträge

Eizo Monitorkalibrierung auf Windows

Fußnoten zu Endnoten konvertieren

Mehrfach geschichtete und übereinander gelagerte PDFs bereinigen

Platzierte Vektorgrafiken skalieren

SMS ab Server senden? Wie geht das?

WebShare Verzeichnisse im SharePoint erstellen

Buchsrabensteuerung

Klickbare Links zu Seiten in einem Buch aus extern erzeugtem Index erstellen

Gleiche Ebene mit untersch. Fonts in Text + autom. IHVZ: Probleme mit Kursivierung

Javascript zur Kursivierung von Klammern mit Variabler

Weitere Stellenangebote