[GastForen Programmierung/Entwicklung AppleScript pdf-Dateien aneinanderhängen

  • Suche
  • Hilfe
  • Lesezeichen
  • Benutzerliste
Themen
Beiträge
Moderatoren
Letzter Beitrag

pdf-Dateien aneinanderhängen

Goar
Beiträge gesamt: 389

14. Jun 2004, 16:16
Beitrag # 1 von 16
Bewertung:
(3192 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Skripter,

da möchte ich nur mal eben sehen, ob man per AS alle pdf in einem Ordner aneinanderhängen kann, da bleibe ich wieder bei application "Acrobat™ 4.05" hängen.
Es ist ein umgebautes Script aus dem Kochbuch, mit dem Ordnerinhalte bearbeitet werden können:
---
on OpenFirstFile(firstFile)
 tell application "Acrobat™ 4.05"
  open firstFile
 end tell
end OpenFirstFile

on ProcessAFile(firstFile, theFile)
 set theFileInfo to info for theFile
    tell application "Acrobat™ 4.05"
     insert pages firstFile after -1 from theFile starting with 1 -- s.u.
    end tell
end ProcessAFile

on ScanAFolder(theFolder)
 -- unsichtbare Dateien werden nicht berücksichtigt
 set fileNames to list folder theFolder without invisibles
  set firstFile to (theFolder as string) & contents of item 1 of fileNames -- kompletter Pfad
 OpenFirstFile(firstFile)
  -- hier wolle ich es erst einmal mit EINER Anhängung versuchen
 -- repeat with m from 2 to count of items of fileNames
 set theFile to (theFolder as string) & contents of item 2 of fileNames -- kompletter Pfad
  ProcessAFile(alias firstFile, theFile)
 -- end repeat
end ScanAFolder

on run
 set theFolder to choose folder with prompt "Ordner auswählen:"
  ScanAFolder(theFolder)
end run
---
In der bezeichneten Zeile meint AS: access not allowed, gemeint ist der Zugriff auf firstFile. Dabei ist es gleich, ob firstFile geöffnet ist oder nicht.
Mehr Varianten sind mir nicht eingefallen.
Weiß jemand, wo der Haken liegt?

Gruß, Goar
X

pdf-Dateien aneinanderhängen

Hans Haesler
  
Beiträge gesamt: 5816

15. Jun 2004, 10:09
Beitrag # 2 von 16
Beitrag ID: #418829
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Goar,

ich habe kurz versucht, den Befehl zum Seiteneinfügen hinzubiegen. Aber erstens sind meine Acrobat-Script-Kenntnisse sehr beschränkt und zweitens bin ich schon halb im Urlaub. :-)

Damit Du gleichwohl ein funktionierendes Script bekommst, habe ich ein bestehendes genommen und angepasst. Als Applikation speichern, dann wird es zum Droplet. Das Script erwartet, dass nur die zu mergenden PDF-Dateien auf das Icon gezogen werden. Keine Ordner. Der Dialog schlägt einen Namen für die neue PDF-Datei vor. Dann werden die Dateien sortiert. Die erste wird an den Anfang gestellt und die weiteren der Reihe nach angehängt.
---
on open fileList
  set fileCount to (count of fileList)
  set newFile to choose file name with prompt "Name der neuen PDF-Datei:" default name "Datei" & fileCount & ".pdf"
  tell application "Acrobat™ 4.05a"
    activate
  end tell
  tell application "Finder"
    set fileList to (sort fileList by name) as alias list
    set doc1 to name of item 1 of fileList
  end tell
  tell application "Acrobat™ 4.05a"
    open (item 1 of fileList) with invisible
    set fileList to rest of fileList
    repeat with afile in fileList
      tell application "Finder" to set doc2 to name of afile
      try
        set pageCount to count each PDPage of document doc1
        open afile with invisible
        set pageCount2 to count each PDPage of document doc2
        insert pages document doc1 from document doc2 starting with 1 number of pages pageCount2 after pageCount
        close document doc2 saving no
      end try
    end repeat
    save document doc1 to newFile with linearize
    display dialog "Fertig."
  end tell
end open
---

Falls es Dir (wider Erwarten ;-) nicht gelingen sollte, das Script so umzuschreiben, dass es den Inhalt eines Ordners verwertet, dann werde ich es versuchen. Aber erst anfangs Juli.

Hans Haesler <[email protected]>


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Goar
Beiträge gesamt: 389

30. Jun 2004, 14:47
Beitrag # 3 von 16
Beitrag ID: #418830
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

mit dem Droplet hast Du mir viel Freude gemacht. Dort befand sich nämlich sämtliches Knowhow, was in meinem Kopf für diese Aufgabe noch fehlte. Und ich fand es spannend, mein Script anzupassen.

Dabei wurde mir auch der unterschiedliche Ansatz klar:
Das Droplet hat für jede Datei den kompletten Pfad und holt sich über den Finder nach Bedarf den Dateinamen daraus.
Mein Script hat den Ordnerpfad und die Namen aller im Ordner befindlichen Dateien. So wird hier nach Bedarf (und ohne Finder) der komplette Pfad zusammengesetzt.

Bei der Überarbeitung habe ich dann noch alle Handler geschleift; das Ganze ist jetzt deutlich überschaubarer. Und ein Test mit 10 pdf (ca. um die 100 kb) lief so schnell, in der Zeit hätte ich manuell gerade das zweite an das erste pdf angehängt.

So sieht das Script jetzt aus:

---
on run
 set theFolder to choose folder with prompt "Ordner auswählen:"
 -- unsichtbare Dateien werden nicht berücksichtigt
 set fileNames to list folder theFolder without invisibles -- alle Dateinamen
 set newFile to (theFolder as string) & text returned of (display dialog &not;
  "Name der neuen PDF-Datei:" default answer "Gesamtdatei.pdf" buttons {"Abbruch", "OK"} default button 2)
 -- set doc1 to item 1 of fileNames -- contents of item 1 of fileNames
 set firstFile to (theFolder as string) & (item 1 of fileNames) -- kompletter Pfad
 tell application "Acrobat&#153; 4.05"
  activate
  open firstFile with invisible -- offene Datei ist nicht sichtbar
  repeat with m from 2 to count of items of fileNames
   set theFile to (theFolder as string) & item m of fileNames -- kompletter Pfad
   try
    set countPages to count each PDPage of document (item 1 of fileNames)
    open theFile with invisible
    set countPages2 to count each PDPage of document (item m of fileNames)
    insert pages document (item 1 of fileNames) from document (item m of fileNames) &not;
     starting with 1 number of pages countPages2 after countPages
    close document (item m of fileNames) saving no
   end try
  end repeat
  save document (item 1 of fileNames) to newFile with linearize
  display dialog "Fertig."
 end tell
end run
---
Danke, Goar


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Hans Haesler
  
Beiträge gesamt: 5816

1. Jul 2004, 16:29
Beitrag # 4 von 16
Beitrag ID: #418831
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Goar,

bitteschön. Super, dass Du es alleine geschafft hast!

N.-B.: Das 'on run' / 'end run' ist nicht notwendig, weil ein unsichtbarer 'run'-Handler schon definiert ist.
Man gebraucht diese Bezeichnung aber meistens, wenn daneben noch ein 'open'-Handler besteht.

Hans Haesler <[email protected]>


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Anonym
Beiträge gesamt: 22827

1. Okt 2004, 19:56
Beitrag # 5 von 16
Beitrag ID: #418832
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Goar, hallo Hans,

nur ne Frage:
existiert so ein Script auch für OS-X / Acrobat 6.01

Gruesse
willem


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Hans Haesler
  
Beiträge gesamt: 5816

1. Okt 2004, 21:41
Beitrag # 6 von 16
Beitrag ID: #418833
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

leider habe ich "Acrobat 6.01" nicht zur Hand. Aber ich habe heute ein Upgrade auf die Creative Suite
bestellt. Bis ich dieses Paket erhalten habe, muss ich mich mit der Lizenz unserer Anzeigenabteilung
behelfen. Aber es wird Montag, bevor ich die Sache prüfen kann.

Aber was man so von der Scriptfähigkeit von "Acrobat 6.01" hört, stimmt nicht sehr zuversichtlich &#133;
Erst heute hat sich wieder ein Teilnehmer (und zwar ein sehr versierter) der AS-users-Liste bitterlich beklagt!

Hans Haesler <[email protected]>


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Anonym
Beiträge gesamt: 22827

2. Okt 2004, 12:34
Beitrag # 7 von 16
Beitrag ID: #418834
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

wenns nicht funktioniert ist es nicht weiter tragisch, ich kann unter Acrobat 6 die ausgewählten PDFs ins Thubnail-Fenster ziehen, nur die Seitenfolge wird so nicht sortiert, d.h. Acr6 scheint willkürlich einzufügen.

Trotzdem vielen Dank
willem


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Martin Fischer
Beiträge gesamt: 12623

12. Okt 2004, 16:56
Beitrag # 8 von 16
Beitrag ID: #418835
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Um PDF-Dateien in einem Ordner mit Acro 6 zusammenzuführen, habe ich einen Versuch gemacht, der in http://www.hilfdirselbst.ch/...4&topic_id=24002 zu finden ist.

Allerdings wurde ich darauf hingewiesen, daß Acrobat 6 die Zusammenführung selbst anbietet:
Zitat Datei->PDF erstellen-> aus mehreren Dateien erstellen
oder
Erstes PDF öffnen->Dokument->Seiten einfügen->alle PDFs auswählen und einfügen


Ich habe mein Script zwar ausgebaut, aber es ist so langsam, daß ich die o.g. Acrobat-eigene Lösung für zweckmäßiger halte. Allerdings wird hier nicht sortiert. ;-)

Bei meiner AS-Lösung hat mich gestört, daß die einzufügenden PDF-Dateien erst in Acrobat 6 geöffnet werden mußten. Will mal sehen ob ich mit Hilfe des Acrobat 4-Scripts eine Lösung finde, wie ich die Datei direkt anfüge.


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Martin Fischer
Beiträge gesamt: 12623

13. Okt 2004, 23:34
Beitrag # 9 von 16
Beitrag ID: #418836
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Zitat von willem nur ne Frage:
existiert so ein Script auch für OS-X / Acrobat 6.01

Das obige Script läuft auch auf OS X mit Acrobat 6.0.2.
Du mußt nur die Zeile
[code:1]tell application "Acrobat&#153; 4.05"[/code:1]
durch die Zeile
[code:1]tell application "Acrobat 6.0.2 Professional"[/code:1]
ersetzen.

Und wenn Du die Zeile
[code:1]save document &#40;item 1 of fileNames&#41; to newFile with linearize[/code:1]
auskommentierst oder statt "newFile" einen festen Dateinamen (in Anführungszeichen" reinschreibst, dann klappt das Ganze.

Denn mit dieser letzten Zeile habe ich Probleme: Acrobat meldet daß die erste Datei den Befehl save nicht verstehe. Das versteht sie aber nur solange nicht, bis "newFile" entweder ganz auskommentiert oder durch einen festen Dateinamen ersetzt wird.

Weiß der Teufel, warum.
Die Syntax für SAVE hat sich in Acrobat 6 nicht geändert.
Und ich hab mit SMILE die Variablen immer wieder überprüft und für richtig befunden.

Allerdings ist dieses Applescript für Acrobat 6 nicht mehr so dringend nötig, denn Acrobat 6 ist selbst in der Lage, PDF-Dateien zusammenzufügen.


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Martin Fischer
Beiträge gesamt: 12623

14. Okt 2004, 08:48
Beitrag # 10 von 16
Beitrag ID: #418837
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Zitat von MartinF Und wenn Du die Zeile
[code:1]save document &#40;item 1 of fileNames&#41; to newFile with linearize[/code:1]
auskommentierst oder statt "newFile" einen festen Dateinamen (in Anführungszeichen" reinschreibst, dann klappt das Ganze.


Da gab's wohl doch ne kleine Änderung von Acrobat 4 auf Acrobat 6.

Schreibe statt
[code:1]save document &#40;item 1 of fileNames&#41; to newFile with linearize[/code:1]
[code:1]save document &#40;item 1 of fileNames&#41; to file newFile with linearize[/code:1]
(Es braucht also vor "newFile" das Wörtchen "file" -> "file NewFile")


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Hans Haesler
  
Beiträge gesamt: 5816

14. Okt 2004, 09:40
Beitrag # 11 von 16
Beitrag ID: #418838
Bewertung:
(3192 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Martin,

nun ... ich habe keine Probleme mit der Zeile 'save document doc1 to newFile with linearize'.

Aber der Befehl 'set fileList to (sort fileList by name) as alias list' mit welchem der Finder die Liste der Pfade
sortieren soll, löst eine Fehlermeldung aus. Vielleicht ist das Sortieren in Mac OS 10.3.5 möglich.
Aber im 10.3.4, welches ich benutze, steht im Verzeichnis: (NOT AVAILABLE YET).

Ich habe deshalb einen QuickSort-Handler eingebaut. Und dieses Script funktioniert:
---
on open fileList
  set fileCount to (count of fileList)
  set newFile to choose file name with prompt "Name der neuen PDF-Datei:" default name "Datei" & fileCount & ".pdf"
  tell application "Acrobat 6.0 Professional"
    activate
  end tell
 
  set stringList to {}
  repeat with i from 1 to fileCount
    set end of stringList to (item i of fileList) as string
  end repeat
  set fileList to my quickSort(stringList, 1, fileCount)
 
  tell application "Finder" to set doc1 to name of ((item 1 of fileList) as alias)
 
  tell application "Acrobat 6.0 Professional"
    open (item 1 of fileList) with invisible
    set fileList to rest of fileList
    repeat with aFile in fileList
      tell application "Finder" to set doc2 to name of (aFile as alias)
      try
        set pageCount to count each PDPage of document doc1
        open aFile with invisible
        set pageCount2 to count each PDPage of document doc2
        insert pages document doc1 from document doc2 starting with 1 number of pages pageCount2 after pageCount
        close document doc2 saving no
      end try
    end repeat
    save document doc1 to newFile with linearize
    display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
  end tell
end open

on quickSort(a, L, R)
  script
    property aList : a
  end script
  tell result
    set ctr to L
    set n to R
    set aRef to item L of its aList
    repeat while ctr < n
      repeat while (aRef < item n of its aList) and (ctr < n)
        set n to n - 1
      end repeat
      if n is not ctr then
        set item ctr of its aList to item n of its aList
        set ctr to ctr + 1
      end if
      repeat while (aRef > item ctr of its aList) and (ctr < n)
        set ctr to ctr + 1
      end repeat
      if n is not ctr then
        set item n of its aList to item ctr of its aList
        set n to n - 1
      end if
    end repeat
    set item n of its aList to aRef
    if L < n then
      quickSort(its aList, L, n - 1)
    end if
    if R > ctr then
      quickSort(its aList, ctr + 1, R)
    end if
    return its aList
  end tell
end quickSort
---
Das Wörtchen 'file' brauche ich demnach nicht. Kann aber auch sein, dass mir die Scripting Addition "Jon's Commands.osax" reinfunkt.

Hans Haesler <[email protected]>


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Martin Fischer
Beiträge gesamt: 12623

14. Okt 2004, 22:04
Beitrag # 12 von 16
Beitrag ID: #418839
Bewertung:
(3192 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Hans,

Zitat von Hans Haesler nun ... ich habe keine Probleme mit der Zeile 'save document doc1 to newFile with linearize'.

Du hast wahrscheinlich ein anderes Workaround als ich.
Hab mich bislang nicht über die Bordmittel von AppleScript und Smile hinausgewagt.

Zitat Aber der Befehl 'set fileList to (sort fileList by name) as alias list' mit welchem der Finder die Liste der Pfade
sortieren soll, löst eine Fehlermeldung aus. Vielleicht ist das Sortieren in Mac OS 10.3.5 möglich.
Aber im 10.3.4, welches ich benutze, steht im Verzeichnis: (NOT AVAILABLE YET).

Um die Sortierung hatte ich mich gar nicht gekümmert, nachdem's bei mir stets alphabethisch sortiert war (im Gegensatz zur Acrobat 6 eigenen Lösung zur Zusammenfügung der PDFs).

Zitat Ich habe deshalb einen QuickSort-Handler eingebaut.

Wow!
Den QuickSort-Handler hast Du aber nicht nur für die PDF-Vereinigung aus dem Ärmel gezogen ...
Da wird mir ganz schwindelig, wenn ich den versuche nachzuvollziehen.
Klasse!

Zitat Und dieses Script funktioniert:


Nachdem ich's bei mir umgebaut habe, funktionierts bei mir auch.

Wie kommt es, daß Du mit einem Handler anfängst?
Zitat on open fileList
  set fileCount to (count of fileList)
  set newFile to choose file name with prompt "Name der neuen PDF-Datei:" default name "Datei" & fileCount & ".pdf"
  tell application "Acrobat 6.0 Professional"
    activate
  end tell
  (...)

Hängt das mit Deiner Entwicklerumgebung zusammen?
Ich arbeite ganz simpel mit dem ScriptEditor (und mit Smile).

Dafür mußte ich die Einleitung folgendermaßen umbauen:
[code:1]
set theFolder to choose folder with prompt "Choose Folder&#58;"
-- no invisible files
set fileList to list folder theFolder without invisibles -- all files

set fileCount to &#40;count of fileList&#41;
set newFile to choose file name with prompt "Name der neuen PDF-Datei&#58;" default name "Datei" & fileCount & ".pdf"
tell application "Acrobat 6.0.2 Professional"
 activate
end tell

set stringList to &#123;&#125;
repeat with i from 1 to fileCount
 set end of stringList to &#40;theFolder as string&#41; & &#40;item i of fileList&#41; as string
end repeat
set fileList to my quickSort&#40;stringList, 1, fileCount&#41;

tell application "Finder" to set doc1 to name of &#40;&#40;item 1 of fileList&#41; as alias&#41;

tell application "Acrobat 6.0.2 Professional"
 open &#40;item 1 of fileList&#41; with invisible
 set fileList to rest of fileList
 repeat with aFile in fileList
  tell application "Finder" to set doc2 to name of &#40;aFile as alias&#41;
  try
   set pageCount to count each PDPage of document doc1
   open aFile with invisible
   set pageCount2 to count each PDPage of document doc2
   insert pages document doc1 from document doc2 starting with 1 number of pages pageCount2 after pageCount
   close document doc2 saving no
  end try
 end repeat
 save document doc1 to newFile with linearize
 display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end tell

&#40;... weiter mit "on quickSort&#40;a,L,R&#41;"&#41;
[/code:1]


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Hans Haesler
  
Beiträge gesamt: 5816

15. Okt 2004, 08:36
Beitrag # 13 von 16
Beitrag ID: #418840
Bewertung:
(3192 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Martin,

nein, ich habe eine "gewöhnliche" Arbeitsumgebung. Apple's Script Editor und sonst nichts.

Aber wir haben nicht dasselbe Script ausprobiert. Du hast mit der Version von Goar gepröbelt,
während ich das von mir gepostete Script wählte. Das Script von Goar fordert den Anwender auf,
einen Ordner zu wählen. Meine Version ist ein Droplet. Deshalb der Handler zu Beginn. Der Vorteil
des Droplets: Man kann die PDF-Dateien im Finder darauf ziehen. Und muss sich nicht im Dialog
zum Ordner durchhangeln.

Die QuickSort-Routine ist nicht meine Erfindung. Dies ist übrigens die Turbo-Version. Es gibt eine
langsamere. Die schnelle hat den Vorteil, dass sie wirklich schnell ist. Aber in gewissen Fällen
habe ich damit Probleme gehabt. Das Resultat war leer. Ich muss mal versuchen, dies nachzustellen.

Hans Haesler <[email protected]>


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Anonym
Beiträge gesamt: 22827

15. Okt 2004, 23:01
Beitrag # 14 von 16
Beitrag ID: #418841
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Forum,

die Version von Hans klappt unter OS-X einwandfrei,
zuerst dachte ich es tut sich nichts - bis dann die Meldung "Fertig" kam, und alle PDFs waren in 1Ziel-Dokument zusammengefasst.

Gruss willem


als Antwort auf: [#418828]

pdf-Dateien aneinanderhängen

Hans Haesler
  
Beiträge gesamt: 5816

15. Okt 2004, 23:38
Beitrag # 15 von 16
Beitrag ID: #418842
Bewertung:
(3191 mal gelesen)
URL zum Beitrag
Beitrag als Lesezeichen
Hallo Willem,

danke für die Rückmeldung! Ja, alles geschieht im Hintergrund ('open aFile with invisible').
Und diese Unsichtbarkeit lässt einen glauben, dass nichts geschieht &#133;

Ich werde versuchen, einen Fortschrittsbalken einzubauen. Damit hat man wenigstens eine
optische Anzeige und wird auf dem laufenden gehalten.

Hans Haesler <[email protected]>


als Antwort auf: [#418828]
X

Aktuell

Veranstaltungskalender

Hier können Sie Ihre Anlässe eintragen, welche einen Zusammenhang mit den Angeboten von HilfDirSelbst.ch wie z.B. Adobe InDesign, Photoshop, Illustrator, PDF, Pitstop, Affinity, Marketing, SEO, Büro- und Rechtsthemen etc. haben. Die Einträge werden moderiert freigeschaltet. Dies wird werktags üblicherweise innert 24 Stunden erfolgen.

pdf-icon Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.

Veranstaltungen
29.09.2022

IDUGS#85 Press2id

Zoom Meeting
Donnerstag, 29. Sept. 2022, 19.00 - 21.00 Uhr

Vortrag

Kennst du WordPress? Vielleicht. Verwendest du WordPress? Ja, klar! WordPress ist das am weitesten verbreitete System für die Erstellung von Webseiten. Um Webseitenbau soll es auf dieser IDUG aber nicht gehen. Gregor zeigt press2id (github.com/grefel/press2id). Seine Open-Source-Lösung für die Verbindung von Web und InDesign. Richtig gelesen: InDesign liest mithilfe von press2id die Inhalte der WordPress-Webseiten und generiert daraus Zeitschriften, Kataloge, Programmhefte oder Bierdeckel (das zeigen wir natürlich auch!). So wird die „Content First“ Theorie zu einer konkret anwendbaren Praxis, ohne gleich die ganz großen Räder zu drehen. Versprochen: Jeder kann nach der IDUG innerhalb kürzester Zeit Daten von WordPress nach InDesign importieren. Aber Achtung: Prinzipiell kann press2id aus jeder Website, oder besser Contentmanagementsystem (CMS) Daten auslesen und nach InDesign importieren! Spannend, oder? Danach geht es in die Praxis: Stefan hat die Webseite des Parktheater Iserlohn (parktheater-iserlohn.de) gestaltet. Die gedruckten Spielpläne (parktheater-iserlohn.de/interaktive-spielplaene) werden mit press2id realisiert. Wir schauen in den Maschinenraum und zeigen, wie die Lösung des Projekts realisiert wurde.

Nein

Organisator: InDesign Usergroup Stuttgart

Kontaktinformation: Christoph Steffens, E-Mailidug AT satzkiste DOT de

https://idugs85.eventbrite.de/

Von Wordpress nach InDesign
Veranstaltungen
08.11.2022

Frankfurt, Fraport Conference Center
Dienstag, 08. Nov. 2022, 13.30 - 18.00 Uhr

Seminar

Auf der Enfocus World Tour stellen wir Ihnen gemeinsam mit Enfocus die aktuellen Highlights von Enfocus Switch und dem Impressed Workflow Server (IWS) vor. Wir präsentieren Ihnen anhand typischer Aufgabenstellungen in einem modernen Produktionsbetrieb die Möglichkeiten, die Enfocus Switch für die Automatisierung und Standardisierung von Abläufen bietet. Wir haben sowohl für Produktionsverantwortliche als auch technisch Interessierte ein spannendes Programm vorbereitet, bei dem Sie sicherlich viel Neues erfahren werden, welches Sie in Ihrem eigenen Betrieb umsetzen können. Die Veranstaltung bietet darüber hinaus eine hervorragende Möglichkeit, sich mit anderen Anwendern und Workflow-Spezialisten auszutauschen und Antworten auf konkrete Aufgabenstellungen zu erhalten, welche Sie mit Hilfe von Enfocus Switch/IWS umsetzen möchten.

Wir sind jeweils an 2 Tagen in Frankfurt, Hamburg und München vor Ort. Der erste (halbe) Tag richtet sich in erster Linie an Betriebsleiter und Produktionsverantwortliche in Druckereien - ist also weniger technisch orientiert - sondern gibt einen Überblick zu den heutigen Möglichkeiten einer automatisierten Produktion.

Der zweite Tag (Switch Anwender-Treffen) richtet sich an bestehende Switch-Anwender und Administratoren.

Anmeldung und weitere Infos: https://www.impressed.de/schulung.php?c=sDetail&sid=310

Ja

Organisator: Enfocus/Impressed

Kontaktinformation: Silvia Noack, E-Mailsnoack AT impressed DOT de

https://www.impressed.de/schulung.php?c=sDetail&sid=310

Enfocus World Tour 2022