Nummer 1 bis 100 sind drin.
Den Rest mußt du erledigen:
-- karten.as
-- InDesign CS
-- MAC OS 10.3.x
-- fragt erst ein paar pParameter
-- und legt dann neues Dokument an
tell application "InDesign CS"
set myVorspan to "[Nr. "
set myNachspan to "]"
set myNumber to 0
--Reihen, Zeilen und Karten - Umfangsberechnung
set myRowsDef to 4
set myColumnsDef to 2
set myMaxNumberDef to 100
--Gespräche über ein paar grundsätzliche Fragen
set myRowsCount to text returned of (display dialog "Anzahl der Reihen: " default answer myRowsDef)
set myColumnsCount to text returned of (display dialog "Anzahl der Spalten: " default answer myColumnsDef)
set myMaxNumber to text returned of (display dialog "Höchste Nummer: " default answer myMaxNumberDef)
set myKarten to myRowsCount * myColumnsCount
set myPageRange to (myMaxNumber / myKarten + 0.5) as integer
--Seiteneinrichtung - hier DIN A3
set myPageWidth to 297
set myPageHeight to 420
--Textboxhöhe, Textboxbreite
set myBoxHeight to myPageHeight / myRowsCount
set myBoxWidth to myPageWidth / myColumnsCount
-- erzeuge neues Dokument
set myDocument to make document
tell myDocument
--gib dem Dokument ein paar Eigenschaften
tell document preferences
set page height to myPageHeight
set page width to myPageWidth
set page orientation to portrait
set pages per document to myPageRange
end tell
--Ränder
tell margin preferences of pages
set bottom to 0
set top to 0
set left to 0
set right to 0
end tell
--paar Eigenschaften des Rahmens
set myColor to swatch "Black"
set myVersatz to {10, 10, 0, 0} as list
--Absatzstil
try
set myParaStyle to make paragraph style with properties {name:"Nummern", applied font:"Adobe Caslon Pro", font style:"Bold", point size:12, left indent:0, right indent:0, first line indent:0}
end try
--Seiten abarbeiten
repeat with myPage from 1 to myPageRange
tell page myPage
--Reihen abarbeiten
repeat with myRows from 1 to myRowsCount
--Spalten abarbeiten
repeat with myColumns from 1 to myColumnsCount
set myNumber to myNumber + 1
set myX1 to (myColumns - 1) * myBoxWidth
set myX2 to myX1 + myBoxWidth
set myY1 to (myRows - 1) * myBoxHeight
set myY2 to myY1 + myBoxHeight
--Inhalt des Rahmens
set myContent to myVorspan & myNumber & myNachspan
--Zuweisung der Eigenschaften des Rahmens
set myBox to make text frame with properties {contents:myContent as string, geometric bounds:{myY1, myX1, myY2, myX2}, stroke weight:0.2, stroke color:myColor}
set inset spacing of text frame preferences of myBox to myVersatz
set applied paragraph style of paragraph 1 of myBox to myParaStyle
end repeat
end repeat
end tell
end repeat
end tell
display dialog "Habe fertig!"
end tell
-- ende karten.as
grüßle
als Antwort auf: [#122527]
Hier eine kleine Anleitung hinsichtlich Bedeutung der auszufüllenden Formularfelder.
