on adding folder items to hotFolder after receiving itemList 
  set targetFolder to "server_x:online:" 
  try 
    targetFolder as alias 
  on error 
    with timeout of 300 seconds 
      set targetFolder to (choose folder with prompt ¬ 
        "Einen Zielordner für die Dateien wählen.") as Unicode text 
    end timeout 
  end try 
  repeat with aFile in itemList 
    set AppleScript's text item delimiters to ":" 
    set filePath to aFile as Unicode text 
    set baseName1 to text 1 thru 2 of (text item -3 of filePath) 
    set baseName2 to text item -2 of filePath 
    set oldName to text item -1 of filePath 
    set AppleScript's text item delimiters to "." 
    if (count of text items of oldName) is greater than 1 then 
      set baseName3 to text items 1 thru -2 of oldName 
      set curSuff to "." & (text item -1 of oldName) 
    else 
      set baseName3 to oldName 
      set curSuff to "" 
    end if 
    set newName to baseName1 & "_" & baseName2 & "_" & baseName3 
    if (count of newName) is greater than 27 then 
      set newName to (text 1 thru 27 of newName) & curSuff 
    else 
      set newName to newName & curSuff 
    end if 
    try 
      tell application "Finder" to duplicate file aFile to folder targetFolder with replacing 
      try 
        tell application "Finder" to set name of file oldName of folder targetFolder to newName 
      end try 
      try 
        tell application "Finder" to delete file aFile 
      end try 
    end try 
  end repeat 
  set AppleScript's text item delimiters to {""} 
end adding folder items to 

posix file ""