------------------------------------------------------------------------------------------------------------------------------------- 
on Initialize() 
	set my text item delimiters to "" 
end Initialize 
 
on Finalize() 
	with timeout of 14400 seconds -- 4 Stunden 
		activate 
		display alert "Fertig" message "Objekt(e) wurde(n) verarbeitet." 
	end timeout 
end Finalize 
 
on ProcessAFileOrFolder(theFile) 
	if (theFile as text) ends with ":" then 
		ScanAFolder(theFile) 
	else 
		ProcessAFile(theFile) 
	end if 
end ProcessAFileOrFolder 
 
on ScanAFolder(theFolder) 
	set fileNames to list folder theFolder without invisibles 
	repeat with aFile in fileNames 
		set theFile to (theFolder as text) & contents of aFile 
		ProcessAFileOrFolder(alias theFile) 
	end repeat 
end ScanAFolder 
 
on open of filesList 
	my Initialize() 
	repeat with aFile in filesList 
		ProcessAFileOrFolder(contents of aFile) 
	end repeat 
	my Finalize() 
end open 
 
on run 
	activate 
	display alert "ACHTUNG!" message "Läuft nur als Droplet. Bitte Objekt(e) auf das Script ziehen." as warning 
end run 
------------------------------------------------------------------------------------------------------------------------------------- 
on ProcessAFile(aFile) 
	tell application "Finder" to set fileName to (name of aFile) as string 
	set fileNameNew to (characters 1 thru 7 of fileName) & (characters -1 thru -4 of fileName) as string 
	tell application "Finder" to set name of aFile to fileNameNew 
end ProcessAFile 
-------------------------------------------------------------------------------------------------------------------------------------